function Trig_Arrows_New_Conditions takes nothing returns boolean
return GetSpellAbilityId() == 'A000'
endfunction

function Arrows_M takes nothing returns nothing
local timer t=GetExpiredTimer()
local integer id=GetHandleId(t)
local unit dammi=LoadUnitHandle(udg_ah,id,0)
local real distance=LoadReal(udg_ah,id,1)
local real angle=LoadReal(udg_ah,id,2)
local integer level=LoadInteger(udg_ah,id,3)
local unit dammicaster
local group g
local unit f
local real x=GetUnitX(dammi)
local real y=GetUnitY(dammi)
// ниже идет проверка,не прилетел ли снаряд к цели или не вылетел ли он за карту
if distance<10. or IsTerrainPathable(x+20.*Cos(angle),y+20.*Sin(angle),PATHING_TYPE_FLYABILITY)==true then
    call KillUnit(dammi)
    call PauseTimer(t)
    call DestroyTimer(t)
    call FlushChildHashtable(udg_ah,id)
else// если не вылетел то двигаем его,уменьшаем его дистанцию полета и сохраняем
    call SetUnitX(dammi,x+20.*Cos(angle))
    call SetUnitY(dammi,y+20.*Sin(angle))
    set distance=distance-20.
    call SaveReal(udg_ah,id,1,distance)
    set g=CreateGroup()// создаём группу для проверки,не находится ли кто рядом со снарядом
    call GroupEnumUnitsInRange(g,x,y,100.,null)
loop
    set f=FirstOfGroup(g)// выбираем первого из групы,если подходит условиям то дамажим,станим,убиваем снаряд,чистим группу
exitwhen f==null
if IsPlayerEnemy(GetOwningPlayer(dammi),GetOwningPlayer(f)) and GetWidgetLife(f)>0.405 and not IsUnitType(f,UNIT_TYPE_STRUCTURE) and not IsUnitType(f,UNIT_TYPE_MAGIC_IMMUNE) then
    call KillUnit(dammi)
    call PauseTimer(t)
    call DestroyTimer(t)
    call FlushChildHashtable(udg_ah,id)
    set dammicaster=CreateUnit(GetOwningPlayer(dammi),'n001',x,y,0)
    call UnitAddAbility(dammicaster,'A001')
    call SetUnitAbilityLevel(dammicaster,'A001',level)
    call IssueTargetOrder(dammicaster,"thunderbolt",f)
    call UnitApplyTimedLife(dammicaster,'BTLF',0.5)
    call UnitDamageTarget(dammi,f,level*50.,true,false,ATTACK_TYPE_CHAOS,DAMAGE_TYPE_NORMAL,null)
    call GroupClear(g)
else//если не подходит то просто удаляем как ненужный хлам
    call GroupRemoveUnit(g,f)
endif
endloop
    call DestroyGroup(g)//удаляем созданную группу(очистив её до этого)
endif
set dammi=null
set dammicaster=null
set t=null
set g=null
set f=null
endfunction

function Trig_Arrows_New_Actions takes nothing returns nothing
local unit caster=GetTriggerUnit()
local integer level=GetUnitAbilityLevel(caster,'A000')
local real x=GetUnitX(caster)
local real y=GetUnitY(caster)
local unit dammi
local real tx
local real ty
local real distance
local real angle=0.523598775// это число соответствует 30 градусам,только в радианах
//(для последующей работы с косинусом и синусом без всяких bj_DEGTORAD или CosBJ Sin BJ)
local timer t
local integer id
local integer i=1
loop
exitwhen i>12/* создаём в цикле 12 снарядов,устанавливаем и сохраняем для каждого угол,
дистанцию,уровень способности и запускаем свои таймеры*/
    set dammi=CreateUnit(GetOwningPlayer(caster),'n000',x,y,30.*i)
    set tx=x+500.*Cos(angle*i)
    set ty=y+500.*Sin(angle*i)
    set distance=SquareRoot((tx - x) * (tx - x) + (ty - y) * (ty - y))
    set t=CreateTimer()
    set id=GetHandleId(t)
    call SaveUnitHandle(udg_ah,id,0,dammi)
    call SaveReal(udg_ah,id,1,distance)
    call SaveReal(udg_ah,id,2,angle*i)
    call SaveInteger(udg_ah,id,3,level)
    call TimerStart(t,0.03,true,function Arrows_M)
set i=i+1
endloop
set caster=null
set t=null
set dammi=null
endfunction

//===========================================================================
function InitTrig_Arrows_New takes nothing returns nothing
    set udg_ah=InitHashtable()
    set gg_trg_Arrows_New = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Arrows_New, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Arrows_New, Condition( function Trig_Arrows_New_Conditions ) )
    call TriggerAddAction( gg_trg_Arrows_New, function Trig_Arrows_New_Actions )
endfunction