WarCraft 3

Negate Damage library

Добавлен PT153, опубликован

Алгоритмы, Наработки и Способности

Способ реализации:

vJass

Тип:

Наработка

Версия Warcraft:

1.26+

Библиотека, позволяющая отменять входящий урон.

код

library NegateDamageLib
globals
    private constant group Group = CreateGroup()
    private constant timer Timer = CreateTimer()

    public keyword MaxLifeBonusAbility
    public keyword MaxLifeBonus
endglobals

native UnitAlive takes unit id returns boolean

function GetUnitMaxLife takes unit u returns real
    return GetUnitState(u, UNIT_STATE_MAX_LIFE) - GetUnitAbilityLevel(u, MaxLifeBonusAbility) * MaxLifeBonus
endfunction

private function ProcessUnits takes nothing returns nothing
    local unit u
    local real life2set

    loop
        set u = FirstOfGroup(Group)
        exitwhen u == null
        call GroupRemoveUnit(Group, u)

        if UnitAlive(u) then
            set life2set = GetWidgetLife(u)
            call UnitRemoveAbility(u, MaxLifeBonusAbility)
            call SetWidgetLife(u, life2set)
        else
            call UnitRemoveAbility(u, MaxLifeBonusAbility)
        endif
    endloop
endfunction

function NegateDamage takes unit u, real negated returns nothing
    local real life2set = GetWidgetLife(u) + negated
    local boolean add_ability = life2set > GetUnitState(u, UNIT_STATE_MAX_LIFE)

    if add_ability then
        call GroupAddUnit(Group, u)
        call UnitAddAbility(u, MaxLifeBonusAbility)
    endif

    call SetWidgetLife(u, life2set)

    if add_ability then
        call TimerStart(Timer, 0., false, function ProcessUnits)
    endif
endfunction

endlibrary

Установка

Скачать .j файл и переместить в Директория-JNGP/jass.
В коде карты прописать импорт библиотеки.

//! import "NegateDamageLibrary.j"

Создать способность (далее NegateDamageAbil), которая увеличивает максимальное здоровье юнитов. Рекомендуется создать способность на основе Item Life Bonus [AIlf] с увеличением здоровья на 1 миллион или больше.
Указать равкод способности и значение увеличения здоровья в константах по шаблону ниже.

globals
    constant integer NegateDamageLib_MaxLifeBonusAbility = 'A000'
    constant integer NegateDamageLib_MaxLifeBonus = 1000000
endglobals

Использование

NegateDamage

call NegateDamage(damaged_unit, damage_to_negate)

Отменяет damage_to_negate для damaged_unit. damage_to_negate должно быть больше 0. Если это значение больше входящего урона, то юнит будет вылечен на разницу этих значений. Если вызывать функцию не в триггере получения урона, то damaged_unit будет вылечен на damage_to_negate.

Отмена может не произойти в следующих случаях:

Входящий урон больше, чем бонус здоровья способности NegateDamageAbil.
У юнита здоровья меньше чем 1.

GetUnitMaxLife

set max_life = GetUnitMaxLife(any_unit)

Возвращает максимальное здоровье any_unit без учёта бонуса от NegateDamageAbil.

Особенности

Функция NegateDamage меняет текущее и максимальное здоровье юнита во время вызова и через некоторое время ещё раз:

Триггеры с событием Unit - Life (TriggerRegisterUnitLifeEvent) могут срабатывать во время изменений здоровья.
Чтобы узнавать максимальное здоровье без учёта изменений от NegateDamage, используйте функцию GetUnitMaxLife.

Примеры

Имунные рабочие

Карта
Рабочие игнорируют любой урон до миллиона включительно. Урон более миллиона может убить, а может и не убить.

Щит

Карта
У пехотинца есть способность Shield, которая даёт ему щиты. Щиты поглощают весь входящий урон, пока не израсходуются.

Обновления

08.12.2024

Настраиваемые константы (MaxLifeBonusAbility и MaxLifeBonus) теперь можно определить вне библиотеки.
- Это позволяет импортировать библиотеку из файла, а не копировать её в код карты.
- В связи с этим изменён способ установки и настройки.
Тестовые карты были обновлены для соответствия изменениям выше.

01.12.2024

Таймер запускается, только если способность NegateDamageAbil была добавлена.
Тестовые карты были обновлены для соответствия изменениям выше.
В карте NegateDamage-shield занулены поля Art - Animation - Cast Backswing и Art - Animation - Cast Point у пехотинца.

27.01.2022

Теперь способность добавляется в случаях, если сумма текущего здоровья и отменяемого урона больше максимального запаса здоровья.
GetUnitMaxHealth переименована в GetUnitMaxLife.
Тестовые карты были обновлены для соответствия изменениям выше.

25.12.2021

Убрано требование "библиотеки" AINativesLib, так как тот ресурс был обновлён.
Определение UnitAlive было добавлено в код самой библиотеки.
Обновлены тестовые карты дабы соответствовать изменениям выше.

23.03.2021

Добавлена функция GetUnitMaxHealth.
Некоторые константы стали публичными.
Добавлена ещё одна карта-пример.

21.03.2021 - 3

Полная переработка библиотеки:

Делает всё тоже самое, но лучше. Например, теперь регенерация здоровья верно работают у юнитов, которые игнорируют весь входящий урон и находятся под непрерывным огнём.
Убрана целая куча настроек и требований.

21.03.2021 - 2

В требования добавлена AI natives library.
Изменена проверка того, что юнит жив.

21.03.2021 - 1

Обновлён способ отключения других триггеров, отслеживающих урон.
Обновлена карта-пример.
Улучшена обработка случая, когда юнит умирает от полученного урона.

16.03.2021

Исправлены критические ошибки.

Скачать - 1 КБ 262

2 424

ОЖИДАНИЕ РЕКЛАМЫ...

Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.

Показать

GetLocalPlayer 4 года
Ред. GetLocalPlayer

Показать

PT153, не думаю, что это возможно.
Но!
Но мы вероятно можем контролировать момент, когда мы добавляем макс. хп. Варкрафт ведь линеен, у него нет многопоточности, он не порождает параллельных процессов. Это означает что все триггеры на получение урона юнитом, срабатывают последовательно. Но под влиянием каких правил выстраивается последовательность исполнения триггеров? В порядке назначения им событий? Или в порядке создания триггеров? Зависит ли очередь от величины числового значения хэндла? В порядке регистрации собития (TriggerRegister...Event)? Это очередь или стек?

Зная, как выстраивается последовательность, мы можем хукнуть подходящую функцию таким образом, чтобы максимальное хп юнита увеличивалось не в момент вызова функции, а после того как все пользовательские триггеры отработали.

Показать

PT153 4 года
Ред. PT153

Показать

GetLocalPlayer:

последовательность исполнения триггеров

В порядке регистрации событий. Кто раньше зарегистрировался, тот раньше и сработает. А порядок регистрации диктуется расположением триггеров в редакторе: те что выше, регистрируются раньше. Там есть пара нюансов, когда триггер был только что создан, но это исправляется при закрытии и повторном открытии карты с сохранением.

Есть вариант хукнуть функцию нанесения урона, тем самым добавить к ней убирание способности сразу, как только она завершилась. Это поможет ситуациям вроде таких:

function ...
    call UnitDamageTarget()
    ...
    call UnitDamageTarget()
endfunction

Предположим, что в коде нет пауз. Без хука способность уберётся только после выполнения всего кода функции, а также того кода, где функция была вызвана. С хуком сразу после получения урона. Однако до этого все триггеры на урон сработают.

Однако это никак не поможет для ситуаций, когда триггеры срабатывают раз за разом. Это можно наблюдать в тестовой карте: порой там так жёстко расстреливают, что до таймера в 0 секунд очередь доходит только после нескольких срабатываний триггера. Что делать в такой ситуации, не совсем ясно.

И нужно понимать, что после вызова NegateDamage ничего не мешает делать что-то ещё в триггере, узнавать то же максимальное здоровье. Тут никакие хуки не помогут.

Показать

GetLocalPlayer 4 года
Ред. GetLocalPlayer

Показать

Было бы удобнее хукать TriggerRegisterUnitEvent, но поскольку vJass позволяет хукать функции только до их выполнения, наш хук будет выполнятся перед основной функцией, в то время как нам надо после. Шипко изящного решения что-то не высматривается.
Тем не менее, на данном этапе можно намутить хотя бы это

Код

static if DEBUG_MODE then
    private function hook_GetUnitState takes unit u, unitstate state returns nothing
        if state == UNIT_STATE_MAX_LIFE and GetUnitAbilityLevel(u, HealthAbility) > 0 then
            call BJDebugMsg("WARNING: попытка получить максимальное здоровье юнита, увеличенное библиотекой Negate Damage")
        endif
    endfunction

    hook GetUnitState hook_GetUnitState
endif

По крайней мере пользователь будет знать, где ошибся. Аналогичный хук нужен как минимум для ГУИшного GetUnitStateSwap

Показать

PT153 4 года

Показать

GetLocalPlayer:

до их выполнения

До? Я думал, после.

Было бы удобнее хукать TriggerRegisterUnitEvent

А что это даст? Событие всё равно добавится.

Показать

GetLocalPlayer 4 года

Показать

PT153:

А что это даст? Событие всё равно добавится.

Если порядок исполнения зависит от порядка регистрации событий, то можно было бы зарегистрировать свой триггер на олов урона после регистрации всех пользовательских. Код этого триггера исполнялся бы после всех пользовательских и это хороший момент для выдачи способности/запуска таймера.
Но это прокатило бы если бы хуки вызывали хук-функцию после оригинальной, а не перед.

Показать

PT153 4 года
Ред. PT153

Показать

Либа обновлена, подробности в посте. Из важного - добавлена ещё одна карта-пример.

Показать

GetLocalPlayer 4 года

Показать

Опять же, не нужна константа MaxLifeBonus. Присвоить этой переменной значение 0, в теле функции проверить, если оно равно 0, то выщитать MaxLifeBonus при добавлении способности.
И хуки с предупреждением в дебаг моде на функции GetUnitState, GetUnitStateSwap, GetUnitStatePercent, GetUnitLife все таки нужны.

Показать

KaneThaumaturge 3 года
Ред. KaneThaumaturge

Показать

Делюсь измененной либой. Проблема исходной в скачущей полосе (и значения) здоровья при блокировании дамага. Тут это немного исправлено. Абилка будет выдаваться лишь тогда, когда отменённый урон больше чем максимальное здоровье. Если урон больше чем недостающее здоровье, то юнит хилится на максимум, а дохил будет после нанесения урона. В других случаях юнит просто хилится на отмененный урон. Позволяет немного убрать недостатки либы.

Вам нужна инициализированная хэш-таблица.

код

library NegateDamageLib uses HashId

    globals
        private constant group Group = CreateGroup()
        private constant timer Timer = CreateTimer()
        
        // MUST BE SPECIFIED
        public constant integer MaxLifeBonusAbility = 'A002'
        public constant integer MaxLifeBonus = 1000000
    endglobals

    private function ProcessUnitAbility takes nothing returns nothing
        local unit u
        local real life2set
    
        loop
            set u = FirstOfGroup(Group)
            exitwhen u == null
            call GroupRemoveUnit(Group, u)
        
            if UnitAlive(u) then
                set life2set = GetWidgetLife(u)
                call UnitRemoveAbility(u, MaxLifeBonusAbility)
                call SetWidgetLife(u, life2set)
            else
                call UnitRemoveAbility(u, MaxLifeBonusAbility)
            endif
        endloop
    endfunction

    private function ProcessUnit takes nothing returns nothing
        local integer tmId = GetHandleId(GetExpiredTimer())
        local unit u = LoadUnitHandle(HT, tmId, 0)
        local real lifeBonus = LoadReal(HT, tmId, 1)
            
        if UnitAlive(u) then
            call SetWidgetLife(u, GetUnitState(u, UNIT_STATE_LIFE)  + lifeBonus)
        endif
        
        set u = null
        call FlushChildHashtable(HT, tmId)
        call PauseTimer(GetExpiredTimer())
        call DestroyTimer(GetExpiredTimer())
    endfunction

    function NegateDamage takes unit u, real negated returns nothing
        local real life = GetWidgetLife(u)
        local real a
        local timer tm
        set a = GetUnitState(u, UNIT_STATE_MAX_LIFE) - GetUnitState(u, UNIT_STATE_LIFE)
        if (GetUnitState(u, UNIT_STATE_MAX_LIFE) < negated) then
            call GroupAddUnit(Group, u)
            call UnitAddAbility(u, MaxLifeBonusAbility)
            call SetWidgetLife(u, life + negated)
            call TimerStart(Timer, 0., false, function ProcessUnitAbility)
        elseif (a < negated) then
            call SetWidgetLife(u, life + a)
            set tm = CreateTimer()
            call SaveUnitHandle(HT, GetHandleId(tm), 0, u)
            call SaveReal(HT, GetHandleId(tm), 1, negated - a)
            call TimerStart(tm, 0., false, function ProcessUnit)
        else
            call SetWidgetLife(u, life + negated)
        endif
        set tm = null
    endfunction

    function GetUnitMaxHealth takes unit u returns real
        return GetUnitState(u, UNIT_STATE_MAX_LIFE) - MaxLifeBonus * GetUnitAbilityLevel(u, MaxLifeBonusAbility)
    endfunction

endlibrary

И в дополнение макрос для перехвата функции, жаль cJass.

    define GetUnitState(u, state) = GetUnitStateHook(u, state)
    
    //! nocjass
    function GetUnitStateHook takes unit u, unitstate state returns real
        if state == UNIT_STATE_MAX_LIFE then
            return GetUnitState(u, UNIT_STATE_MAX_LIFE) - MaxLifeBonus * GetUnitAbilityLevel(u, MaxLifeBonusAbility)
        endif
        return GetUnitState(u, state)
    endfunction
    //! endnocjass

Этот комментарий удален

Показать

PT153 3 года
Ред. PT153

Показать

KaneThaumaturge:

Если урон больше чем недостающее здоровье, то юнит хилится на максимум, а дохил будет после нанесения урона.

Такой способ может уменьшать и увеличивать хп на небольшое значение (однако через длительное время всё может появится существенная разница), а также никак не решает проблему скачков полоски хп. Поэтому в этом случае лучше добавлять абилку. Первое предложение учту.

Показать

KaneThaumaturge 3 года

Показать

PT153, Но скачки будут гараздо реже и при обычной игре не заметны, да есть небольшая ошибка из-за real. Но в целом если у вас нет юнитов с 1 хп, то все будет норм.

Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.

Чтобы оставить комментарий, пожалуйста, войдите на сайт.

Negate Damage library

Установка

Использование

Особенности

Примеры

Имунные рабочие

Щит

Обновления

Вход

Регистрация на сайте

Переместить ресурс

Создание задания

Выбор проекта для репоста

Управление интересами