offline
Опыт:
8,025
Активность:
|
Название: Скил-стил
Метод исполнения: cJass
Нужен ли JNGP: yes
Количество уровней: 1(ну в принципе хоть сколько)
Описание: Герой копирует последнее примененное врагом заклинание на небольшой промежуток времени, если герой умирает, то он теряет приобретенный скилл
» код
scope SpellSteal initializer init {
include "cj_types_priv.j"
//==========================================
define {
private SPELL_ID='A000'
//id скила
private DUMMY_ID='h000'
//id даммика
private COLOR="|c00B400FF"
//цвет текста
private DURATION=10
//време действия
private DURATION_INC=5
//повышение действия за уровень(1 уровень 15 сек)
private DUMMY_EFFECT="Abilities\\Spells\\NightElf\\TargetArtLumber\\TargetArtLumber.mdl"
//модель даммика
private TARGET_EFFECT="Abilities\\Spells\\Human\\ThunderClap\\ThunderClapCaster.mdl"
//эффект на цель
private CAST_EFFECT="Abilities\\Spells\\Human\\DispelMagic\\DispelMagicTarget.mdl"
//эффект при получении скила
private SPEED=20
//скорость движения (20/0.035=570)
private periodic=0.035
//перод движения
private HEIGHT=50
//высота двжиения даммика
}
//==========================================
private hashtable HASH=InitHashtable()
private group GROUP=CreateGroup()
//==========================================
private void spell_timer(){
timer t=GetExpiredTimer()
int i=GetHandleId(t)
int s=LoadInteger(HASH,i,1)
unit u=LoadUnitHandle(HASH,i,2)
UnitRemoveAbility(u,s)
FlushChildHashtable(HASH,i)
DestroyTimer(t)
t=null
u=null
}
//==========================================
private bool cond () {
return GetSpellAbilityId() == SPELL_ID
}
//==========================================
private void motion(){
unit u=GetEnumUnit(),c=LoadUnitHandle(HASH,GetHandleId(u),1)
int spell=LoadInteger(HASH,GetHandleId(u),2),lvl=LoadInteger(HASH,GetHandleId(u),3)
timer T
texttag text
real x=GetUnitX(u),y=GetUnitY(u),X=GetUnitX(c),Y=GetUnitY(c),a=Atan2(Y-y,X-x),d=SquareRoot((X - x) * (X - x) + (Y - y) * (Y - y))
if d>SPEED then
SetUnitX(u, x+SPEED*Cos(a))
SetUnitY(u, y+SPEED*Sin(a))
else
int dbg=LoadInteger(HASH,GetHandleId(c),1)
UnitRemoveAbility(c,dbg)
UnitAddAbility(c,spell)
SetUnitAbilityLevel(c,spell,lvl)
GroupRemoveUnit(GROUP,u)
RemoveUnit(u)
FlushChildHashtable(HASH,GetHandleId(u))
T=CreateTimer()
TimerStart(T, (DURATION+DURATION_INC*GetUnitAbilityLevel(c,SPELL_ID)), true, function spell_timer)
SaveInteger(HASH,GetHandleId(T),1,spell)
SaveInteger(HASH,GetHandleId(c),1,spell)
SaveUnitHandle(HASH,GetHandleId(T),2,c)
DestroyEffect(AddSpecialEffect(CAST_EFFECT,GetUnitX(c),GetUnitY(c)))
//
text = CreateTextTag()
SetTextTagText(text, COLOR+GetObjectName(spell), 0.023)
SetTextTagPosUnit(text, c, 15)
SetTextTagColor(text, 255, 255, 255, 255)
SetTextTagVelocity(text, 0.0355 * Cos(90.0 * bj_DEGTORAD), 0.0355 * Sin(90.0 * bj_DEGTORAD))
SetTextTagPermanent(text, false)
SetTextTagAge(text, 0.0)
SetTextTagFadepoint(text, 1.)
SetTextTagLifespan(text, 1.7)
endif
u=null
c=null
T=null
text=null
}
//==========================================
private void forgroup(){
ForGroup(GROUP,function motion)
}
//==========================================
private void main(){
unit cast=GetTriggerUnit(),targ=GetSpellTargetUnit(),dummy
int cast_i=GetHandleId(cast),targ_i=GetHandleId(targ),spell=LoadInteger(HASH,targ_i,0)
if spell != 0 then
dummy=CreateUnit(GetOwningPlayer(cast),DUMMY_ID, GetUnitX(targ),GetUnitY(targ),0)
SetUnitFlyHeight(dummy,HEIGHT,0)
SaveUnitHandle(HASH,GetHandleId(dummy),1,cast)
SaveInteger(HASH,GetHandleId(dummy),2,spell)
SaveInteger(HASH,GetHandleId(dummy),3,GetUnitAbilityLevel(targ,spell))
GroupAddUnit(GROUP,dummy)
DestroyEffect(AddSpecialEffect(TARGET_EFFECT,GetUnitX(targ),GetUnitY(targ)))
AddSpecialEffectTarget(DUMMY_EFFECT,dummy,"origin")
endif
cast=null
targ=null
dummy=null
}
//==========================================
private void save(){
unit u=GetTriggerUnit()
int i=GetHandleId(u),spell=GetSpellAbilityId()
SaveInteger(HASH,i,0,spell)
u=null
}
//==========================================
private void death(){
unit u=GetTriggerUnit()
int i=GetHandleId(u),spell=LoadInteger(HASH,i,1)
UnitRemoveAbility(u,spell)
u=null
}
//==========================================
private void init (){
trigger t=CreateTrigger(),t2=CreateTrigger(),t3=CreateTrigger()
int i=0
timer T=CreateTimer()
TimerStart(T,periodic,true,function forgroup)
loop
TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_UNIT_SPELL_CAST, null)
TriggerRegisterPlayerUnitEvent(t2, Player(i), EVENT_PLAYER_UNIT_SPELL_CAST, null)
TriggerRegisterPlayerUnitEvent(t3, Player(i), EVENT_PLAYER_UNIT_DEATH, null)
i += 1
exitwhen i == 15
endloop
TriggerAddCondition(t, Condition( function cond ) )
TriggerAddAction(t, function main )
TriggerAddAction(t2, function save )
TriggerAddAction(t3, function death )
t=null
t2=null
T=null
}
}
Отредактировано youtube, 04.05.2011 в 14:17.
|
25.04.2011, 19:58
