function Trig_Charge_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'AAnp'
endfunction

function Charge_Stun_Check takes nothing returns boolean
    if GetUnitState(GetFilterUnit(), UNIT_STATE_LIFE) > 0.425 and IsUnitType(GetFilterUnit(), UNIT_TYPE_GROUND) == true and not IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) and not IsUnitIdType(GetUnitTypeId(GetTriggerUnit()), UNIT_TYPE_STUNNED) and not IsUnitType(GetFilterUnit(), UNIT_TYPE_STUNNED) and GetUnitAbilityLevel(GetFilterUnit(), 'Aloc') <= 0 then
        return true
    else
        return false
    endif
endfunction

function Charge_Move takes nothing returns nothing
        //Объявление локальных переменных.
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit a = LoadUnitHandle(udg_hash, id, StringHash("ChargeCaster"))
    local real speed = 20.
            //Данные для движения.
    local real x
    local real y
    local real dist = LoadReal(udg_hash, id, StringHash("ChargeDistance"))
    local real tx
    local real ty
    local real angle
            //Остальное.
    local group g = CreateGroup()
    local unit f
    
    
        // Расталкивание юнитов, попавшихся на пути.
    call GroupEnumUnitsInRange(g,GetUnitX(a),GetUnitY(a),200.,function Charge_Stun_Check)
    call GroupRemoveUnit(g, a)
    loop
        set f = FirstOfGroup(g)
        exitwhen f == null
        set x = GetUnitX(a)
        set y = GetUnitY(a)
        set tx = GetUnitX(f)
        set ty = GetUnitY(f)
        set angle = Atan2(ty-y, tx-x)
        call SetUnitPosition(f, tx+15.*Cos(angle), ty+15.*Sin(angle))
        if IsUnitEnemy(f, GetOwningPlayer(a)) == true then
            call UnitDamageTargetBJ( a, f, 10.0+5.0*GetUnitAbilityLevel(a, GetSpellAbilityId()), ATTACK_TYPE_HERO, DAMAGE_TYPE_NORMAL )
        endif
        call GroupRemoveUnit(g, f)
    endloop
        
        //Непосредственно движение.
        set x = LoadReal(udg_hash, id, StringHash("ChargeCenterX"))
        set y = LoadReal(udg_hash, id, StringHash("ChargeCenterY"))
        set tx = GetUnitX(a)
        set ty = GetUnitY(a)
        set angle = Atan2(ty-y, tx-x)
    if dist > 0.0 and GetUnitState(a, UNIT_STATE_LIFE) > 0.425 and not IsTerrainPathable(tx-speed*Cos(angle), ty-speed*Sin(angle),PATHING_TYPE_WALKABILITY) then 
        call SetUnitPosition(a, tx-speed*Cos(angle), ty-speed*Sin(angle))
        call SaveReal(udg_hash, id, StringHash("ChargeDistance"), dist-speed)
    else
            //Если движение окончено, очищаем не нужные данные и приводим кастера в нормальное состояние.
        call PauseUnit(a, false)
        call SetUnitAnimation(a, "stand")
        call FlushChildHashtable(udg_hash, id)
        call DestroyTimer(t)
    endif 
    
    call DestroyGroup(g)
    set t = null
    set a = null
    set f = null
    set g = null
endfunction

function Trig_Charge_Actions takes nothing returns nothing
    local unit a = GetSpellAbilityUnit()
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    local real x = GetLocationX(GetSpellTargetLoc())
    local real y = GetLocationY(GetSpellTargetLoc())
    local real dx = GetUnitX(a) - x
    local real dy = GetUnitY(a) - y
    local real dist = SquareRoot(dx * dx + dy * dy)
    if dist > 400.0+100.0*GetUnitAbilityLevel(a, GetSpellAbilityId()) then
        set dist = 400.0+200.0*GetUnitAbilityLevel(a, GetSpellAbilityId())
    endif
        //Занесение необходимых для движения данных в хэщ и запуск таймера.
    call SaveReal(udg_hash, id, StringHash("ChargeCenterX"), x)
    call SaveReal(udg_hash, id, StringHash("ChargeCenterY"), y)
    call SaveUnitHandle(udg_hash, id, StringHash("ChargeCaster"), a)
    call SaveReal(udg_hash, id, StringHash("ChargeDistance"), dist)
    
    call IssueImmediateOrder(a, "stop")
    call PauseUnit(a, true)
    call SetUnitAnimationByIndex(a, 3)
    call TimerStart(t, 0.03, true, function Charge_Move) 
    
    set a = null
    set t = null
endfunction

//===========================================================================
function InitTrig_Charge takes nothing returns nothing
    set gg_trg_Charge = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Charge, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Charge, Condition( function Trig_Charge_Conditions ) )
    call TriggerAddAction( gg_trg_Charge, function Trig_Charge_Actions )
endfunction