Прочитаешь всё это, и поймешь, что Sleep вообще не нужен, ибо есть таймеры, как говорится, на все случаи жизни.

Я никак не могу взять в толк, как таймером заменить TriggerSleepAction? Если запустить таймер, а потом в цикле проверять закончился он или нет это остановит не функцию а всю игру.

Запускай каждую итерацию цикла в новом потоке и там уже начинай с локалок+вейта. - Это как? Ясс имеет средства управления потоками? Всмысле несколько функций могут выполнятся параллельно?

Нет, не нужно в цикле проверять закончился ли таймер, а в функции, запускаемой таймером доделывать то, что шло после слипа. Данные передаются через глобалки либо вешаются на таймер через хеш(чаще всего)

ARHUI, где ты в моих примерах видел, чтоб я циклы использовал в таймерах для их остановки?

Слип вобще нельзя никак ничем заменить, и не нужно )

Фу-ух, кажись получилось!

16Gb, у тебя в коде не было:

((код jass

set udg_AssassinHash=InitHashtable()
))

ну и я изначально не вкурил, что нужна глобалка AssassinHash.

В общем, вот внизу рабочий пример карты, который у меня получился, на джассе БЕЗ слипа (там использовал более короткую глобалку Hash), где целитель после каста хилки на 5 сек. даёт тому, на кого сказал, ясновидение вертолёта и манабурн альянсовской башни.

Код:

((код jass

function Trig_Stil_Franzy_Cast_Conditions takes nothing returns boolean
return GetSpellAbilityId() == 'Ahea'
endfunction

function StillFrenzyEffect takes nothing returns nothing
local timer t=GetExpiredTimer()
local unit u=LoadUnitHandle(udg_Hash,GetHandleId(t),2)
call UnitRemoveAbility( u,'Afbt' )
call UnitRemoveAbility( u,'Agyv' )
call FlushChildHashtable(udg_Hash,GetHandleId(t))
call DestroyTimer(t)
set t=null
set u=null
endfunction

function Trig_Stil_Franzy_Cast_Actions takes nothing returns nothing
local unit u = GetSpellTargetUnit()
local timer t = CreateTimer()
call UnitAddAbility( u, 'Afbt' )
call UnitAddAbility( u, 'Agyv' )
call SaveUnitHandle(udg_Hash,GetHandleId(t),2,u)
call TimerStart(t,5,false,function StillFrenzyEffect)
set t=null
set u=null
endfunction

===========================================================================
function InitTrig_Stil_Franzy_Cast takes nothing returns nothing
set gg_trg_Stil_Franzy_Cast = CreateTrigger( )
set udg_Hash=InitHashtable()
call TriggerRegisterAnyUnitEventBJ( gg_trg_Stil_Franzy_Cast, EVENT_PLAYER_UNIT_SPELL_EFFECT )
call TriggerAddCondition( gg_trg_Stil_Franzy_Cast, Condition( function Trig_Stil_Franzy_Cast_Conditions ) )
call TriggerAddAction( gg_trg_Stil_Franzy_Cast, function Trig_Stil_Franzy_Cast_Actions )
endfunction
))

Если никто не хочет откомментить карту ниже, можно крыть, образец, надеюсь, кому-нибудь пригодится. Спс!

Молодец, Velociraptor, ты способный ученик))