//***************************************************************************
//*
//*  Rain Effects
//*
//***************************************************************************

//===========================================================================
function ME_LightningStrikeAction takes nothing returns nothing
   call SetWidgetLife(GetEnumUnit(), GetWidgetLife(GetEnumUnit()) - udg_rain_light_damage)
endfunction

//===========================================================================
function ME_LightningStrikeFilter takes nothing returns boolean
   return ( GetUnitX(GetFilterUnit()) - GetLocationX(udg_light_loc) )*( GetUnitX(GetFilterUnit()) - GetLocationX(udg_light_loc) )  +  ( GetUnitY(GetFilterUnit()) - GetLocationY(udg_light_loc) )*( GetUnitY(GetFilterUnit()) - GetLocationY(udg_light_loc) ) < udg_rain_light_radius*udg_rain_light_radius
endfunction

//===========================================================================
function ME_LightningStrike takes nothing returns nothing
   local group units
   local effect lightnin
   if GetRandomReal(0,1) < udg_rain_light_chance then
      set udg_light_loc = GetRandomLocInRect(udg_rain_rect)
      set lightnin =  AddSpecialEffectLoc("Doodads\\Cinematic\\Lightningbolt\\Lightningbolt.mdl",  udg_light_loc )
      set units = GetUnitsInRectMatching(udg_rain_rect, Condition(function ME_LightningStrikeFilter))
      call ForGroupBJ( units, function ME_LightningStrikeAction )
      call DestroyGroup(units)
      call RemoveLocation(udg_light_loc)
      call TriggerSleepAction(0.3)
      call DestroyEffect(lightnin)
   endif
endfunction

//===========================================================================
function ME_EnhanceRegenAction takes nothing returns nothing
   call SetWidgetLife(GetEnumUnit(), GetWidgetLife(GetEnumUnit()) + udg_regen_rate)
endfunction

//===========================================================================
function ME_EnhanceRegenFilter takes nothing returns boolean
   return IsUnitType(GetFilterUnit(), UNIT_TYPE_ANCIENT)
endfunction

//===========================================================================
function ME_EnhanceRegen takes nothing returns nothing
   local group murlocs = GetUnitsInRectMatching(udg_rain_rect, Condition(function ME_EnhanceRegenFilter))
   call ForGroupBJ( murlocs, function ME_EnhanceRegenAction )
   call DestroyGroup(murlocs)
endfunction

//===========================================================================
function ME_RainStartStop takes boolean disable returns nothing
   call RemoveWeatherEffect(udg_rain)
   call DestroyTrigger(udg_regen_trigger)
   call DestroyTrigger(udg_light_trigger)
   if not disable then
      set udg_rain_rect = bj_mapInitialPlayableArea
      set udg_rain = AddWeatherEffect( udg_rain_rect, 'RAhr')
      call EnableWeatherEffect( udg_rain, true)

      set udg_regen_trigger = CreateTrigger()
      call TriggerRegisterTimerEvent(udg_regen_trigger, 1.00, true)
      call TriggerAddAction(udg_regen_trigger, function ME_EnhanceRegen)

      set udg_light_trigger = CreateTrigger()
      call TriggerRegisterTimerEvent(udg_light_trigger, udg_rain_light_period, true)
      call TriggerAddAction(udg_light_trigger, function ME_LightningStrike)      
   else
      set udg_rain = AddWeatherEffect( udg_rain_rect, 'RAlr')
      call EnableWeatherEffect( udg_rain, true)
      call TriggerSleepAction(2.00)
      call RemoveWeatherEffect(udg_rain)
   endif
   set udg_rain_enabled = not udg_rain_enabled
endfunction