native SetUnitTimeScale takes unit whichUnit, real timeScale returns nothing

native QuestSetDiscovered takes quest whichQuest, boolean discovered returns nothing

// By Zahanc. Version 1. 2017-01-25.
library WanderingStarSpell initializer WanderingStarSpellInit

  globals
    // Meta settings
    public constant integer WANDERING_STAR_SPELL_ID = 'A000'
    public constant integer WANDERING_STAR_DUMMY_ID = 'n000'
    public constant string WANDERING_STAR_MISSILE_EFFECT_NAME = "Abilities\\Weapons\\DragonHawkMissile\\DragonHawkMissile.mdl"
    public constant string WANDERING_STAR_IMPACT_EFFECT_NAME = "Abilities\\Weapons\\DragonHawkMissile\\DragonHawkMissile.mdl"
    // End meta settings
    
    // Spell parameters
    private constant real missileSpeed = 1000.0
    private constant real missileSpeedWhenBouncing = missileSpeed * 3
    private constant real bouncingRange = 50.0
    private constant real bounceOffDistance = 500.0
    private constant real baseDurationSeconds = 5.0
    private constant real durationIncreasePerSpellLevel = 1.0
    private constant real baseDamagePerBounce = 20.0
    private constant real damageIncreasePerSpellLevel = 20.0
    private constant integer baseBouncesNumber = 3
    private constant integer bouncesNumberIncreasePerSpellLevel = 2
    // End spell parameters
    
    // Core variables
    private constant real UPDATE_LOOP_TIMER_TIMEOUT = 0.02
    private SpellEffect array spellEffects
    private integer spellEffectsAmount = 0
    
    
    // End core variables
  endglobals
  
  struct SpellEffect    
    public unit caster = null
    public unit target = null
    public integer spellLevel = 1
    
    private static constant integer MODE_FOLLOW = 1
    private static constant integer MODE_BOUNCE = 2
    
    private integer mode = SpellEffect.MODE_FOLLOW
    public effect missileEffect = null
    public unit missile = null
    private integer bounces = 0
    private location bounceOffLoc = null
    
    public method update takes nothing returns nothing
      local real x0 = GetUnitX(this.missile)
      local real y0 = GetUnitY(this.missile)
      local real z0 = GetUnitFlyHeight(this.missile)
      local real x1 = 0.0
      local real y1 = 0.0
      local real z1 = 0.0
      local real x = 0.0
      local real y = 0.0
      local real z = 0.0
      local real vectorMagnitude = 0.0
      local real f = 0.0
      local real damage = 0.0
      
      if IsUnitDeadBJ(this.target) then
        call this.destroy()
        return
      endif
      
      if SpellEffect.MODE_FOLLOW == this.mode then
        set x1 = GetUnitX(this.target)
        set y1 = GetUnitY(this.target)
        set z1 = GetUnitFlyHeight(this.target)
      elseif SpellEffect.MODE_BOUNCE == this.mode then
        set x1 = GetLocationX(this.bounceOffLoc)
        set y1 = GetLocationY(this.bounceOffLoc)
        set z1 = GetLocationZ(this.bounceOffLoc)
      endif
      
      set vectorMagnitude = SquareRoot((x1-x0)*(x1-x0)+(y1-y0)*(y1-y0)+(z1-z0)*(z1-z0))
      set x = x0 + ((x1 - x0) / vectorMagnitude) * missileSpeed * UPDATE_LOOP_TIMER_TIMEOUT
      set y = y0 + ((y1 - y0) / vectorMagnitude) * missileSpeed * UPDATE_LOOP_TIMER_TIMEOUT
      set z = z0 + ((z1 - z0) / vectorMagnitude) * missileSpeed * UPDATE_LOOP_TIMER_TIMEOUT
      set f = bj_RADTODEG * Atan2(y1 - y0, x1 - x0)
      
      call SetUnitX(this.missile, x)
      call SetUnitY(this.missile, y)
      call SetUnitFlyHeight(this.missile, z, 0.0)
      call SetUnitFacing(this.missile, f)
      
      // Do not count height when calculating collision.
      if SquareRoot((x1-x)*(x1-x)+(y1-y)*(y1-y)) <= bouncingRange and SpellEffect.MODE_FOLLOW == this.mode then
        set this.mode = SpellEffect.MODE_BOUNCE
        // FORMULA FOR DAMAGE CALCULATION
        set damage = baseDamagePerBounce + damageIncreasePerSpellLevel * I2R(this.spellLevel)
        call UnitDamageTarget(this.caster, this.target, damage, true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS)
        call DestroyEffect(AddSpecialEffect(WANDERING_STAR_IMPACT_EFFECT_NAME, x1, y1))
        
        call RemoveLocation(this.bounceOffLoc)
        // Use `location` to ensure the result is in game map bounds.
        set this.bounceOffLoc = Location(GetRandomReal(x1 - bounceOffDistance, x1 + bounceOffDistance), GetRandomReal(y1 - bounceOffDistance, y1 + bounceOffDistance))
        set this.bounces = this.bounces + 1
      elseif SquareRoot((x1-x)*(x1-x)+(y1-y)*(y1-y)) <= bouncingRange and SpellEffect.MODE_BOUNCE == this.mode then
        set this.mode = SpellEffect.MODE_FOLLOW
        call RemoveLocation(this.bounceOffLoc)
        set this.bounceOffLoc = null
      endif
      
      // FORMULA FOR BOUNCES AMOUNT CALCULATION
      if this.bounces >= baseBouncesNumber + bouncesNumberIncreasePerSpellLevel * this.spellLevel then
        call this.destroy()
      endif
    endmethod
    
    method onDestroy takes nothing returns nothing
      local integer i = 0
      
      set this.caster = null
      set this.target = null
      call DestroyEffect(this.missileEffect)
      set this.missileEffect = null
      call RemoveUnit(this.missile)
      set this.missile = null
      call RemoveLocation(this.bounceOffLoc)
      set this.bounceOffLoc = null
      
      loop
        exitwhen i >= spellEffectsAmount
        if this == spellEffects[i] then
          set spellEffectsAmount = spellEffectsAmount - 1
          set spellEffects[i] = spellEffects[spellEffectsAmount]
          set spellEffects[spellEffectsAmount] = 0
          return
        endif
        set i = i + 1
      endloop
    endmethod
  endstruct
  
  function CreateWanderingStarSpellEffect takes unit caster, unit target, integer spellLevel returns nothing
    local SpellEffect spellEffect = SpellEffect.create()
    set spellEffect.caster = caster
    set spellEffect.target = target
    set spellEffect.missile = CreateUnit(Player(PLAYER_NEUTRAL_PASSIVE), WANDERING_STAR_DUMMY_ID, GetUnitX(caster), GetUnitY(caster), GetUnitFacing(caster))
    call UnitAddAbility(spellEffect.missile, 'Avul')
    call UnitAddAbility(spellEffect.missile, 'Aloc')
    call UnitAddAbility(spellEffect.missile, 'Amrf')
    set spellEffect.missileEffect = AddSpecialEffectTarget(WANDERING_STAR_MISSILE_EFFECT_NAME, spellEffect.missile, "origin")
    
    set spellEffects[spellEffectsAmount] = spellEffect
    set spellEffectsAmount = spellEffectsAmount + 1
  endfunction
  
  function SpellUpdateLoopCallback takes nothing returns nothing
    local integer i = 0
    local SpellEffect next = 0
    
    loop
      exitwhen i >= spellEffectsAmount
      set next = spellEffects[i]
      call next.update()
      set i = i + 1
    endloop
  endfunction
  
  function OnSpellEffectPredicate takes nothing returns boolean
    return WANDERING_STAR_SPELL_ID == GetSpellAbilityId()
  endfunction

  function OnSpellEffect takes nothing returns nothing
    call CreateWanderingStarSpellEffect(GetSpellAbilityUnit(), GetSpellTargetUnit(), GetUnitAbilityLevel(GetSpellAbilityUnit(), WANDERING_STAR_SPELL_ID))
  endfunction

  function WanderingStarSpellInit takes nothing returns nothing
    local trigger t = CreateTrigger(  )
    
    call TimerStart(CreateTimer(), UPDATE_LOOP_TIMER_TIMEOUT, true, function SpellUpdateLoopCallback)
    
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(t, Condition( function OnSpellEffectPredicate))
    call TriggerAddAction(t, function OnSpellEffect)
    
    set t = null
  endfunction

endlibrary