У предметов в магазине вроде таже привязка что у панели героя где находятся его скилы . www.hiveworkshop.com/threads/ui-v1-3.337753 вот посмотри.

Ну у меня без ошибки, а просто зависает на мертво, при загрузке этой части кода
Зависает из за строки

Скопировать в буфер

set Frame09 = BlzCreateFrame("CheckListBox", BlzGetOriginFrame(ORIGIN_FRAME_GAME_UI, 0),0,0)

заменил её на

Скопировать в буфер

Frame09 = BlzCreateFrameByType("CheckListBox", "", BlzGetOriginFrame(ORIGIN_FRAME_GAME_UI, 0), "", 0)

пока что ничего не происходит

---

В общем оно всё очень кривое, конкретно не создаётся этот "CheckListBox", попробуйте в этом месте создать любой прозрачный бекдроп визуаль будет тоже самое, по поводу REFORGEDUIMAKER, не пользовался, но слышал что вещь крайне кривая, да и судя по кода что она генерирует, там ничего особенного, лучше делать это без каких либо программ просто кодом, помог как смог, мб другой кто что подскажет

а если убрать call BlzFrameSetScale(Frame010, 1.00)?

Вы всё правильно делаете, оба должны полностью перезапустить игру, а твой друг должен удалить у себя все старые версии, иногда нужно ещё удалять папки, внутри dowloads, но чаще всего достаточно просто перезахода

Правильно, там же событие идёт на отлов приказа, а каст способности как отловить я написал выше )
call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_ORDER, function thistype.onOrder)
Да я тоже хотел предложить кое-что, но в том случае так же была бы проблема с включение/выключением автокаста при полёте стрелы

Тут единственный вариант сделать идеально и как тебе надо это сделать кастомные снаряды стрел и атаки, а по другому только извращения

library BlackArrow requires DamageInterface, RegisterPlayerUnitEvent, Utilities, optional WitheringFire
/* ---------------------- Black Arrow v1.0 by Chopinski --------------------- */
// Credits:
//     Magtheridon96 - RegisterPlayerUnitEvent
//     AZ            - Black Arrow model
//     Darkfang      - Arcane Arrow icon
//     YourArthas    - Skeleton Models
/* ----------------------------------- END ---------------------------------- */

/* ------------------------------ CONFIGURABLES ----------------------------- */
    globals
        // The raw code of the Black Arrow ability
        public  constant integer BLACK_ARROW       = 'A00C'
        // The raw code of the Black Arrow Curse debuff
        public  constant integer BLACK_ARROW_CURSE = 'A00D'
        // The raw code of the melee unit
        private constant integer SKELETON_WARRIOR  = 'u000'
        // The raw code of the ranged unit
        private constant integer SKELETON_ARCHER   = 'n001'
        // The raw code of the Elite unit
        private constant integer SKELETON_ELITE    = 'n000'
        // The effect created when the skelton warrior spawns
        private constant string  RAISE_EFFECT      = "Abilities\\Spells\\Undead\\RaiseSkeletonWarrior\\RaiseSkeleton.mdl"
    endglobals

    // The curse duration
    public function GetCurseDuration takes integer level returns real
        return 10.
    endfunction

    // The damage bonus when Black Arrows is active
    private function GetBonusDamage takes unit u, integer level returns real
        return (5 + 5*level) + ((0.05*level)*GetHeroAgi(u, true))
    endfunction

    // The melee sketelon health amount
    private function GetSkeletonWarriorHealth takes integer level returns integer
        return 50*(level + 6)
    endfunction

    // The melee sketelon damage amount
    private function GetSkeletonWarriorDamage takes integer level returns integer
        return 5*(level + 3)
    endfunction

    // The ranged sketelon health amount
    private function GetSkeletonArcherHealth takes integer level returns integer
        return 50*(level + 3)
    endfunction

    // The ranged sketelon damage amount
    private function GetSkeletonArcherDamage takes integer level returns integer
        return 5*(level + 6)
    endfunction

    // The sketelon duration
    private function GetSkeletonDuration takes integer level returns real
        return 15.
    endfunction

    // The max amount of skeleton warriors a unit can have
    private function GetMaxSkeletonCount takes integer level returns integer
        return 11
    endfunction

    // The elite sketelon health amount
    private function GetEliteHealth takes integer level returns integer
        return 50*(level + 11)
    endfunction

    // The elite sketelon damage amount
    private function GetEliteDamage takes integer level returns integer
        return 5*(level + 11)
    endfunction

    // The elite sketelon duration
    private function GetEliteDuration takes integer level returns real
        return 60.
    endfunction

    // How long it takes to a unit to be able to spawn Elites again after it already has the max amount
    private function GetEliteCountReset takes integer level returns real
        return 30.
    endfunction

    // The Max amount of Elites a unit can have before going into cooldown
    private function GetMaxEliteCount takes integer level returns integer
        return 2
    endfunction

    /* --------------------------------- System --------------------------------- */
    struct BlackArrow
        private static integer array counter
        private static integer array elite
        private static integer array skeletons
        private static player        owner
        static boolean array         active

        timer   t
        integer idx

        private static method onPeriod takes nothing returns nothing
            local thistype this = GetTimerData(GetExpiredTimer())

            call ReleaseTimer(t)
            set elite[idx] = 0
            set t = null
            call deallocate()
        endmethod

        private static method onOrder takes nothing returns nothing
            local unit    source = GetOrderedUnit()
            //---------------------------------------------
            local integer id     = GetIssuedOrderId()
            local integer idx    = GetUnitUserData(source)
            //---------------------------------------------

            if id == 852174 or id == 852175 then
                set active[idx] = id == 852174
                static if LIBRARY_WitheringFire then
                    if GetUnitAbilityLevel(source, WitheringFire_WITHERING_FIRE) > 0 then
                        call WitheringFire.setMissileArt(source, active[idx])
                    endif
                endif
            endif

            set source = null
        endmethod

        static method onDamage takes nothing returns nothing
            local integer  level    = GetUnitAbilityLevel(DamageI.source, BLACK_ARROW)
            local integer  manaCost = BlzGetAbilityIntegerLevelField(BlzGetUnitAbility(DamageI.source, BLACK_ARROW), ABILITY_ILF_MANA_COST, level - 1)
            //----------------------------------------------
            local boolean  hasMana  = GetUnitState(DamageI.source, UNIT_STATE_MANA) > manaCost
            //----------------------------------------------
            local real     damage   = GetEventDamage()
            //----------------------------------------------
            local unit     u
            //----------------------------------------------
            local thistype this
            //----------------------------------------------

            if active[DamageI.sIdx] and DamageI.isEnemy and not DamageI.structure and hasMana and damage > 0 then
                set owner = DamageI.sourcePlayer

                call BlzSetEventDamage(damage + GetBonusDamage(DamageI.source, level))
                if DamageI.targetIsHero then
                    set counter[DamageI.sIdx] = counter[DamageI.sIdx] + 1

                    if counter[DamageI.sIdx] >= 5 then
                        set counter[DamageI.sIdx] = 0

                        if elite[DamageI.sIdx] < GetMaxEliteCount(level) then
                            set elite[DamageI.sIdx] = elite[DamageI.sIdx] + 1 
                            set u = CreateUnit(owner, SKELETON_ELITE, DamageI.targetX, DamageI.targetY, 0)

                            call BlzSetUnitMaxHP(u, GetEliteHealth(level))
                            call BlzSetUnitBaseDamage(u, GetEliteDamage(level), 0)
                            call SetUnitLifePercentBJ(u, 100)
                            call UnitApplyTimedLife(u, 'BTLF', GetEliteDuration(level))
                            call SetUnitAnimation(u, "Birth")
                            call DestroyEffect(AddSpecialEffectEx(RAISE_EFFECT, GetUnitX(u), GetUnitY(u), GetUnitFlyHeight(u), 2))
                            
                            if elite[DamageI.sIdx] == GetMaxEliteCount(level) then
                                set this = thistype.allocate()
                                set .t   = NewTimerEx(this)
                                set .idx = DamageI.sIdx
                                call TimerStart(.t, GetEliteCountReset(level), false, function thistype.onPeriod)
                            endif
                        endif
                    endif
                endif
                call UnitAddAbilityTimed(DamageI.target, BLACK_ARROW_CURSE, GetCurseDuration(level), true)
                call SetUnitAbilityLevel(DamageI.target, BLACK_ARROW_CURSE, level)
            endif

            set u = null
        endmethod

        private static method onDeath takes nothing returns nothing
            local unit    killed   = GetTriggerUnit()
            //---------------------------------------------
            local integer level    = GetUnitAbilityLevel(killed, BLACK_ARROW_CURSE)
            local integer idx      = GetPlayerId(owner)
            local integer id       = GetUnitTypeId(killed)
            //---------------------------------------------
            local boolean ranged   = IsUnitType(killed, UNIT_TYPE_RANGED_ATTACKER)
            local boolean skeleton = id == SKELETON_WARRIOR or id == SKELETON_ARCHER
            //---------------------------------------------
            local unit    u
            local real    x
            local real    y
            //---------------------------------------------

            if skeleton then
                set idx = GetPlayerId(GetOwningPlayer(killed))
                set skeletons[idx] = skeletons[idx] - 1
            elseif level > 0 and skeletons[idx] < GetMaxSkeletonCount(level) then
                set skeletons[idx] = skeletons[idx] + 1
                set x = GetUnitX(killed)
                set y = GetUnitY(killed)
                
                if ranged then
                    set u = CreateUnit(owner, SKELETON_ARCHER, x, y, 0)
                    call BlzSetUnitMaxHP(u, GetSkeletonArcherHealth(level))
                    call BlzSetUnitBaseDamage(u, GetSkeletonArcherDamage(level), 0)
                else
                    set u = CreateUnit(owner, SKELETON_WARRIOR, x, y, 0)
                    call BlzSetUnitMaxHP(u, GetSkeletonWarriorHealth(level))
                    call BlzSetUnitBaseDamage(u, GetSkeletonWarriorDamage(level), 0)
                endif
                
                call UnitApplyTimedLife(u, 'BTLF', GetSkeletonDuration(level))
                call SetUnitLifePercentBJ(u, 100)
                call SetUnitAnimation(u, "Birth")
                call DestroyEffect(AddSpecialEffectEx(RAISE_EFFECT, GetUnitX(u), GetUnitY(u), GetUnitFlyHeight(u), 1))
            endif

            set u      = null
            set killed = null
        endmethod   

        static method onInit takes nothing returns nothing
            call RegisterAttackDamageEvent(function thistype.onDamage)
            call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_DEATH, function thistype.onDeath)
            call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_ORDER, function thistype.onOrder)
        endmethod
    endstruct
endlibrary

call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, function thistype.onOrderTarg)


        private static method onOrderTarg takes nothing returns nothing
            local unit    source = GetOrderedUnit()
            //---------------------------------------------
            local integer id     = GetIssuedOrderId()
            local integer idx    = GetUnitUserData(source)
            //---------------------------------------------

            if id == 852173  then
                set active[idx] = id == 852173  // Тут типо order c flamingarrowtarg
            endif

            set source = null
        endmethod