Creep Respawn With Replace

library ResetUnit initializer Init

globals
    ///
    private constant boolean InitReset = true
    private constant real Period = 60.0
    ///
    private resun array Allun
    private integer Countun = 0
    private group GG = CreateGroup()
endglobals
  
struct resun
    private integer idx
         
    unit u
    private integer t
    private player p
    
    private real sX
    private real sY
    private real sA
                                             
    method Create takes nothing returns nothing
        set .u = CreateUnit(.p, .t, .sX, .sY, .sA)
        call SetUnitUserData(.u, this)
    endmethod       
                                     
    method Delete takes nothing returns nothing
        call SetUnitUserData(.u, 0)
        set Countun = Countun - 1
        set Allun[.idx] = Allun[Countun]     
        set Allun[.idx].idx = .idx
        call .destroy()
    endmethod
        
    static method New takes unit u returns nothing
        local resun this = resun.create()
        set .u = u
        set .t = GetUnitTypeId(u)
        set .p = GetOwningPlayer(u)                               
        set .sX = GetUnitX(u)
        set .sY = GetUnitY(u)
        set .sA = GetUnitFacing(u)
        set Allun[Countun] = this     
        set Allun[Countun].idx = Countun
        set Countun = Countun + 1
        call SetUnitUserData(u, this) 
    endmethod
        
endstruct

public function UnitAdd takes unit u returns nothing
    local resun un = GetUnitUserData(u) 
    if (un.u != u) then
        call resun.New(u)
    endif
endfunction

public function UnitRemove takes unit u returns nothing
    local resun un = GetUnitUserData(u) 
    if (un.u == u) then
        call un.Delete()
    endif
endfunction
     
private function ResetUnit_ForAllUnit takes nothing returns boolean
    local player pf = GetOwningPlayer(GetFilterUnit())
    if (pf == Player(10) or pf == Player(11)) then
        call UnitAdd(GetFilterUnit())
    endif
    return false
endfunction
             
private function ResetUnit_Action_Timer takes nothing returns nothing
    local resun un = R2I(TimerGetRemaining(GetExpiredTimer())+0.5)
    if (GetUnitUserData(un.u) == un) then
        call un.Create()
    endif
    call DestroyTimer(GetExpiredTimer())
endfunction

private function ResetUnit_Action takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local timer t
    local resun un = GetUnitUserData(u) 
    if (un.u == u) then
        set t = CreateTimer()
        call TimerStart(t, un, false, null)
        call PauseTimer(t)
        call TimerStart(t, Period, false, function ResetUnit_Action_Timer)
        set t = null
    endif
    set u = null
endfunction
    
private function Init takes nothing returns nothing
    local trigger trig = CreateTrigger()
    if (InitReset) then
        call GroupEnumUnitsInRect(GG, bj_mapInitialPlayableArea, Filter(function ResetUnit_ForAllUnit))
    endif
    call TriggerRegisterPlayerUnitEvent(trig, Player(10), EVENT_PLAYER_UNIT_DEATH, null)
    call TriggerRegisterPlayerUnitEvent(trig, Player(11), EVENT_PLAYER_UNIT_DEATH, null)
    call TriggerAddAction(trig, function ResetUnit_Action)
    set trig = null
endfunction

endlibrary

// глобалки
InitReset - включает/выключает библиотеку.
Period - устанавливает время респавна
// функции
ResetUnit_UnitAdd(unit) - добавляет юнита в список воскрешаемых
ResetUnit_UnitRemove(unit) - убирает юнита из списка воскрешаемых.