globals
    integer array dualpha
    unit array dunit
endglobals

function UDSysTimerAction takes integer i returns nothing
    set dualpha[ i ] = dualpha[ i ] + 20
    call SetUnitVertexColor(dunit[ i ], 255, 255, 255, 255 - dualpha[ i ])
    call TriggerSleepAction(.01)
    if dualpha[ i ] < 255 then
        call UDSysTimerAction(i)
    else
        if not(IsUnitType( dunit[ i ] , UNIT_TYPE_HERO )) then
            call RemoveUnit( dunit[ i ] )
        endif
        set dunit[ i ]   = null
    endif
endfunction

function UDSysAction takes nothing returns nothing
    local unit    u = GetTriggerUnit( )
    local integer i = 0
    call SetUnitTimeScale( u, 0 )
    call SetUnitPathing( u, false )
    loop
        exitwhen dunit[ i ] == null
        set i = i + 1
    endloop
    set dunit[ i ]   = u
    set dualpha[ i ] = 0
    call UDSysTimerAction(i)
    set u = null
endfunction

function InitTrig_UDSys takes nothing returns nothing
    local trigger t = CreateTrigger( )
    local integer i = 0
    loop
        call TriggerRegisterPlayerUnitEvent( t, Player( i ), EVENT_PLAYER_UNIT_DEATH, null )
        set i = i + 1
        exitwhen i == 15
    endloop
    call TriggerAddAction( t, function UDSysAction )
endfunction

library UNITALPHA initializer Init

globals
    constant real g_Period = 0.012
    constant integer g_Speed = 2
    timer g_durimer = CreateTimer()
                        
    integer g_count = 0
    AU array g_All
    code g_FuncTimer
endglobals

struct AU  
    private integer index
    private integer alpha
    private unit un
           
    private method Add takes nothing returns nothing
        if (g_count == 0) then
            call TimerStart(g_durimer, g_Period, true, g_FuncTimer)
        endif
        set g_All[g_count] = this
        set .index = g_count
        set g_count = g_count + 1
    endmethod
  
    private method Delete takes nothing returns nothing
        set g_count = g_count - 1
        set g_All[.index] = g_All[g_count]
        set g_All[.index].index = .index
        if (g_count == 0) then
            call PauseTimer(g_durimer)
        endif
    endmethod                                        
   
    method AddAlpha takes nothing returns nothing 
        set .alpha = .alpha - g_Speed
        call SetUnitVertexColor(.un, 255, 255, 255, .alpha)
        if (.alpha <= 0) then
            call .Delete()
            call .destroy()
        endif
    endmethod
    
    static method AlphaUnit takes unit u returns nothing 
        local AU this = AU.create()
        set .un = u
        set .alpha = 256
        call .Add()
    endmethod
    
endstruct

private function Timer_Func takes nothing returns nothing
    local integer i = g_count - 1
    loop
        call g_All[i].AddAlpha()
        exitwhen i == 0
        set i = i - 1    
    endloop
endfunction 
 
private function Init takes nothing returns nothing
    set g_FuncTimer = function Timer_Func
endfunction

endlibrary

library UNITDEADALPHA initializer Init requires UNITALPHA
       
private function SysAction takes nothing returns nothing
    local unit u = GetTriggerUnit()
    call AU.AlphaUnit(u)
    set u = null
endfunction
     
private function Init takes nothing returns nothing
    local trigger t = CreateTrigger()
    local integer i = 0
    loop
        call TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_UNIT_DEATH, null) 
        exitwhen i == 15
        set i = i + 1
    endloop
    call TriggerAddAction(t, function SysAction)
endfunction 
         
endlibrary