library SpellCastLib
globals
    private constant timer TempTimer = CreateTimer( )
    private constant real timerPeriodic = 0.01
    
    private integer max = 0

    private unit array dummy
    
    private real array startx
    private real array starty
    private real array startz
    private real array midx
    private real array midy
    private real array midz
    private real array endx
    private real array endy
    private real array endz
    private real array lastx
    private real array lasty
    
    private real array time
    private real array maxTime
    
    private location LFZ = Location( 0.00, 0.00 )
endglobals

private function GetLocZ takes real x, real y returns real
    call MoveLocation( LFZ, x, y )
    return GetLocationZ( LFZ )
endfunction

private function move takes nothing returns nothing
    local real x
    local real y
    local real z
    local integer i
    
    set i = 1
    loop
        set x = startx[i] + ( ( 2.00 * ( midx[i] - startx[i] ) ) + ( startx[i] - 2.00 * midx[i] + endx[i] ) * time[i] ) * time[i]
        set y = starty[i] + ( ( 2.00 * ( midy[i] - starty[i] ) ) + ( starty[i] - 2.00 * midy[i] + endy[i] ) * time[i] ) * time[i]
        set z = startz[i] + ( ( 2.00 * ( midz[i] - startz[i] ) ) + ( startz[i] - 2.00 * midz[i] + endz[i] ) * time[i] ) * time[i]
        
        call SetUnitX( dummy[i], x )
        call SetUnitY( dummy[i], y )
        call SetUnitFlyHeight( dummy[i], z - GetLocZ( x, y ), 0.00 )
        call SetUnitFacing( dummy[i], Atan2( y - lasty[i], x - lastx[i] ) * bj_RADTODEG )
        
        set lastx[i] = x
        set lasty[i] = y
        
        set time[i] = time[i] + timerPeriodic / maxTime[i]
        
        if time[i] >= 1.00 then
            call KillUnit( dummy[i] )
            call DestroyEffect( AddSpecialEffect( "Objects\\Spawnmodels\\NightElf\\EntBirthTarget\\EntBirthTarget.mdl", x, y ) )
            call CreateDestructable( 'ATtr', x, y, 270.00, 1.00, GetRandomInt( 0, 4 ) )
            
            if i != max then
                set dummy[i] = dummy[max]
                
                set startx[i] = startx[max]
                set starty[i] = starty[max]
                set startz[i] = startz[max]
                
                set lastx[i] = lastx[max]
                set lasty[i] = lasty[max]
                
                set endx[i] = endx[max]
                set endy[i] = endy[max]
                set endz[i] = endz[max]
                
                set midx[i] = midx[max]
                set midy[i] = midy[max]
                set midz[i] = midz[max]
                
                set time[i] = time[max]
                set maxTime[i] = maxTime[max]
            endif
            
            set dummy[max] = null
            
            set i = i - 1
            set max = max - 1
            
            if max <= 0 then
                call PauseTimer( TempTimer )
            endif
        endif
        
        set i = i + 1
        exitwhen i > max
    endloop
endfunction

function Trig_SpellCast_Actions takes nothing returns nothing
    local unit caster = GetTriggerUnit( )
    local real x = GetSpellTargetX( )
    local real y = GetSpellTargetY( )
    local real angle
    local real angle1
    local real angle2
    local real distance
    local integer i
    local integer count = 10 // кол-во деревьев
    local boolean b 
    local real d
    
    set b = count / 2 * 2 == count
    
    if b then
        set d = 32.00 // начальная дистанция между деревьями
        set angle2 = 5.00 // начальный угол полёта
    else
        set d = 0.00
        set angle2 = 0.00
    endif
    
    set angle1 = Atan2( y - GetUnitY( caster ), x - GetUnitX( caster ) )
    
    set i = 1
    loop
        set max = max + 1
        
        set startx[max] = GetUnitX( caster )
        set starty[max] = GetUnitY( caster )
        set startz[max] = GetLocZ( startx[max], starty[max] ) + 50.00 + GetUnitFlyHeight( caster )
        
        set lastx[max] = startx[max]
        set lasty[max] = starty[max]
        
        set dummy[max] = CreateUnit( GetOwningPlayer( caster ), 'u000', startx[max], starty[max], angle1 * bj_RADTODEG )
        
        call UnitAddAbility( dummy[max], 'Arav' )
        call UnitRemoveAbility( dummy[max], 'Arav' )
        call SetUnitPathing( dummy[max], false )
        call SetUnitX( dummy[max], startx[max] )
        call SetUnitY( dummy[max], starty[max] )
        call SetUnitFlyHeight( dummy[max], startz[max], 0.00 )
        
        if b then
            set endx[max] = x + d * Cos( angle1 + 90.00 * bj_DEGTORAD )
            set endy[max] = y + d * Sin( angle1 + 90.00 * bj_DEGTORAD )
        else
            set endx[max] = x + d * Cos( angle1 - 90.00 * bj_DEGTORAD )
            set endy[max] = y + d * Sin( angle1 - 90.00 * bj_DEGTORAD )
        endif
        
        set endz[max] = GetLocZ( endx[max], endy[max] )
        set angle     = Atan2( endy[max] - starty[max], endx[max] - startx[max] )
        set distance  = SquareRoot( ( endx[max] - startx[max] ) * ( endx[max] - startx[max] ) + ( endy[max] - starty[max] ) * ( endy[max] - starty[max] ) )
        
        if b then
            set midx[max] = startx[max] + distance / 2.00 * Cos( angle + angle2 * bj_DEGTORAD )
            set midy[max] = starty[max] + distance / 2.00 * Sin( angle + angle2 * bj_DEGTORAD )
            set midz[max] = GetLocZ( midx[max], midy[max] )
            
            set b = false
        else
            set midx[max] = startx[max] + distance / 2.00 * Cos( angle - angle2 * bj_DEGTORAD )
            set midy[max] = starty[max] + distance / 2.00 * Sin( angle - angle2 * bj_DEGTORAD )
            set midz[max] = GetLocZ( midx[max], midy[max] )
            
            set angle2 = angle2 + 10.00 // доп угол
            set d = d + 64.00 // расстояние между деревьями
            set b = true
        endif
        
        if startz[max] < endz[max] then
            set midz[max] = midz[max] + endz[max]
        else
            set midz[max] = midz[max] + startz[max]
        endif
        
        set midz[max] = midz[max] + 50.00
        
        set time[max] = 0.00
        set maxTime[max] = distance * timerPeriodic * 0.20 // скорость полёта
        
        if max == 1 then
            call TimerStart( TempTimer, timerPeriodic, true, function move )
        endif
        
        set i = i + 1
        exitwhen i > count
    endloop
    
    set caster = null
endfunction
endlibrary

function Trig_SpellCast_Conditions takes nothing returns boolean
    return GetSpellAbilityId( ) == 'A000' // равкод абилки
endfunction

//===========================================================================
function InitTrig_SpellCast takes nothing returns nothing
    set gg_trg_SpellCast = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_SpellCast, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_SpellCast, Condition( function Trig_SpellCast_Conditions ) )
    call TriggerAddAction( gg_trg_SpellCast, function Trig_SpellCast_Actions )
endfunction

library DamageEventLib
globals
    private constant hashtable H     = InitHashtable( )
    private constant timer TempTimer = CreateTimer( )
    private constant group TempGroup = CreateGroup( )
endglobals

private struct UnitStruct
    integer attacker
    integer damaged
    integer count
    timer t
endstruct

private function RemoveStacks takes nothing returns nothing
    local timer t = GetExpiredTimer( )
    local UnitStruct A = LoadInteger( H, GetHandleId( t ), 0 )
    
    call RemoveSavedInteger( H, A.attacker, A.damaged )
    call FlushChildHashtable( H, GetHandleId( t ) )
    call DestroyTimer( t )
    
    set A.t = null
    set A.count    = 0
    set A.attacker = 0
    set A.damaged  = 0
    call A.destroy( )
    
    set t = null
endfunction

private function DamageEvent_Actions takes nothing returns nothing
    local UnitStruct A
    
    set udg_damaged = GetTriggerUnit( )
    
    if GetUnitAbilityLevel( udg_damaged, 'Bssd' ) > 0 then // заклинания яда
        call UnitRemoveAbility( udg_damaged, 'Bssd' )
        
        set udg_damage = GetEventDamage( )
        set udg_attacker = GetEventDamageSource( )
        set A = LoadInteger( H, GetHandleId( udg_attacker ), GetHandleId( udg_damaged ) )
        
        if A == 0 then
            set A = UnitStruct.create( )
            set A.t = CreateTimer( )
            set A.attacker = GetHandleId( udg_attacker )
            set A.damaged = GetHandleId( udg_damaged )
            
            call SaveInteger( H, A.attacker, A.damaged, A )
            call SaveInteger( H, GetHandleId( A.t ), 0, A )
        endif
            
        call TimerStart( A.t, 3.00, false, function RemoveStacks ) // через какое время удалить стаки ( 3.00 сек )
        
        set A.count = A.count + 1
        set udg_count = A.count
        
        call TriggerExecute( gg_trg_DamageEventGUI )
        
        set A.count = udg_count
    endif
endfunction

//===========================================================================
private function Regist_2 takes nothing returns boolean
    call TriggerRegisterUnitEvent( gg_trg_DamageEvent, GetTriggerUnit( ), EVENT_UNIT_DAMAGED )
    
    return false
endfunction

private function Regist_1 takes nothing returns boolean
    call TriggerRegisterUnitEvent( gg_trg_DamageEvent, GetFilterUnit( ), EVENT_UNIT_DAMAGED )
    
    return false
endfunction

private function Regist takes nothing returns nothing
    if gg_trg_DamageEvent != null then
        call DestroyTrigger( gg_trg_DamageEvent )
    endif
    
    set gg_trg_DamageEvent = CreateTrigger(  )
    
    call GroupEnumUnitsInRect( TempGroup, bj_mapInitialPlayableArea, Condition( function Regist_1 ) )
    call TriggerAddAction( gg_trg_DamageEvent, function DamageEvent_Actions )
    
    call TimerStart( TempTimer, 600.00, false, function Regist )
endfunction

function InitTrig_DamageEvent takes nothing returns nothing
    local region rectRegion = CreateRegion( )
    local trigger trg = CreateTrigger( )
    
    call RegionAddRect( rectRegion, bj_mapInitialPlayableArea )
    call TriggerRegisterEnterRegion( trg, rectRegion, null )
    call TriggerAddCondition( trg, Condition( function Regist_2 ) )
    call TimerStart( TempTimer, 0.00, false, function Regist )
    
    set trg = null
    set rectRegion = null
endfunction
endlibrary