scope Spell initializer Init{
    define{
        private SpellId='A000'
        //айди скила
        private DummyId='h000'
        //айди даммика
        private Range=350.
        //радиус действия
        private Duration=10.
        //время действия скила
        private ExtraRange=80.
        //радиус преграды
        private Count=20
        //сол-во юнитов (преграды)
    }
    private unit CAST
    private real X,Y
    private struct Cast{
    unit cast,dmy[21]
    real d,x,y
    static method onAction takes void returns void
        timer t = GetExpiredTimer()
        thistype r = GetTimerData(t)
        if r.d>=0
        //проверяем оставшееся время
        
            //========================================
            //вычитаем время
            r.d-=.03125
            //========================================
            
            //========================================
            //присваиваем для пика к клобалке
            CAST=r.cast
            X=r.x
            Y=r.y
            //========================================
            group g=new group
            //создаем группу
            GroupEnumUnitsInRange(g, r.x, r.y,Range+ExtraRange, Filter(lambda bool onDamage(){
                unit u = GetFilterUnit()
                //фильтр офк
                //убери потом "not" что бы действовала на врагов
                if not IsUnitEnemy(CAST, GetOwningPlayer(u)) and GetWidgetLife(u) > 0.405 and not IsUnitType(u, UNIT_TYPE_STRUCTURE) and not IsUnitType(u, UNIT_TYPE_MECHANICAL)
                    real d=SQ(X,Y,GetUnitX(u),GetUnitY(u))
                    //находим м\у ними расстояние
                    real a=ABU3(GetUnitX(u),GetUnitY(u),X,Y)
                    //угол
                    if d>=Range
                        //из круга
                        //SafeX\Y для того, что бы не улетала за границу
                        SetUnitX(u,SafeX(X+(Range+ExtraRange)*Cos(a)))
                        SetUnitY(u,SafeY(Y+(Range+ExtraRange)*Sin(a)))
                    elseif d>=Range-ExtraRange
                        //в круге
                        SetUnitX(u,SafeX(X+(Range-ExtraRange)*Cos(a)))
                        SetUnitY(u,SafeY(Y+(Range-ExtraRange)*Sin(a)))
                    endif
                endif
                clear
                return false
            }))
            DestroyGroup(g)
            //удаляем группу
        else
            int i=1
            do {
                RemoveUnit(r.dmy[i])
                //удаляем даммиков
            } whilenot(i++==20)
            ReleaseTimer(t)
            //удаляем таймер
        endif
        clear
        //обнуляем переменные
    endmethod
    
    static method Create takes unit cast returns thistype
        thistype r = thistype.create()
        timer t = NewTimer()
        r.cast=cast
        //присваиваем юнита-кастера к система
        int i=1
        real a=bj_PI/Count
        //фигня
        real x=GetUnitX(cast)
        real y=GetUnitY(cast)
        //положение юнита
        r.x=x
        r.y=y
        r.d=Duration
        //в систему добавляем данные
        do {
            //создаем даммиков через цикл
            r.dmy[i]=new unit(GetOwningPlayer(cast),DummyId,x+Range*Cos(a*(i*2)),y+Range*Sin(a*(i*2)))
        } whilenot( i++ == Count)
        
        SetTimerData(t,r)
        //сохраняем
        TimerStart(t, .03125, true, function thistype.onAction)
        //запускаем таймер
        clear
        //обнуляем переменные
        return r
    endmethod
    }
    private void Init(){
        trigger t=new trigger
        TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
        TriggerAddCondition(t,Condition(lambda bool Cond(){
            //регистрация на скилл
            if GetSpellAbilityId()==SpellId
                unit cast=GetTriggerUnit()
                Cast.Create(cast)
                //применение скила
            endif
            clear
            return false
        }))
        clear
        //обнуляем переменные
    }
}