Библиотека заклинаний

library Spiral initializer Init

struct rotation
real x1
real y1
real z1
real x2
real y2
real z2

method dist takes nothing returns real
return SquareRoot((.x2-.x1)*(.x2-.x1)+(.y2-.y1)*(.y2-.y1))
endmethod

method AxisX takes real a,real d returns nothing
if d==0.00 then
 set .y2=.y1+(.y2-.y1)*CosBJ(a)+(.z2-.z1)*SinBJ(a)
 set .z2=.z1+(.z2-.z1)*CosBJ(a)-(.y2-.y1)*SinBJ(a)
else
 set .x2=.x1
 set .y2=.y1+d*CosBJ(a)
 set .z2=.z1+d*SinBJ(a)
 endif
endmethod

method AxisY takes real a,real d returns nothing
if d==0.00 then
 set .x2=.x1+(.x2-.x1)*CosBJ(a)-(.z2-.z1)*SinBJ(a)
 set .z2=.z1+(.z2-.z1)*CosBJ(a)+(.x2-.x1)*SinBJ(a)
else
 set .x2=.x1+d*CosBJ(a)
 set .y2=.y1
 set .z2=.z1+d*SinBJ(a)
endif
endmethod

method AxisZ takes real a,real d returns nothing
if d==0.00 then
 set .x2=.x1+(.x2-.x1)*CosBJ(a)-(.y2-.y1)*SinBJ(a)
 set .y2=.y1+(.y2-.y1)*CosBJ(a)+(.x2-.x1)*SinBJ(a)
else
 set .x2=.x1+d*CosBJ(a)
 set .y2=.y1+d*SinBJ(a)
 set .z2=.z1
endif
endmethod

endstruct

globals
private constant integer SpellID='A000'
private constant integer Dummy1ID='u000'
private constant integer Dummy2ID='u001'
private constant integer Dummy3ID='u002'
private constant integer BuffID='B001'
private constant string SpellOrder="channel"
private constant real Ra=80.00
private group G=CreateGroup()
private group H=CreateGroup()
private hashtable HT=InitHashtable()
private real R=1.20
endglobals

private function Motion3 takes nothing returns nothing
local unit eu=GetEnumUnit()
local unit u=LoadUnitHandle(HT,GetHandleId(eu),1)
local rotation rotate=rotation.create()
set rotate.x1=GetUnitX(eu)
set rotate.y1=GetUnitY(eu)
set rotate.x2=GetUnitX(u)
set rotate.y2=GetUnitY(u)
if rotate.dist()<=150 and GetUnitState(u,UNIT_STATE_LIFE)!=0 and GetUnitState(eu,UNIT_STATE_LIFE)!=0 and GetUnitCurrentOrder(eu)!=OrderId(SpellOrder) then
 call rotate.AxisZ(GetUnitFacing(u),25)
 if not IsTerrainPathable(rotate.x2,rotate.y2,PATHING_TYPE_WALKABILITY) then
  call SetUnitX(eu,rotate.x2)
  call SetUnitY(eu,rotate.y2)
 endif
else
 call FlushChildHashtable(HT,GetHandleId(eu))
 call UnitRemoveAbility(eu,BuffID)
 call GroupRemoveUnit(H,eu)
endif
call rotate.destroy()
set eu=null
set u=null
endfunction

private function Motion2 takes nothing returns nothing
local unit eu=GetEnumUnit()
local integer h=LoadInteger(HT,GetHandleId(eu),1)
local real a=GetUnitFacing(eu)
local real b=LoadReal(HT,GetHandleId(eu),2)+7.00
local rotation rotate=LoadInteger(HT,h,2)
call rotate.AxisX(b,Ra)
call rotate.AxisZ(a,0.00)
if not IsTerrainPathable(rotate.x2,rotate.y2,PATHING_TYPE_FLYABILITY) then
 call SetUnitX(eu,rotate.x2)
 call SetUnitY(eu,rotate.y2)
endif
call SetUnitFlyHeight(eu,rotate.z2,0.00)
call SaveReal(HT,GetHandleId(eu),2,b)
set eu=null
endfunction

private function Motion1 takes nothing returns nothing
local unit eu=GetEnumUnit()
local group g=LoadGroupHandle(HT,GetHandleId(eu),1)
local real a=GetUnitFacing(eu)
local rotation rotate=LoadInteger(HT,GetHandleId(eu),2)
set rotate.x1=GetUnitX(eu)
set rotate.y1=GetUnitY(eu)
set rotate.z1=GetUnitFlyHeight(eu)
call rotate.AxisZ(a,8.00)
if not IsTerrainPathable(rotate.x2,rotate.y2,PATHING_TYPE_FLYABILITY) then
 call SetUnitX(eu,rotate.x2)
 call SetUnitY(eu,rotate.y2)
endif
set rotate.x1=rotate.x2
set rotate.y1=rotate.y2
call ForGroup(g,function Motion2)
set eu=null
set g=null
endfunction

private function CreateSpiral2 takes nothing returns nothing
local group g1=LoadGroupHandle(HT,GetHandleId(GetEnumUnit()),1)
call ForGroup(g1,function Motion1)
set g1=null
endfunction

private function Act5 takes nothing returns nothing
local unit u=LoadUnitHandle(HT,GetHandleId(GetTriggeringTrigger()),1)
local player p=GetOwningPlayer(u)
local unit tu=GetTriggerUnit()
local unit d
if GetUnitCurrentOrder(tu)!=OrderId(SpellOrder) and IsUnitAlly(tu,p) and GetUnitState(u,UNIT_STATE_LIFE)!=0 and GetUnitState(tu,UNIT_STATE_LIFE)!=0 then
call SaveUnitHandle(HT,GetHandleId(tu),1,u)
 if not IsUnitInGroup(tu,H) then
  call GroupAddUnit(H,tu)
  set d=CreateUnit(p,Dummy3ID,GetUnitX(tu),GetUnitY(tu),0.00)
  call IssueTargetOrder(d,"banish",tu)
  set d=null
 endif
endif
set u=null
set p=null
set tu=null
endfunction

private function CreateSpiral1 takes nothing returns nothing
local unit u1
local unit u2
local unit eu=GetEnumUnit()
local player p=GetOwningPlayer(eu)
local real a=LoadReal(HT,GetHandleId(eu),2)
local group g1=LoadGroupHandle(HT,GetHandleId(eu),1)
local group g2=CreateGroup()
local trigger tr=CreateTrigger()
local integer i=1
local rotation rotate=rotation.create()

set rotate.x1=GetUnitX(eu)
set rotate.y1=GetUnitY(eu)
set rotate.z1=GetUnitFlyHeight(eu)+Ra
set u1=CreateUnit(p,Dummy1ID,rotate.x1,rotate.y1,a)
call SetUnitFlyHeight(u1,rotate.z1,0.00)
loop
 call rotate.AxisX(i*120.00,Ra)
 call rotate.AxisZ(a,0.00)
 set u2=CreateUnit(p,Dummy2ID,rotate.x2,rotate.y2,a)
 call SetUnitFlyHeight(u2,rotate.z2,0.00)
 call SaveInteger(HT,GetHandleId(u2),1,GetHandleId(u1))
 call SaveReal(HT,GetHandleId(u2),2,i*120.00)
 call GroupAddUnit(g2,u2)
 set i=i+1
exitwhen i>3
endloop

call SaveGroupHandle(HT,GetHandleId(u1),1,g2)
call SaveInteger(HT,GetHandleId(u1),2,rotate)
call TriggerRegisterUnitInRange(tr,u1,Ra,null)
call TriggerAddAction(tr,function Act5)
call SaveTriggerHandle(HT,GetHandleId(u1),3,tr)
call SaveUnitHandle(HT,GetHandleId(tr),1,u1)
call GroupAddUnit(g1,u1)


set p=null
set g2=null
set u1=null
set u2=null
set g1=null
set eu=null
set tr=null
endfunction

private function Act4 takes nothing returns nothing
call ForGroup(G,function CreateSpiral2)
call ForGroup(H,function Motion3)
endfunction

private function Act3 takes nothing returns nothing
call ForGroup(G,function CreateSpiral1)
endfunction

private function Clear2 takes nothing returns nothing
call FlushChildHashtable(HT,GetHandleId(GetEnumUnit()))
call KillUnit(GetEnumUnit())
endfunction

private function Clear1 takes nothing returns nothing
local group g=LoadGroupHandle(HT,GetHandleId(GetEnumUnit()),1)
local rotation rotate=LoadInteger(HT,GetHandleId(GetEnumUnit()),2)
local trigger tr=LoadTriggerHandle(HT,GetHandleId(GetEnumUnit()),3)
call FlushChildHashtable(HT,GetHandleId(tr))
call DestroyTrigger(tr)
call rotate.destroy()
call FlushChildHashtable(HT,GetHandleId(GetEnumUnit()))
call ForGroup(g,function Clear2)
call GroupClear(g)
call DestroyGroup(g)
call KillUnit(GetEnumUnit())
set g=null
set tr=null
endfunction

private function Act2 takes nothing returns boolean
local group g
if GetSpellAbilityId()==SpellID then
 set g=LoadGroupHandle(HT,GetHandleId(GetTriggerUnit()),1)
 call FlushChildHashtable(HT,GetHandleId(GetTriggerUnit()))
 call ForGroup(g,function Clear1)
 call GroupClear(g)
 call DestroyGroup(g)
 call GroupRemoveUnit(G,GetTriggerUnit())
 set g=null
endif
return false
endfunction

private function Act1 takes nothing returns boolean
local group g
local unit tu
if GetSpellAbilityId()==SpellID then
 set tu=GetTriggerUnit()
 set g=CreateGroup()
 call SaveGroupHandle(HT,GetHandleId(tu),1,g)
 call SaveReal(HT,GetHandleId(tu),2,Atan2BJ(GetSpellTargetY()-GetUnitY(tu),GetSpellTargetX()-GetUnitX(tu))​)
 call GroupAddUnit(G,tu)
 set g=null
 set tu=null
 endif
return false
endfunction

private function Init takes nothing returns nothing
local trigger tr1=CreateTrigger()
local trigger tr2=CreateTrigger()
local timer tm1=CreateTimer()
local timer tm2=CreateTimer()
local player p
local integer i=0
loop
 set p=Player(i)
 call TriggerRegisterPlayerUnitEvent(tr1,p,EVENT_PLAYER_UNIT_SPELL_EFFECT,null)
 call TriggerRegisterPlayerUnitEvent(tr2,p,EVENT_PLAYER_UNIT_SPELL_FINISH,null)
 call TriggerRegisterPlayerUnitEvent(tr2,p,EVENT_PLAYER_UNIT_SPELL_ENDCAST,null)
 set p=null
 set i=i+1
 exitwhen i>11
endloop

call TriggerAddCondition(tr1,Condition(function Act1))
call TriggerAddCondition(tr2,Condition(function Act2))
call TimerStart(tm1,0.45,true,function Act3)
call TimerStart(tm2,0.03,true,function Act4)

set tr1=null
set tm1=null
set tm2=null
endfunction
endlibrary

scope FireLaser initializer Init{
include "cj_types_priv.j"
    define{
        private SpellId='A777'
        //айди скила
        private DummyId='h000'
        //айди дамика
        private LightningId="AFOD"
        //айди молнии
        private Height_up=12.
        //скорость с которой поднимаются в воздух шары
        private num=30
        //кол-во шариков
        private speed_of_laser=2.5
        //скорость лазера
        private MoveSpeed_one=10.
        //скорость шариков, когда они разлетаються
        private MoveSpeed_of_target=(GetUnitMoveSpeed(u)*periodic)
        //сила, с которой двигаеи юнитов, попавших под лазер
        private MaxRange=500
        //максимальный радиус когда шарики разлетаются во все строны
        private MinRange=100
        //мин радиус шариков
        private MaxHeight=500
        //макс высота
        private range_of_group=80
        //радиус каждого лазера
        private periodic=.025
        //...
        private periodic_of_creating=.0
        //период появления шаров
        private effect_st="Abilities\\Spells\\Orc\\LiquidFire\\Liquidfire.mdl"
        //эффект во время спавна шаров
        private effect_nd="Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl"
        //эффект по окончанию спавна
    }
    
    define{
        private Unit(u,x,y,a)={ut=CreateUnit(GetOwningPlayer(u),DummyId,x,y,a)}
        private random=GetRandomReal(0,100)
    }
globals
    private unit dummy
endglobals

private struct Lightning
lightning l
unit u
real a,d,tm
    
    static method onRange takes nothing returns boolean
        unit u = GetFilterUnit()
        real x1 = GetUnitX(u) - GetUnitX(dummy)
        real y1 = GetUnitY(u) - GetUnitY(dummy)    
        real dist = SquareRoot(x1*x1 + y1*y1)
        real angle = Atan2(GetUnitY(dummy) - GetUnitY(u), GetUnitX(dummy) - GetUnitX(u))       
        if IsUnitEnemy(dummy, GetOwningPlayer(u)) and GetWidgetLife(u) > 0.405 and dist > 20 and not IsUnitType(u, UNIT_TYPE_STRUCTURE) and not IsUnitType(u, UNIT_TYPE_MECHANICAL) then 
            SetUnitX(u, GetUnitX(u) - MoveSpeed_of_target * Cos(angle))
            SetUnitY(u, GetUnitY(u) - MoveSpeed_of_target * Sin(angle))
        endif
        u = null
        return false          
    endmethod
    static method onAction takes nothing returns nothing
        timer t = GetExpiredTimer()
        thistype c = GetTimerData(t)
        if c.d>MinRange
            if c.tm<3 then
                c.tm+=periodic
                SetUnitScalePercent(c.u,100+(c.tm*10),100+(c.tm*10),100+(c.tm*10))
                SetLightningColor(c.l,random,0,random,100)
                MoveLightningEx(c.l,true,GetUnitX(c.u),GetUnitY(c.u),GetUnitFlyHeight(c.u),GetUnitX(c.u),GetUnitY(c.​u),GetUnitFlyHeight(c.u)-c.tm*200)
            else
                SetUnitX(c.u,GetUnitX(c.u)-speed_of_laser*Cos(c.a))
                SetUnitY(c.u,GetUnitY(c.u)-speed_of_laser*Sin(c.a))
                MoveLightningEx(c.l,true,GetUnitX(c.u),GetUnitY(c.u),GetUnitFlyHeight(c.u),GetUnitX(c.u),GetUnitY(c.​u),0)
                SetLightningColor(c.l,100,0,100,100)
                dummy=c.u
                group g=CreateGroup()
                GroupEnumUnitsInRange(g, GetUnitX(c.u), GetUnitY(c.u), range_of_group, Filter(function thistype.onRange))
                DestroyGroup(g)
                g=null
                c.d-=speed_of_laser
            endif
        else
            DestroyLightning(c.l)
            KillUnit(c.u)
            ReleaseTimer(t)
        endif
        t=null
    endmethod
    static method onCreate takes unit caster,real a,real d returns thistype
        thistype c= thistype.create()
        timer t = NewTimer()
        c.u=caster
        c.a=a
        c.d=d
        c.tm=0
        c.l=AddLightningEx("AFOD",true,GetUnitX(c.u),GetUnitY(c.u),GetUnitFlyHeight(c.u),GetUnitX(​c.u),GetUnitY(c.u),GetUnitFlyHeight(c.u))
        SetTimerData(t, c)
        TimerStart(t, periodic, true, function thistype.onAction)
        t = null
        return c
    endmethod
endstruct

private struct Height
    unit u
    real x,y,a,d,h
    static method onAction takes nothing returns nothing
        timer t = GetExpiredTimer()
        thistype c = GetTimerData(t)
        c.d=SquareRoot((GetUnitX(c.u) - c.x) * (GetUnitX(c.u) - c.x) + (GetUnitY(c.u) - c.y) * (GetUnitY(c.u) - c.y))
        if c.h<MaxHeight then
            c.h+=Height_up
            SetUnitFlyHeight(c.u,c.h,0)
        elseif c.d>MoveSpeed_one
            UnitRemoveAbility(c.u,'Aloc')
            ShowUnit(c.u,true)
            UnitAddAbility(c.u,'Aloc')
            SetUnitX(c.u,GetUnitX(c.u)+MoveSpeed_one*Cos(c.a))
            SetUnitY(c.u,GetUnitY(c.u)+MoveSpeed_one*Sin(c.a))
        else
            Lightning.onCreate(c.u,c.a,MaxRange)
            ReleaseTimer(t)
        endif
        t=null
    endmethod
    static method onCreate takes unit caster,real a returns thistype
        thistype c= thistype.create()
        timer t = NewTimer()
        c.u=caster
        c.x = GetUnitX(c.u)+MaxRange*Cos(a)
        c.y = GetUnitY(c.u)+MaxRange*Sin(a)
        c.h=0
        c.a=a
        SetTimerData(t, c)
        TimerStart(t, periodic, true, function thistype.onAction)
        t = null
        return c
    endmethod
endstruct

private struct cold
    //+++++
    unit u
    real x,y,ts
    effect e
    //+++++
    static method onDamage takes nothing returns boolean
         return false
    endmethod
    
    static method onRange takes nothing returns boolean
        return false
    endmethod
    
    static method onAction takes nothing returns nothing
        timer t = GetExpiredTimer()
        thistype c = GetTimerData(t)
        unit ut
        if c.ts>0 then
            c.ts--
            Unit(c.u,c.x,c.y,0)
            if c.ts!=1 then
                ShowUnit(ut,false)
            endif
            Height.onCreate(ut,((360/num)*c.ts)*bj_DEGTORAD)
        else
            DestroyEffect(c.e)
            DestroyEffect(AddSpecialEffect(effect_nd,c.x,c.y ))
            ReleaseTimer(t)
        endif
        t=null
        ut=null
    endmethod
    
    static method onCreate takes unit caster returns thistype
        thistype Cold = thistype.create()
        timer t = NewTimer()
        Cold.u=caster
        Cold.x = GetUnitX(Cold.u)
        Cold.y = GetUnitY(Cold.u)
        Cold.ts = num
        Cold.e=AddSpecialEffect(effect_st,Cold.x,Cold.y )
        SetTimerData(t, Cold)
        TimerStart(t, periodic_of_creating, true, function thistype.onAction)
        t = null
        return Cold
    endmethod
    
endstruct 

    private bool COLD_CAST(){
        if GetSpellAbilityId()==SpellId then
            cold.onCreate(GetTriggerUnit())
        endif 
        return false
    }

    private void Init(){
        trigger t=CreateTrigger()   
        int index = 0
        debug BJDebugMsg("|c0000C5FFSpell Created By Jumper aka YouTube")
        whilenot(index == 13){
            TriggerRegisterPlayerUnitEvent(t, Player(index), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
            index++
        }
        TriggerAddCondition(t, Condition(function COLD_CAST))
        t = null
    }
}