function OpenInventory takes unit u returns nothing
    local integer id = GetPlayerId(GetOwningPlayer(u)) // Номер игрока
    call IssueImmediateOrder(u, "stop") // Остановить юнита который использовал способность
    set udg_CurrentInvUnit[id] = u // Юнит для которого открыть инвентарь Для данного игрока
    set udg_OpenInv[id] = true // Инвентарь открыт для даного игрока
    call ViewCamera_Action() // Вызываем функцию которую использует таймер ViewCamera
endfunction

function CloseInventory takes player p returns nothing
    local integer id = GetPlayerId(p)
    set udg_OpenInv[id] = false
    if GetLocalPlayer() == p then
        call ResetToGameCamera(0)
        call PanCameraToTimed(GetUnitX(udg_CurrentInvUnit[id]), GetUnitY(udg_CurrentInvUnit[id]), 0)
    endif
    set udg_CurrentInvUnit[id] = null
endfunction

function InvStart_Conditions takes nothing returns boolean
   return GetSpellAbilityId() == 'A006' and not udg_OpenInv[GetPlayerId(GetOwningPlayer(GetSpellAbilityUnit()))]
endfunction

function InvStart_Actions takes nothing returns nothing
   call OpenInventory(GetSpellAbilityUnit())
endfunction

function GetOpenInvPl takes nothing returns boolean
   return udg_OpenInv[GetPlayerId(GetTriggerPlayer())]
endfunction

function PressEsc_Action takes nothing returns nothing
   call CloseInventory(GetTriggerPlayer())
endfunction

function CreateInvTriggers takes nothing returns nothing
    local trigger trig = CreateTrigger()
    call TriggerRegisterAnyUnitEventInv(trig, EVENT_PLAYER_UNIT_SPELL_CAST, null    ) // Юнит кастует Магию
    call TriggerAddCondition           (trig,Condition(function InvStart_Conditions))
    call TriggerAddAction              (trig,          function InvStart_Actions    )
   set trig = CreateTrigger()
   call TriggerRegisterPlayerEventInv(trig, EVENT_PLAYER_END_CINEMATIC        ) // Игрок Нажимает Esc
   call TriggerAddCondition          (trig,Condition(function GetOpenInvPl   ))
   call TriggerAddAction             (trig,          function PressEsc_Action )
    set trig = null
endfunction