globals
  hashtable Hash = InitHashtable()
endglobals

function Trig_Random_Timer takes nothing returns nothing
// Тута всё гуд!
  local timer ta = GetExpiredTimer() 
  local integer ID = GetHandleId(ta) 
  local unit t = LoadUnitHandle(Hash, ID, 0)

  call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\Starfall\\StarfallTarget.mdl​", t, "overhead"))
  call UnitDamageTarget(LoadUnitHandle(Hash, ID, 1), t, 100., true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_FIRE, WEAPON_TYPE_WHOKNOWS)
  call PauseTimer(ta)
  call DestroyTimer(ta) 
  call FlushChildHashtable(Hash, ID)

  set t = null
  set ta = null
endfunction

function Trig_Random_Actions takes nothing returns nothing
  local timer ta
  local integer ID
  local group g
  local integer i
  // Чёта я непонел чё это? оО И зачем это?
  //local unit array u
  local unit pu
  local unit su
  local unit c
  local player p

  if (GetSpellAbilityId() == 'AEsf')  then
    set i = 1
    set c = GetSpellAbilityUnit()
    set g = CreateGroup()
    set p = GetOwningPlayer(c)
    set su = null
    call GroupEnumUnitsInRange(g, GetUnitX(c), GetUnitY(c), 450., null)

    loop
      // Аа паходу понял, говнооптимизация кода - ф топку(ни выйгрыша в скорости, ни выйгриша в читабельности), даешь нормальные переменные
      //set u[1]=FirstOfGroup(g)
      set pu = FirstOfGroup(g)
      exitwhen (pu == null)
      //call GroupRemoveUnit(g,u[1])
      call GroupRemoveUnit(g, pu)

      //if (IsUnitEnemy(u[1], p)) then
      if (IsUnitEnemy(pu, p)) then

      // Ыы... фтыкал пять минут чё за хрень, так и непонял
        if (GetRandomInt(1, i) == 1) then
          //set u[0] = u[1]
          set su = pu
        endif

        set i = i + 1
      endif

    endloop

    call DestroyGroup(g)
    set g = null

    // Проверим, нашли мы зайца или нет, если да, то бьём в морду!
    if (su != null) then
      set ta = CreateTimer()
      set ID = GetHandleId(ta)
      call SaveUnitHandle(Hash, ID, 0, su)
      call SaveUnitHandle(Hash, ID, 1, c) 
      call TimerStart(ta, 3., false, function Trig_Random_Timer)
      set ta = null
    else
      // типа оптимизация, смысл обнулять переменную, если она и так пуста
      set su = null
    endif

    //set u[0] = null
    set pu = null
    set c = null
    set p = null
  endif

endfunction

//===========================================================================
function InitTrig_Random takes nothing returns nothing
  local integer index = 0
  local trigger trig = CreateTrigger()

  loop
    call TriggerRegisterPlayerUnitEvent(trig, Player(index), EVENT_PLAYER_UNIT_SPELL_FINISH, null)
    set index = index + 1
    exitwhen index == bj_MAX_PLAYER_SLOTS
  endloop

  call TriggerAddAction( trig, function Trig_Random_Actions )
  set trig=null
endfunction