constant hashtable h = InitHashtable()

function SR takes real x1, real y1, real x2, real y2 returns real
    return SquareRoot((x1-x2)*(x1-x2)+(y1-y2)*(y1-y2))
endfunction

function MissleMove2 takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit u = LoadUnitHandle(h,id,0)
    local unit c = LoadUnitHandle(h,id,1)
    local unit d = LoadUnitHandle(h,id,2)
    local real speed = LoadReal(h,id,4)
    local real x = GetUnitX(d)
    local real y = GetUnitY(d)
    local real x1 = GetUnitX(c)
    local real y1 = GetUnitY(c)
    local real a = Atan2(y1-y,x1-x)+LoadReal(h,id,3)
    if SR(x,y,x1,y1) > 40 and GetWidgetLife(c) > 0 then
        call SetUnitX(d,x+speed*Cos(a))
        call SetUnitY(d,y+speed*Sin(a))
        call SetUnitFacing(d,a*bj_DEGTORAD)
    else
        call UnitDamageTarget(u,c,LoadReal(h,id,5),false,false,null,null,null)
        call FlushChildHashtable(h,id)
        call DestroyTimer(t)
        call RemoveUnit(d)
    endif
    set d = null
    set c = null
    set t = null
    set u = null
endfunction

function MissleMove takes unit u,unit c,real speed,real angle,real dmg,integer ab returns nothing
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    call SaveUnitHandle(h,id,0,u)
    call SaveUnitHandle(h,id,1,c)
    call SaveUnitHandle(h,id,2,CreateUnit(GetOwningPlayer(u),ab,GetUnitX(u),GetUnitY(u),GetUnitFacing(u)))
    call SaveReal(h,id,3,angle)
    call SaveReal(h,id,4,speed)
    call SaveReal(h,id,5,dmg)
    call TimerStart(t,0.04,true,function MissleMove2)
    set t = null
endfunction

function Trig_LaserStrike_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction

function Trig_LaserStrike_Actions2 takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit u = LoadUnitHandle(h,id,0)
    local unit c = LoadUnitHandle(h,id,1)
    local real m = GetUnitState(u,UNIT_STATE_MANA)
    if GetUnitCurrentOrder(u) == OrderId("channel") and m > 0 then
        call MissleMove(u,c,30,GetRandomReal(-1.2,1.2),GetHeroInt(u,true)*GetUnitAbilityLevel(u,'A000'),'e000')
        call SetUnitState(u,UNIT_STATE_MANA,m-m*0.01)
    else
        call FlushChildHashtable(h,id)
        call DestroyTimer(t)
    endif
    set t = null
    set c = null
    set u = null
endfunction

function Trig_LaserStrike_Actions takes nothing returns nothing
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    call SaveUnitHandle(h,id,0,GetTriggerUnit())
    call SaveUnitHandle(h,id,1,GetSpellTargetUnit())
    call TimerStart(t,0.25,true,function Trig_LaserStrike_Actions2)
    set t = null
endfunction

//===========================================================================
function InitTrig_LaserStrike takes nothing returns nothing
    set gg_trg_LaserStrike = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_LaserStrike, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_LaserStrike, Condition( function Trig_LaserStrike_Conditions ) )
    call TriggerAddAction( gg_trg_LaserStrike, function Trig_LaserStrike_Actions )
endfunction