Как скрыть юнита локально?

    //достает адрес обнаружения юнита (это типа флага, что ваш юнит обнаружен)
    //кооперируется с другими offset-ами
    function GetUnitVisibilityClass takes unit u returns integer
        local integer a = ConvertHandle( u )
        local integer res = 0
        if a > 0 then
            set res = RMem( a + 0x130 )
            if res > 0 then
                set res = GetSomeAddressForAbility( res, RMem( a + 0x134 ) )
            endif
        endif
        return res
    endfunction

    //достает адрес обзора юнита (этот флаг показывает, с кем из игроков делит поле зрение)
    //кооперируется с другими offset-ами
    function GetUnitDetectedClass takes unit u returns integer
        local integer a = ConvertHandle( u )
        local integer res = 0
        if a > 0 then
            set res = RMem( a + 0x13C )
            if res > 0 then
                set res = GetSomeAddressForAbility( res, RMem( a + 0x140 ) )
            endif
        endif
        return res
    endfunction

    //обычная проверка на видимость. 
    //помните: волшебный огонь у друида, он смотрит глазами врага, т.е. показывает то, что делает вражеский юнит на карте
    //еще такое можно добиться близардской функцией UnitShareVision
    function IsUnitDetectedByPlayer takes unit u, player p returns boolean
	//shared vision-like effect, used for Faerie fire / Wand of evil eye
	//have no reveal effect by itself, used only as detector?
        local integer a = GetUnitDetectedClass( u )
        if a > 0 then
            return IsFlagBitSet( RMem( a + 0x24 ), Player2Flag( p ) )
        endif
        return false
    endfunction

    //Удалить детект с юнита (обнулить).
    //юнита u перестают обнаруживать вражеские детекторы
    function RemoveAnyDetectionFromUnit takes unit u returns nothing
        local integer a = ConvertHandle( u )
        if a > 0 then
            call WMem( a + 0x148, 0 )
            call WMem( a + 0x14C, 0 )
            set a = GetUnitVisibilityClass( u )
            if a > 0 then
                call WMem( a + 0x24, 0 )
            endif
        endif
    endfunction

   //Вернуть детект юниту
   //вашего юнита u могут обнаружить вражеские детекторы
    function RecountAnyDetectionForUnit takes unit u returns nothing
        local integer a = ConvertHandle( u )
        local integer sum = 0
        local integer i = 0
        if a > 0 then
            set a = GetUnitDetectedClass( u )
            if a > 0 then
                loop
                    if RMem( a + 0x2C + 4 * i ) > 0 then
                        set sum = sum + R2I( Pow( 2, i ) )
                    endif
                    set i = i + 1
                    exitwhen i > 15
                endloop
                call WMem( a + 0x14C, sum )
                call WMem( a + 0x148, sum )
                set sum = 0
                set i = 0
            endif
            set a = GetUnitVisibilityClass( u )
            if a > 0 then
                loop
                    if RMem( a + 0x2C + 4 * i ) > 0 then
                        set sum = sum + R2I( Pow( 2, i ) )
                    endif
                    set i = i + 1
                    exitwhen i > 15
                endloop
                call WMem( a + 0x24, sum )
            endif
        endif
    endfunction

//флаги москитов. За основу взят флаг москита. У москитов много флагов
    function GetSomeAddressForLocustFlags takes integer pAddr1 , integer pAddr2 returns integer
        local integer i = GetSomeAddress( pAddr1, pAddr2 )
        return RMem( i + 0x94 )
    endfunction

    function SetLocustFlags takes unit u, integer i returns nothing //These flags can make unit immune to truesight
        local integer pOff1
        set LastConvertedHandle = ConvertHandle( u )
        if LastConvertedHandle > 0 then
            set LastConvertedHandle = LastConvertedHandle + 0x16C
            set pOff1 = GetSomeAddressForLocustFlags( RMem( LastConvertedHandle ), RMem( LastConvertedHandle + 4 ) )
            if pOff1 > 0 then
                call WMem( pOff1 + 0x34, i )
            endif
        endif
    endfunction

    //Включить иммунитет к обнаружению инвизных юнитов
    //Это означает, что детекторы не смогут обнаружить невидимого юнита u
    function EnableTruesightImmunity takes unit u returns nothing
    //I don’t really know what other side effects may be caused by this, at least GroupEnum is not affected
    //Я не знаю, какие другие побочные эффекты могут быть вызваны этим, по крайней мере GroupEnum не влияет
        call SetLocustFlags( u, 0x08000000 )
    endfunction

	//Выключить иммунитет к обнаружению инвиза
    function DisableTruesightImmunity takes unit u returns nothing
        call SetLocustFlags( u, 0 )
    endfunction