local location l = GetUnitLoc(GetTriggerUnit())
call RemoveLocation(l)
set l = null

local string s = "bee !!!"
...

code
player
real
integer
boolean

function CrashAttack_HeroSpellRawCode takes nothing returns integer
    return 'A000'
endfunction
function CrashAttack_Damage takes integer lvl, integer str returns real
    return ( lvl * 10. + 10. ) + (  (0.2 * lvl ) * str )
endfunction
function CrashAttack_HeroHandsEffect takes nothing returns string
    return "units\\human\\phoenix\\phoenix.mdl"
endfunction
function CrashAttack_KnockbackEffect takes nothing returns string
    return "Abilities\\Weapons\\AncientProtectorMissile\\AncientProtectorMissile.mdl"
endfunction
function CrashAttack_Hashtable takes nothing returns hashtable
    return udg_Hashtable
endfunction
function CrashAttack_AttackType takes nothing returns attacktype
    return ATTACK_TYPE_MELEE
endfunction
function CrashAttack_DamageType takes nothing returns damagetype
    return DAMAGE_TYPE_NORMAL
endfunction
function CrashAttack_WeaponType takes nothing returns weapontype
    return WEAPON_TYPE_WHOKNOWS
endfunction

// Setup ===========|

function CrashAttack_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == CrashAttack_HeroSpellRawCode()
endfunction

function CrashAttack_OnTimer takes nothing returns nothing
    local hashtable ht = CrashAttack_Hashtable()
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit trg = LoadUnitHandle(ht, id, 0)
    local real kbp = LoadReal(ht, id, 1)
    local real kbrs = LoadReal(ht, id, 2)
    local real a = LoadReal(ht, id, 3)
    local real tx = GetUnitX(trg)
    local real ty = GetUnitY(trg)
    local string e = CrashAttack_KnockbackEffect()
    
    set kbp = kbp - kbrs
    call SaveReal(ht, id, 1, kbp)
    
    if kbp <= 0. then
    call FlushChildHashtable(ht, id)
    call PauseTimer(t)
    call DestroyTimer(t)
    else
    call DestroyEffect(AddSpecialEffectTarget(e, trg, "origin"))
    call SetUnitX(trg, tx + kbp * Cos(a * bj_DEGTORAD))
    call SetUnitY(trg, ty + kbp * Sin(a * bj_DEGTORAD))
    endif
    
    set ht = null
    set t = null
    set trg = null
    set e = ""
endfunction

function CrashAttack_Actions takes nothing returns nothing
    local hashtable ht = CrashAttack_Hashtable()
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    local unit c = GetTriggerUnit()
    local unit trg = GetSpellTargetUnit()
    local real cx = GetUnitX(c)
    local real cy = GetUnitY(c)
    local real tx = GetUnitX(trg)
    local real ty = GetUnitY(trg)
    local integer abi = CrashAttack_HeroSpellRawCode()
    local integer lvl = GetUnitAbilityLevel(c, abi)
    local integer str = GetHeroStr(c, true)
    local real dmg = CrashAttack_Damage(lvl, str)
    local real kbp = 20.
    local real kbrs = .9
    local attacktype at = CrashAttack_AttackType()
    local damagetype dt = CrashAttack_DamageType()
    local weapontype wt = CrashAttack_WeaponType()
    local string e = CrashAttack_HeroHandsEffect()
    local real period = .03
    local real a = 57.295827 * Atan2(ty-cy, tx-cx)
    
    call UnitDamageTarget(c, trg, dmg, false, false, at, dt, wt)
    
    call DestroyEffect(AddSpecialEffectTarget(e, c, "hand right"))
    call DestroyEffect(AddSpecialEffectTarget(e, c, "hand left"))
    
    call SaveUnitHandle(ht, id, 0, trg)
    call SaveReal(ht, id, 1, kbp)
    call SaveReal(ht, id, 2, kbrs)
    call SaveReal(ht, id, 3, a)
    
    call TimerStart(t, period, true, function CrashAttack_OnTimer)
    
    set ht = null
    set t = null
    set c = null
    set trg = null
    set at = null
    set dt = null
    set wt = null
    set e = ""
endfunction

function CrashAttack_Filter takes nothing returns boolean
    return true
endfunction

function InitTrig_Crash_Attack takes nothing returns nothing
    local integer i = 0
    local filterfunc f = Filter(function CrashAttack_Filter)
    
    set gg_trg_Crash_Attack = CreateTrigger()
    
    loop
    exitwhen i == 16
    call TriggerRegisterPlayerUnitEvent(gg_trg_Crash_Attack, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, f)
    set i = i + 1
    endloop
    
    call TriggerAddCondition(gg_trg_Crash_Attack, Condition(function CrashAttack_Conditions))
    call TriggerAddAction(gg_trg_Crash_Attack, function CrashAttack_Actions)
    
    call Preload(CrashAttack_HeroHandsEffect())
    call Preload(CrashAttack_KnockbackEffect())
    
    call DestroyFilter(f)
    set f = null
endfunction