function Trig_SoulLantern_Conditions takes nothing returns boolean
    return msc_check_item_for_id ( GetTriggerUnit (), GetIssuedOrderId (), 'Pr1L' )
endfunction

function Trig_SoulLantern_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit ()
    local real x1 = GetOrderPointX ()
    local real y1 = GetOrderPointY ()
    local unit trg 
    local item it = msc_get_item_by_o_id ( u, GetIssuedOrderId () )
    local group gr = CreateGroup ()
    local real x2
    local real y2
    local real dist
    local integer i = 0
    loop
        set x2 = GetUnitX ( msc_Players.msc_player[i].hero )
        set y2 = GetUnitY ( msc_Players.msc_player[i].hero )
        set dist = msc_dist_between ( x1, x2, y1, y2 )
        if ( dist < 300.0 ) and ( IsUnitType ( msc_Players.msc_player[i].hero , UNIT_TYPE_DEAD ) ) then
            call GroupAddUnit ( gr, msc_Players.msc_player[i].hero )
        endif
        set i = i + 1
        exitwhen ( i == msc_Players.player_count )
    endloop
        
    set trg = GroupPickRandomUnit ( gr )
    
    if ( trg != null ) and ( GetItemCharges ( it ) > 0 ) then
        call CrossRespawn.respawn ( trg, 50.0, 50.0, GetUnitX ( trg ), GetUnitY ( trg ) )
    else
        if ( trg == null ) then
            call SimError ( GetOwningPlayer ( u ), "Можно применять только на могилы" )
        endif
        if ( GetItemCharges ( it ) == 0 ) then
            call SimError ( GetOwningPlayer ( u ), "Зарядите Фонарь при помощи Крестов" )
        endif
        call SetItemPosition ( it, 0, 0 )
        call msc_give_item_delay ( u, it, 0.00 )
    endif
    
    call DestroyGroup ( gr )
    set u = null
    set trg = null
    set it = null
    set gr = null
endfunction

//===========================================================================
function InitTrig_SoulLantern takes nothing returns nothing
    set gg_trg_SoulLantern = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_SoulLantern, EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER )
    call TriggerAddCondition( gg_trg_SoulLantern, Condition( function Trig_SoulLantern_Conditions ) )
    call TriggerAddAction( gg_trg_SoulLantern, function Trig_SoulLantern_Actions )
endfunction