-------// нестанд. код
globals
  constant integer NumberOfPlayers = 10
  trigger array Trigger
  timer array Timer
  real array Real
  real array Z
  unit array Unit
  unit array Target
  integer array Int
endglobals

function H2I takes handle h returns integer
  return h
  return 0
endfunction

function Angle takes real AX, real AY, real BX, real BY returns real
  return bj_RADTODEG * Atan2(BY - AY, BX - AX)
endfunction

-------// сама способность

function Gr_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000' 
endfunction

function G_Filt takes nothing returns boolean
    local integer h = H2I(GetExpiredTimer())-0x100000
    return GetUnitState(GetFilterUnit(),ConvertUnitState(0))>0 and GetFilterUnit()!=Unit[h] and IsUnitEnemy(GetFilterUnit(),GetOwningPlayer(Unit[h]))
endfunction

function Gr_Endcast takes nothing returns nothing
    local trigger tr = GetTriggeringTrigger()
    local integer htr = H2I(tr)-0x100000
    local integer h = H2I(Timer[htr])-0x100000
    call DestroyTimer(Timer[htr])
    call DestroyTrigger(tr)
    set Unit[h] = null
    set Timer[htr] = null
    set tr = null
endfunction

function GroupMove takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer h = H2I(t)-0x100000
      if Real[h]>=0 then
        call SetUnitX(Target[h],GetUnitX(Target[h])-20*Cos(Z[h]*0.0175))
        call SetUnitY(Target[h],GetUnitY(Target[h])-20*Sin(Z[h]*0.0175))
        call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Human\\FlakCannons\\FlakTarget.mdl",Target[h],"origin"))
        set Real[h] = Real[h]-20
      else
        call DestroyTimer(t)
        call PauseUnit(Target[h],false)
        set Target[h] = null
      endif
    set t = null
endfunction

function GroupEnum takes nothing returns nothing
    local timer te = GetExpiredTimer() 
    local integer he = H2I(te)-0x100000
    local timer t = CreateTimer()
    local integer h = H2I(t)-0x100000
    set Target[h] = GetEnumUnit()
    set Real[h] = 200.
    set Z[h] = Angle(GetUnitX(Target[h]),GetUnitY(Target[h]),GetUnitX(Unit[he]),GetUnitY(Unit[he]))
    call UnitDamageTarget(Unit[he],Target[h], 200, true, false, ConvertAttackType(4), ConvertDamageType(14), ConvertWeaponType(0))
    call PauseUnit(Target[h],true)
    call TimerStart(t,0.04,true, function GroupMove)
    set t = null
endfunction

function G_Actions takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local unit u = GetTriggerUnit()
    local group g = CreateGroup()
    local integer h = H2I(t)-0x100000
    set Int[h] = Int[h] + R2I(TimerGetElapsed(t))
      if Int[h]<10 then
        call GroupEnumUnitsInRange(g,GetUnitX(Unit[h]),GetUnitY(Unit[h]),400,Filter(function G_Filt))
        call ForGroup(g,function GroupEnum)
        call DestroyGroup(g)
        call TimerStart(t,1.,false,function G_Actions)
      else
        call DestroyTimer(t)
        set Unit[h] = null
      endif
    set g = null
    set u = null
    set t = null
endfunction

function Gr_Actions takes nothing returns nothing
    local timer t = CreateTimer()
    local integer h = H2I(t)-0x100000
    local integer htr = 0
    set Trigger[h] = CreateTrigger()
    set htr = H2I(Trigger[h])-0x100000
    set Timer[htr] = t
    set Int[h] = 0
    set Unit[h] = GetTriggerUnit()
    call TriggerRegisterUnitEvent(Trigger[h], Unit[h], EVENT_UNIT_SPELL_ENDCAST)
    call TriggerAddAction( Trigger[h], function Gr_Endcast )
    call TimerStart(t,0.,false,function G_Actions)
    set t = null
endfunction

//===========================================================================
function InitTrig_Group takes nothing returns nothing
    local integer index = 0
    set gg_trg_Group = CreateTrigger(  )
    
      loop
         call TriggerRegisterPlayerUnitEvent(gg_trg_Group, Player(index), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
         set index = index + 1
       exitwhen index == NumberOfPlayers
      endloop

    call TriggerAddCondition( gg_trg_Group, Condition( function Gr_Conditions ) )
    call TriggerAddAction( gg_trg_Group, function Gr_Actions )
endfunction