library MissileGroup requires Table

    private function interface forMissileDo takes CustomMissile theMissile returns nothing
    private function interface onMissileEnum takes CustomMissile theMissile returns nothing

    struct MissileGroup
        private Table   stack = 0
        private Table   stackIndex = 0
        private integer index = 0
        
        public onMissileEnum onEnum = 0
        
        public static method create takes nothing returns thistype
            local thistype this = thistype.allocate()
            
            set .stack = Table.create()
            set .stackIndex = Table.create()
            
            return this
        endmethod
        
        method operator [] takes integer index returns CustomMissile
            return .stack[index]
        endmethod
        
        public method amount takes nothing returns integer
            return .index
        endmethod
        
        public method add takes CustomMissile theMissile returns nothing
            if .stackIndex.exists(theMissile.ID) then
                return
            endif
            
            set .stack[.index] = integer(theMissile)
            set .stackIndex[theMissile.ID] = .index
            set .index = .index +1
            call .onEnum.execute(theMissile)
        endmethod
        
        public method run takes forMissileDo theFunc returns nothing
            local integer i = 0
            
            loop
                exitwhen i >= .index
                
                call theFunc.execute(CustomMissile(.stack[i]))
                set i = i +1
            endloop
        endmethod
        
        public method remove takes CustomMissile theMissile returns nothing
            local integer i = 0
            
            if .stackIndex.exists(theMissile.ID) then
                set i = .stackIndex[theMissile.ID]
                call .stackIndex.flush(theMissile.ID)
                
                set .stack[i]                       = .stack[.index -1]
                set .stackIndex[CustomMissile(.stack[i]).ID] = i
                set .index                          = .index -1
            endif
        endmethod
        
        public method clear takes nothing returns nothing
            local integer i = 0
            
            loop
                exitwhen i >= .index
                
                call .stackIndex.flush(CustomMissile(.stack[i]).ID)
                call .stack.flush(i)
                set i = i +1
            endloop
            
            set .index = 0
        endmethod
        
        public method inGroup takes CustomMissile theMissile returns boolean
            return .stackIndex.exists(theMissile.ID)
        endmethod
        
        private method onDestroy takes nothing returns nothing
            call .clear()
        endmethod
    endstruct
endlibrary