offline
Опыт:
8,025
Активность:
|
делал для карты скилы, но к сожалению не пригодились, и по этому выкладываю, мб кому и пригодятся...
Название: Ex
Метод исполнения: vjass+cjass
Нужен ли JNGP: +
Тип цели: область
Описание: герой насылает в указанную область небольшое кол-во огненный шаров летящих по параболе, и наносящих урон в области. Каждый шар наносит по ~15ед урона в радиусе 150
» code
scope Fire initializer Init{
include "cj_types_priv.j"
define{
private SpellId ='Z003'//айди скила
private DummyId ='h003'//айди даммика
private Min =25//не важно
private NUM =30//кол-во даммиков
private periodic =0.05//периодпоявления
private AoE =150//радиус нанесения урона
private DmG =15//урон
private EFFECT ="Abilities\\Weapons\\PhoenixMissile\\Phoenix_Missile.mdl"//"Abilities\\Weapons\\DemolisherFireMissile\\DemolisherFireMissile.mdl"
//||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
private clear = flush locals
private Dist(x1,y1,x2,y2)={SquareRoot((x2-x1)*(x2-x1)+(y2-y1)*(y2-y1))}
}
private unit CAST
private unit DUMMY
private struct Spell{
unit cast,dummy
real x,y,d,m_d,a
static method onDamage takes nothing returns boolean
unit u = GetFilterUnit()
if IsUnitEnemy(CAST, GetOwningPlayer(u)) and GetWidgetLife(u) > 0.405 and not IsUnitType(u, UNIT_TYPE_STRUCTURE) and not IsUnitType(u, UNIT_TYPE_MECHANICAL) then
UnitDamageTarget(CAST, u, DmG , false, false, ATTACK_TYPE_HERO, DAMAGE_TYPE_FIRE, null)
endif
clear
return false
endmethod
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
if r.d>Min
r.d-=15
SetUnitX(r.dummy,GetUnitX(r.dummy)+15*Cos(r.a))
SetUnitY(r.dummy,GetUnitY(r.dummy)+15*Sin(r.a))
SetUnitFlyHeight(r.dummy,(4.*350/r.m_d)*(r.m_d-r.d)*(r.d/r.m_d),0)
else
CAST=r.cast
DestroyEffect(AddSpecialEffect(EFFECT,GetUnitX(r.dummy), GetUnitY(r.dummy)))
GroupEnumUnitsInRange(bj_lastCreatedGroup, GetUnitX(r.dummy), GetUnitY(r.dummy), AoE, Filter(function thistype.onDamage))
RemoveUnit(r.dummy)
ReleaseTimer(t)
endif
clear
endmethod
static method onCreate takes unit dummy,location p,unit caster returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.cast=caster
r.x=GetLocationX(p)+GetRandomReal(-300,300)*Cos(GetRandomReal(0,360))
r.y=GetLocationY(p)+GetRandomReal(-300,300)*Sin(GetRandomReal(0,360))
r.d=Dist(r.x,r.y,GetUnitX(r.cast),GetUnitY(r.cast))
r.m_d=r.d
r.a=Atan2(r.y-GetUnitY(r.cast),r.x-GetUnitX(r.cast))
r.dummy=dummy
SetTimerData(t,r)
TimerStart(t, 0.03125, true, function thistype.onAction)
clear
return r
endmethod
}
private struct CreateUnits{
unit cast,dummy
int num
location p
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
if r.num>0
r.num--
r.dummy=CreateUnit(GetOwningPlayer(r.cast),DummyId,GetUnitX(r.cast),GetUnitY(r.cast),GetUnitFacing(r.cast))
Spell.onCreate(r.dummy,r.p,r.cast)
else
ReleaseTimer(t)
endif
clear
endmethod
static method onCreate takes unit caster,location p returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.cast=caster
r.p=p
r.num=NUM
SetTimerData(t,r)
TimerStart(t, periodic, true, function thistype.onAction)
clear
return r
endmethod
}
private bool Cond(){
if GetSpellAbilityId()==SpellId then
location p=GetSpellTargetLoc()
unit u=GetTriggerUnit()
DestroyEffect(AddSpecialEffectTarget(EFFECT,u,"weapon"))
CreateUnits.onCreate(u,p)
clear
endif
return false
}
private void Init(){
trigger t=CreateTrigger()
TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
TriggerAddCondition(t, Condition(function Cond))
clear
}
}
Название: Qu
Метод исполнения: vjass+cjass
Нужен ли JNGP: +
Тип цели: все враги, вокруг героя
Описание: герой создает ледяной круг вокруг себя, тем самым нанося всем врагам урон и замедляя их на небольшой промежуток времени
» code
scope Cold initializer Init{
include "cj_types_priv.j"
define{
private SpellId ='Z001'
private DummySpellId ='Z006'
private EFFECT ="Abilities\\Spells\\Undead\\FrostNova\\FrostNovaTarget.mdl"
//||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
private clear = flush locals
private Dist(x1,y1,x2,y2)={SquareRoot((x2-x1)*(x2-x1)+(y2-y1)*(y2-y1))}
}
private unit CAST
private struct AddEffect{
unit u
static method onAction takes void returns void
timer t=GetExpiredTimer()
thistype r = GetTimerData(t)
UnitRemoveAbility(r.u,DummySpellId)
ReleaseTimer(t)
clear
endmethod
static method onCreate takes unit u returns void
thistype r = thistype.create()
timer t = NewTimer()
r.u=u
UnitAddAbility(r.u,DummySpellId)
SetTimerData(t,r)
TimerStart(t, 3, true, function thistype.onAction)
clear
endmethod
}
private struct Spell{
unit cast
real x,y,a,face,s,d,dis,sx,sy,power
static method onDamage takes nothing returns boolean
unit u = GetFilterUnit()
if IsUnitEnemy(CAST, GetOwningPlayer(u)) and GetWidgetLife(u) > 0.405 and not IsUnitType(u, UNIT_TYPE_STRUCTURE) and not IsUnitType(u, UNIT_TYPE_MECHANICAL) then
UnitDamageTarget(CAST, u, 100+50*GetUnitAbilityLevel(CAST,SpellId) , false, false, ATTACK_TYPE_HERO, DAMAGE_TYPE_COLD, null)
DestroyEffect(AddSpecialEffect(EFFECT,GetUnitX(u), GetUnitY(u)))
AddEffect.onCreate(u)
endif
clear
return false
endmethod
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
if r.d>0
if r.s>0
r.d-=r.s
r.a=r.face
else
r.d+=r.s
r.a=r.face-180*bj_DEGTORAD
endif
r.x+=r.s*Cos(r.face)
r.y+=r.s*Sin(r.face)
DestroyEffect(AddSpecialEffect(EFFECT,r.x,r.y))
else
if r.power<650
r.x=r.sx+r.dis*Cos(r.a)
r.y=r.sy+r.dis*Sin(r.a)
if r.s>0
r.a+=r.s
r.power+=r.s
else
r.a-=r.s
r.power-=r.s
endif
DestroyEffect(AddSpecialEffect(EFFECT,r.x,r.y))
else
CAST=r.cast
GroupEnumUnitsInRange(bj_lastCreatedGroup, r.sx, r.sy, r.dis, Filter(function thistype.onDamage))
ReleaseTimer(t)
endif
endif
clear
endmethod
static method onCreate takes unit cast,real s,real face,real x,real y returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.cast=cast
r.x=x
r.y=y
r.sx=x
r.sy=y
r.d=500
r.dis=r.d
r.s=s
r.power=0
r.face=face
/*if s>0
r.a=face-90*bj_DEGTORAD
else
r.a=face+90*bj_DEGTORAD
endif*/
SetTimerData(t,r)
TimerStart(t, 0.07, true, function thistype.onAction)
clear
return r
endmethod
}
private struct CreateUnits{
unit cast
real x,y,a
int i
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
if r.i>0
if r.i==2
Spell.onCreate(r.cast,50,r.a,r.x,r.y)
elseif r.i==1
Spell.onCreate(r.cast,-50,r.a,r.x,r.y)
endif
r.i--
else
ReleaseTimer(t)
endif
clear
endmethod
static method onCreate takes unit caster returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.cast=caster
r.x=GetUnitX(caster)
r.y=GetUnitY(caster)
r.a=GetUnitFacing(caster)*bj_DEGTORAD
r.i=2
SetTimerData(t,r)
TimerStart(t, 0.01, true, function thistype.onAction)
clear
return r
endmethod
}
private bool Cond(){
if GetSpellAbilityId()==SpellId then
location p=GetSpellTargetLoc()
unit u=GetTriggerUnit()
CreateUnits.onCreate(u)
clear
endif
return false
}
private void Init(){
trigger t=CreateTrigger()
TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
TriggerAddCondition(t, Condition(function Cond))
clear
}
}
Название: We
Метод исполнения: vjass+cjass
Нужен ли JNGP: +
Тип цели: область
Описание: герой пускает цепную молнию в указанного юнита, которая связывает 5 юнитов в месте (т.е они не могут уйти дальше чем были в момент связки)
» code
scope Staff /*
Spell
Created
By
Jumper
*/ initializer Init{
include "cj_types_priv.j"
define{
private SpellId ='Z002'//айди скила
private LightId ="CLPB"
private LightId2 ="CHIM"
private Periodic =.55
//||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
private clear = flush locals
private Dist(x1,y1,x2,y2)={SquareRoot((x2-x1)*(x2-x1)+(y2-y1)*(y2-y1))}
}
private unit CAST
private unit TARG
private unit array unit_array
private group G
private struct Move{
unit cast,targ
real d,dis
lightning l
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
if r.d>0 and GetWidgetLife(r.cast)>0.145 and GetWidgetLife(r.targ)>0.145
r.d-=0.03125
real x1=GetUnitX(r.cast),y1=GetUnitY(r.cast),x2=GetUnitX(r.targ),y2=GetUnitY(r.targ),d=Dist(x1,y1,x2,y2)
if d>r.dis
real a=Atan2(y1-y2, x1-x2)
SetUnitX(r.cast,x1-(GetUnitMoveSpeed(r.cast)*0.03125)*Cos(a))
SetUnitY(r.cast,y1-(GetUnitMoveSpeed(r.cast)*0.03125)*Sin(a))
a=Atan2(y2-y1, x2-x1)
SetUnitX(r.targ,x2-(GetUnitMoveSpeed(r.targ)*0.03125)*Cos(a))
SetUnitY(r.targ,y2-(GetUnitMoveSpeed(r.targ)*0.03125)*Sin(a))
endif
MoveLightningEx(r.l,true,x1,y1,GetUnitFlyHeight(r.cast),x2,y2,GetUnitFlyHeight(r.targ))
else
DestroyLightning(r.l)
ReleaseTimer(t)
endif
clear
endmethod
static method onCreate takes unit cast,unit targ returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.cast=cast
r.targ=targ
real x1=GetUnitX(r.cast),y1=GetUnitY(r.cast),x2=GetUnitX(r.targ),y2=GetUnitY(r.targ),d=Dist(x1,y1,x2,y2)
r.dis=d
r.d=10
r.l=AddLightningEx(LightId2,true,GetUnitX(cast),GetUnitY(cast),GetUnitFlyHeight(cast),GetUnitX(targ),GetUnitY(targ),GetUnitFlyHeight(targ))
SetTimerData(t,r)
TimerStart(t, 0.03125, true, function thistype.onAction)
clear
return r
endmethod
}
private struct AL{
unit u1,u2,cast
lightning l
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
DestroyLightning(r.l)
if r.u1!=r.cast and r.u2!=r.cast
Move.onCreate(r.u1,r.u2)
endif
ReleaseTimer(t)
clear
endmethod
static method onCreate takes unit cast,unit targ,unit CASTER returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.u1=cast
r.u2=targ
r.cast=CASTER
DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\ChimaeraLightningMissile\\ChimaeraLightningMissile.mdl",cast,"origin"))
DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\ChimaeraLightningMissile\\ChimaeraLightningMissile.mdl",targ,"origin"))
r.l=AddLightningEx(LightId,true,GetUnitX(cast),GetUnitY(cast),GetUnitFlyHeight(cast),GetUnitX(targ),GetUnitY(targ),GetUnitFlyHeight(targ))
SetTimerData(t,r)
TimerStart(t, 0.45, true, function thistype.onAction)
clear
return r
endmethod
}
private struct Spell{
unit cast,targ
int ts
group GROUP
static method onDamage takes nothing returns boolean
unit u = GetFilterUnit()
return IsUnitEnemy(CAST, GetOwningPlayer(u)) and GetWidgetLife(u) > 0.405 and not IsUnitType(u, UNIT_TYPE_STRUCTURE) and not IsUnitType(u, UNIT_TYPE_MECHANICAL) and GetHandleId(u)!=GetHandleId(TARG) and IsUnitInGroup(u,G)!=true
endmethod
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
if r.targ!=null and r.ts>0
r.ts--
group g=CreateGroup()
CAST=r.cast
TARG=r.targ
G=r.GROUP
GroupEnumUnitsInRange(g, GetUnitX(r.targ), GetUnitY(r.targ), 500, Filter(function thistype.onDamage))
unit T=GroupPickRandomUnit(g)//GetRndUnit(g)
r.GROUP=G
if T!=null and T!=r.targ
AL.onCreate(r.targ,T,r.cast)
r.targ=T
UnitDamageTarget(r.cast,r.targ,70+50*GetUnitAbilityLevel(r.cast,SpellId),true,true,null,null,null)
GroupAddUnit(r.GROUP,r.targ)
elseif T==null
DestroyGroup(r.GROUP)
ReleaseTimer(t)
elseif T==r.targ
DestroyGroup(r.GROUP)
ReleaseTimer(t)
endif
G=null
else
DestroyGroup(r.GROUP)
ReleaseTimer(t)
endif
clear
endmethod
static method onCreate takes unit caster,unit target returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.cast=caster
r.targ=target
r.ts=3+2*GetUnitAbilityLevel(caster,SpellId)
r.GROUP=CreateGroup()
GroupAddUnit(r.GROUP,target)
UnitDamageTarget(r.cast,r.targ,70+50*GetUnitAbilityLevel(r.cast,SpellId),true,true,null,null,null)
SetTimerData(t,r)
TimerStart(t, 0.4, true, function thistype.onAction)
clear
return r
endmethod
}
private bool Cond(){
if GetSpellAbilityId()==SpellId then
unit u=GetTriggerUnit(),t=GetSpellTargetUnit()
Spell.onCreate(u,t)
AL.onCreate(u,t,u)
clear
endif
return false
}
private void Init(){
trigger t=CreateTrigger()
TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
TriggerAddCondition(t, Condition(function Cond))
clear
}
}
Название: Ul
Метод исполнения: vjass+cjass
Нужен ли JNGP: +
Тип цели: область
Описание: Кастер насылает на врага 3 сферы, который в течении небольшого периода начинают летать вокруг цели, нанося урон, замедляя, и снижая защиту
» code
scope Ultimate initializer Init{
include "cj_types_priv.j"
define{
private SpellId='Z004'
private DummySpellId1='Z005'
private DummySpellId2='Z006'
private DummyId1='h000'
private DummyId2='h001'
private DummyId3='h002'
private LIGHTId1="DRAM"
private LIGHTId2="DRAM"
private LIGHTId3="DRAM"
private clear=flush locals
}
//private hashtable h=InitHashtable()
private struct AddEffect{
unit u,d,cast
real Angle,AX,AY,AZ,r,s,c,dmg
int i
lightning array l[3]
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
real xu,yu,xc,yc,a,ax,ay,az,zu,zc
if GetWidgetLife(r.u)>0.145
if r.d==null
UnitRemoveAbility(r.u,'Basl')
UnitRemoveAbility(r.u,DummySpellId1)
UnitRemoveAbility(r.u,DummySpellId2)
ReleaseTimer(t)
else
xu = GetUnitX(r.d)
yu = GetUnitY(r.d)
xc = GetUnitX(r.u)
yc = GetUnitY(r.u)
zu = GetUnitFlyHeight(r.d)
zc = GetUnitFlyHeight(r.u)+50
a = r.Angle
ax = r.AX
ay = r.AY
az = r.AZ
xu = xc + r.r*SinBJ(a+r.s)*CosBJ(ax)
if az > 0
yu = yc + r.r*CosBJ(a+r.s)*SinBJ(ay)
else
yu = yc + r.r*SinBJ(a+r.s)*CosBJ(ay)
endif
zu = zc + r.r*CosBJ(a+r.s)*CosBJ(az)
SetUnitX(r.d,xu)
SetUnitY(r.d,yu)
SetUnitFlyHeight(r.d,zu,0.00)
UnitAddAbility(r.u,DummySpellId1)
UnitAddAbility(r.u,DummySpellId2)
r.Angle = r.Angle + r.s
if r.Angle >= 360
r.Angle = 0
endif
if r.c<0.7
r.s+=0.05
r.r+=.3
r.c+=0.004
SetUnitScale(r.d,r.c,r.c,r.c)
UnitDamageTarget(r.d,r.u,r.dmg,true,false,ATTACK_TYPE_MAGIC,DAMAGE_TYPE_MAGIC,null)
else
UnitRemoveAbility(r.u,'Basl')
UnitRemoveAbility(r.u,DummySpellId1)
UnitRemoveAbility(r.u,DummySpellId2)
RemoveUnit(r.d)
r.d=null
ReleaseTimer(t)
endif
endif
//unit asd=LoadUnitHandle(h,GetHandleId(r.u),r.i)
//MoveLightningEx(r.l[r.i],true,xu,yu,zu,GetUnitX(asd),GetUnitY(asd),GetUnitFlyHeight(asd))
else
if r.d!=null
RemoveUnit(r.d)
r.d=null
endif
endif
clear
endmethod
static method onCreate takes unit u,int i,unit tt returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.u=tt
r.cast=u
if i==2
r.d=CreateUnit(GetOwningPlayer(u),DummyId1,GetUnitX(tt),GetUnitY(tt),0)
r.Angle=180
r.AX=0
r.AY=90
r.AZ=0
//r.l[i]=AddLightningEx(LIGHTId1,true,GetUnitX(tt),GetUnitY(tt),0,GetUnitX(tt),GetUnitY(tt),0)
//SaveUnitHandle(h,GetHandleId(tt),1,r.d)
elseif i==1
r.d=CreateUnit(GetOwningPlayer(u),DummyId2,GetUnitX(tt),GetUnitY(tt),0)
r.Angle=0
r.AX=90
r.AY=0
r.AZ=0
//r.l[i]=AddLightningEx(LIGHTId2,true,GetUnitX(tt),GetUnitY(tt),0,GetUnitX(tt),GetUnitY(tt),0)
//SaveUnitHandle(h,GetHandleId(tt),0,r.d)
elseif i==0
r.d=CreateUnit(GetOwningPlayer(u),DummyId3,GetUnitX(tt),GetUnitY(tt),0)
r.Angle=90
r.AX=0
r.AY=90
r.AZ=90
//r.l[i]=AddLightningEx(LIGHTId3,true,GetUnitX(tt),GetUnitY(tt),0,GetUnitX(tt),GetUnitY(tt),0)
//SaveUnitHandle(h,GetHandleId(tt),2,r.d)
endif
r.dmg=(30+10*GetUnitAbilityLevel(r.u,SpellId))*0.03125
r.r=50
r.s=5
//SetLightningColor(r.l[i],1,1,1,0)
r.i=i
SetTimerData(t, r)
TimerStart(t, 0.03125, true, function thistype.onAction)
clear
return r
endmethod
}
private struct Creating{
unit u,t
int i
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
if r.i>=0
r.i-=1
AddEffect.onCreate(r.u,r.i,r.t)
else
ReleaseTimer(t)
endif
clear
endmethod
static method onCreate takes unit u,unit tt returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.u=u
r.t=tt
r.i=3
SetTimerData(t, r)
TimerStart(t, 0., true, function thistype.onAction)
clear
return r
endmethod
}
private bool Con(){
if GetSpellAbilityId()==SpellId
unit u=GetTriggerUnit(),t=GetSpellTargetUnit()
Creating.onCreate(u,t)
endif
clear
return false
}
private void Init(){
trigger t=CreateTrigger()
TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_CAST )
TriggerAddCondition( t, Condition( function Con ) )
clear
}
}
Дополнительно: при изучении заклинаний, появляется определенная сфера, которая начинает кружить вокруг героя (просто визуальный эффект)
» code
scope LearnSkill initializer Init{
include "cj_types_priv.j"
define{
private SpellId1='Z001'
private SpellId2='Z002'
private SpellId3='Z003'
private DummyId1='h000'
private DummyId2='h001'
private DummyId3='h002'
private clear=flush locals
}
private struct AddEffect{
unit u,d
real Angle,AX,AY,AZ
int i
static method onAction takes void returns void
timer t = GetExpiredTimer()
thistype r = GetTimerData(t)
real xu,yu,xc,yc,a,ax,ay,az,zu,zc
if GetWidgetLife(r.u)>0.145
if r.d==null
r.d=CreateUnit(GetOwningPlayer(r.u),r.i,GetUnitX(r.u),GetUnitY(r.u),0)
else
xu = GetUnitX(r.d)
yu = GetUnitY(r.d)
xc = GetUnitX(r.u)
yc = GetUnitY(r.u)
zu = GetUnitFlyHeight(r.d)
zc = GetUnitFlyHeight(r.u)+50
a = r.Angle
ax = r.AX
ay = r.AY
az = r.AZ
xu = xc + 50*SinBJ(a+8)*CosBJ(ax)
if az > 0
yu = yc + 50*CosBJ(a+8)*SinBJ(ay)
else
yu = yc + 50*SinBJ(a+8)*CosBJ(ay)
endif
zu = zc + 50*CosBJ(a+8)*CosBJ(az)
SetUnitX(r.d,xu)
SetUnitY(r.d,yu)
SetUnitFlyHeight(r.d,zu,0.00)
r.Angle = r.Angle + 8
if r.Angle >= 360
r.Angle = 0
endif
endif
else
if r.d!=null
r.i=GetUnitTypeId(r.d)
RemoveUnit(r.d)
r.d=null
endif
endif
clear
endmethod
static method onCreate takes unit u,int i returns thistype
thistype r = thistype.create()
timer t = NewTimer()
r.u=u
if i==SpellId1
r.d=CreateUnit(GetOwningPlayer(u),DummyId1,GetUnitX(u),GetUnitY(u),0)
r.Angle=180
r.AX=0
r.AY=90
r.AZ=0
elseif i==SpellId2
r.d=CreateUnit(GetOwningPlayer(u),DummyId2,GetUnitX(u),GetUnitY(u),0)
r.Angle=0
r.AX=90
r.AY=0
r.AZ=0
elseif i==SpellId3
r.d=CreateUnit(GetOwningPlayer(u),DummyId3,GetUnitX(u),GetUnitY(u),0)
r.Angle=90
r.AX=0
r.AY=90
r.AZ=90
endif
SetTimerData(t, r)
TimerStart(t, 0.03125, true, function thistype.onAction)
clear
return r
endmethod
}
private bool Con(){
unit u=GetTriggerUnit()
if GetLearnedSkill()==SpellId1 and GetUnitAbilityLevel(u,SpellId1)==1
AddEffect.onCreate(u,SpellId1)
elseif GetLearnedSkill()==SpellId2 and GetUnitAbilityLevel(u,SpellId2)==1
AddEffect.onCreate(u,SpellId2)
elseif GetLearnedSkill()==SpellId3 and GetUnitAbilityLevel(u,SpellId3)==1
AddEffect.onCreate(u,SpellId3)
endif
clear
return false
}
private void Init(){
trigger t=CreateTrigger()
TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_HERO_SKILL )
TriggerAddCondition( t, Condition( function Con ) )
clear
}
}
|
26.08.2011, 19:25
