SpellEventAction
Приводит в действие функцию что вы привязали к спеллу

SpellEventInit
Внутренняя функция, является ядром механизма

SpellEventUnRegisterAll
SpellEventUnRegister
Запрещяют запуск
всех спеллов
указаного спелла

SpellEventDrop
Полностью убивает весь механизм

SpellPreLoad
Подгружает указаный спелл, есть толк если вы запускаете подгрузку в начале игры, иначелаг будет всё равно.

SpellEventRegister
Связывает указаный спелл с указаной функцией

function SpellEventAction takes nothing returns nothing
    local string Table = I2S(GetSpellAbilityId())
    set Table = GetStoredString(EDS(),"SpellEvent:Spell",Table)
    if Table != "" and Table != null then
        call ExecuteFunc(Table)
    endif
endfunction
function SpellEventInit takes nothing returns nothing
    local trigger T = null
    local integer L = 15
    if GetEDS("SpellEvent","IsInit") != 0 then
        return
    endif
    set T = CreateTrigger()
    loop
        call TriggerRegisterPlayerUnitEvent(T, Player(L),EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
        set L = L - 1
        exitwhen L < 0
    endloop
    call TriggerAddActionX(T,function SpellEventAction)
    call SetEDS("SpellEvent","IsInit",1)
    call SetEDS("SpellEvent","Trigger",H2Ix(T))
    set T = null
endfunction

function SpellEventUnRegisterAll takes nothing returns nothing
    call DropEDS("SpellEvent:Spell")
endfunction

function SpellEventUnRegister takes integer Spell returns nothing
    call FlushStoredString(EDS(),"SpellEvent:Spell", I2S(Spell))
endfunction

function SpellEventDrop takes nothing returns nothing
    if GetEDS("SpellEvent","IsInit") == 0 then
        return
    endif
    call DestroyTriggerX(I2TRx(GetEDS("SpellEvent","Trigger")))
    call DropEDS("SpellEvents")
    call SpellEventUnRegisterAll()
endfunction

function SpellPreLoad takes integer Id returns nothing
    local unit Temp = CreateUnit(Player(15),'u000',0,0,0)
    call UnitAddAbility(Temp,Id)
    call UnitRemoveAbility(Temp,Id)
    call RemoveUnit(Temp)
    set Temp = null
endfunction

function SpellEventRegister takes integer Spell ,string Action returns nothing
    local string Table = I2S(Spell)
    if GetEDS("SpellEvent","IsInit") == 0 then
        call SpellEventInit()
    endif
    call StoreString(EDS(),"SpellEvent:Spell", Table, Action)
    if GetEDS("SpellEvent:PreLoad",Table) == 0 then
        call SpellPreLoad(Spell)
        call SetEDS("SpellEvent:PreLoad",Table,1)
    endif
endfunction