Анти-афк

library AFK initializer Init

    globals
        private integer array afkInt
                boolean array afkBool
    endglobals

    private function AFK takes player p returns nothing
        call BJDebugMsg(GetPlayerName(p))
    endfunction
    
    private function afkTrigger_Actions takes nothing returns nothing
        local integer i = 0
        
        loop
            exitwhen i > 11
            if( GetPlayerSlotState(Player(i)) == PLAYER_SLOT_STATE_PLAYING and afkBool[i] != true ) then
                set afkInt[i] = afkInt[i] + 1
                
                if( afkInt[i] == 120 ) then
                    call AFK(Player(i))
                endif
            else
                set afkInt[i] = 0
            endif
            set i = i + 1
        endloop
    endfunction
    
    private function afkRemove_Actions takes nothing returns nothing
        if( afkInt[GetPlayerId(GetTriggerPlayer())] > 0 ) then
            set afkInt[GetPlayerId(GetTriggerPlayer())] = 0
        endif
    endfunction

    //===========================================================================

    private function afkRemove2_Actions takes nothing returns nothing
        if GetIssuedOrderId() == 851973 then
            return
        endif
        if( afkInt[GetPlayerId(GetOwningPlayer(GetOrderedUnit()))] > 0 ) then
            set afkInt[GetPlayerId(GetOwningPlayer(GetOrderedUnit()))] = 0
        endif
    endfunction

    private function AnyPlayersEvent takes trigger trig returns nothing
        local integer i = 0
        loop
        exitwhen i > 11
        
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_END_CINEMATIC)
            call TriggerRegisterPlayerChatEvent( trig, Player(i), "", false )
            call TriggerRegisterPlayerUnitEvent(trig, Player(i), EVENT_PLAYER_UNIT_SELECTED, null)
            call TriggerRegisterPlayerUnitEvent(trig, Player(i), EVENT_PLAYER_UNIT_DESELECTED, null)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_LEFT_DOWN)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_RIGHT_DOWN)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_DOWN_DOWN)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_UP_DOWN)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_LEFT_UP)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_RIGHT_UP)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_DOWN_UP)
            call TriggerRegisterPlayerEvent(trig, Player(i), EVENT_PLAYER_ARROW_UP_UP)
            
        set i = i + 1
        endloop
    endfunction
    //===========================================================================
    private function Trig_afkRemove2 takes nothing returns nothing
        local trigger trg_afkRemove2 = CreateTrigger(  )
        
        call TriggerRegisterAnyUnitEventBJ( trg_afkRemove2, EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER )
        call TriggerRegisterAnyUnitEventBJ( trg_afkRemove2, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER )
        call TriggerRegisterAnyUnitEventBJ( trg_afkRemove2, EVENT_PLAYER_UNIT_ISSUED_ORDER )
        call TriggerAddAction( trg_afkRemove2, function afkRemove2_Actions )
        
        set trg_afkRemove2 = null
    endfunction
    private function Trig_afkRemove takes nothing returns nothing
        local trigger trg_afkRemove = CreateTrigger(  )
        
        call AnyPlayersEvent(trg_afkRemove)
        call TriggerAddAction( trg_afkRemove, function afkRemove_Actions )
        
        set trg_afkRemove = null
    endfunction
    //===========================================================================
    private function Trig_afkTrigger takes nothing returns nothing
        local trigger trg_afkTrigger = CreateTrigger(  )
        
        call TriggerRegisterTimerEvent( trg_afkTrigger, 1.00, true )
        call TriggerAddAction( trg_afkTrigger, function afkTrigger_Actions )
        
        set trg_afkTrigger = null
    endfunction
    
    private function Init takes nothing returns nothing
        call Trig_afkRemove2()
        call Trig_afkRemove()
        call Trig_afkTrigger()
    endfunction

endlibrary