function KletkaTimer takes nothing returns nothing
    local timer ct = GetExpiredTimer()
    local integer Count = GetStoredInteger(udg_cache, I2S(H2I(ct)), "Count") 
    call RemoveUnit(I2U(GetStoredInteger(udg_cache, I2S(H2I(ct)), "unittop")))
    loop
        exitwhen Count <= 0
        call RemoveUnit(I2U(GetStoredInteger(udg_cache, I2S(H2I(ct)), "Effect"+I2S(Count))))
        call DestroyLightning(I2light(GetStoredInteger(udg_cache, I2S(H2I(ct)), "Light"+I2S(Count))))
        set Count = Count - 1
    endloop
    call FlushStoredMission(udg_cache, I2S(H2I(ct)))
    call DestroyTimer(ct)
    set ct = null
endfunction

function KletkaAction takes real Xcenter, real Ycenter, real Height, real radius, integer Count returns nothing
    local timer t = CreateTimer()
    local unit unittop = CreateUnit(Player(0), 'h000', Xcenter, Ycenter, 0)
    local real dAng = 2*bj_PI/Count
    local real X
    local real Y
    call SetUnitFlyHeight(unittop, Height, 0)
    call StoreInteger(udg_cache, I2S(H2I(t)), "unittop", H2I(unittop))
    call StoreInteger(udg_cache, I2S(H2I(t)), "Count", Count)
    loop
        exitwhen Count <= 0
        set X = Xcenter+radius*Cos(Count*dAng)
        set Y = Ycenter+radius*Sin(Count*dAng)
        call StoreInteger(udg_cache, I2S(H2I(t)), "Effect"+I2S(Count), H2I(CreateUnit(Player(0), 'h001', X, Y, (Count*dAng-bj_PI)*bj_RADTODEG)))
        call StoreInteger(udg_cache, I2S(H2I(t)), "Light"+I2S(Count), H2I(AddLightningEx("DRAM", true, X, Y, 0, Xcenter, Ycenter, Height)))    
        set Count = Count - 1
    endloop
    call TimerStart(t, 5, false, function KletkaTimer)
    set t = null
    set unittop = null
endfunction

function TrigKletkaConditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction

function TrigKletkaActions takes nothing returns nothing
    local location TargetLoc = GetSpellTargetLoc()
    call KletkaAction(GetLocationX(TargetLoc), GetLocationY(TargetLoc), 350, 256, 10)
    call RemoveLocation(TargetLoc)
    set TargetLoc = null
endfunction

function InitTrig_Kletka takes nothing returns nothing
    set gg_trg_Kletka = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_Kletka, EVENT_PLAYER_UNIT_SPELL_CAST)
    call TriggerAddCondition(gg_trg_Kletka, Condition(function TrigKletkaConditions))
    call TriggerAddAction(gg_trg_Kletka, function TrigKletkaActions)
endfunction