WarCraft 3

Утечки

Добавлен rsfghd

Обнулял всё, что только в голову взбрело, даже то, что не нужно, и всё равно они есть.. Как же оно задолбало. Может что-то пропустил, не обнулил, не удалил, я хз.
Научите нуба, пожалуйста, избавляться от этой саранчи. Практически среди всех способностей похожего типа присутствуют эти 1-3 утечки, которые растут при быстром касте абилок
Прикладываю карту

https://xgm.guru/files/100/254355/Led.w3x

rsfghd

Принятый ответ

quq_CCCP скинул карту с нормальным кодом.
Спасибо большое)

Код:

globals
    hashtable H = InitHashtable()
    real x
    real y
    group g = CreateGroup()
    real MaxX
    real MinX
    real MaxY
    real MinY
    unit bj_lastFilterUnit = null
endglobals

function GetCorX takes real x returns real
    if ( x < MinX ) then
        return MinX
    endif
    if ( x > MaxX ) then
        return MaxY
    endif
    return x
endfunction

function GetCorY takes real y returns real
    if ( y < MinY ) then
        return MinY
    endif
    if ( y > MaxY ) then
        return MaxY
    endif
    return y
endfunction

function Trig_Frost_Conditions takes nothing returns boolean
    return ( GetSpellAbilityId() == 'A000' )
endfunction

function Enemy_Filter takes nothing returns boolean
    set bj_lastFilterUnit = GetFilterUnit( )
    return IsUnitEnemy( bj_lastFilterUnit, bj_groupEnumOwningPlayer ) and GetWidgetLife(bj_lastFilterUnit) > 0.405 and not IsUnitType( bj_lastFilterUnit, UNIT_TYPE_STRUCTURE ) 
endfunction

function Group_Damage_Enemy_Enum takes nothing returns nothing
    local unit enemy = GetEnumUnit()
    call UnitDamageTarget( bj_lastReplacedUnit, enemy, 100.00,  true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_COLD, WEAPON_TYPE_WHOKNOWS )
    call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Spells\\Undead\\FrostArmor\\FrostArmorDamage.mdl", enemy, "chest" ) )
    set enemy = null
endfunction

function Timer_Dummy_Move_Expires takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer id = GetHandleId(t)
    local unit cast = LoadUnitHandle( H, id, 0 )
    local unit dummy = LoadUnitHandle( H, id, 1 )
    local real facing = LoadReal( H, id, 2 )
    local real dist = LoadReal( H, id, 3 ) + 32.00

    set x = GetCorX( GetUnitX(dummy) + 32.00 * Cos( facing ) )
    set y = GetCorY( GetUnitY(dummy) + 32.00 * Sin( facing ) )
    call SetUnitX( dummy, x )
    call SetUnitY( dummy, y )
    call GroupClear( g )
    set bj_groupEnumOwningPlayer = GetOwningPlayer( cast )
    call GroupEnumUnitsInRange( g, x, y, 125.00, Condition( function Enemy_Filter ) )  
    if dist < 1500.00 and FirstOfGroup( g ) == null then
        call SaveReal( H, id, 3, dist )
    else
        call GroupClear( g )
        set bj_groupEnumOwningPlayer = GetOwningPlayer( cast )
        call GroupEnumUnitsInRange( g, x, y, 225.00, Condition( function Enemy_Filter ) ) 
        set bj_lastReplacedUnit = cast
        call ForGroup( g, function Group_Damage_Enemy_Enum )
        call FlushChildHashtable( H, id )
        call PauseTimer(t)
        call DestroyTimer(t)
        call KillUnit(dummy)
    endif

    set t = null
    set cast = null
    set dummy = null
endfunction

function Trig_Frost_Actions takes nothing returns nothing
    local timer t = CreateTimer()
    local integer id = GetHandleId(t)
    local unit cast = GetSpellAbilityUnit()
    local real dx = GetUnitX(cast)
    local real dy = GetUnitY(cast)
    local real facing = Atan2(GetSpellTargetY() - dy, GetSpellTargetX() - dx)
    local unit dummy = CreateUnit( GetOwningPlayer(cast), 'u000', GetCorX( dx + 64.00 * Cos(facing) ), GetCorY( dy + 64.00 * Sin(facing) ), facing * bj_DEGTORAD )
    
    call SetUnitPathing( dummy, false )
    call UnitApplyTimedLife( dummy, 'BTLF', 0.00 )
    
    call SaveUnitHandle( H, id, 0, cast )
    call SaveUnitHandle( H, id, 1, dummy )
    call SaveReal( H, id, 2, facing )
    call SaveReal( H, id, 3, 0.00 )
    call TimerStart( t, 0.03125, true, function Timer_Dummy_Move_Expires )
    
    set cast = null
    set dummy = null
    set t = null
endfunction

//===========================================================================
function InitTrig_Frost takes nothing returns nothing
    set gg_trg_Frost = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Frost, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Frost, Condition( function Trig_Frost_Conditions ) )
    call TriggerAddAction( gg_trg_Frost, function Trig_Frost_Actions )
endfunction

Загруженные файлы

Led_[1].w3x

Скачать - 20 КБ 81

ОЖИДАНИЕ РЕКЛАМЫ...

Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.

quq_CCCP 4 года назад
Отредактирован Maniac_91

Че это за ахинея?

    local trigger t = CreateTrigger()
    local integer index = 0
    local playerunitevent e = null
    local code c = function Frost_Conditions
    local player p = null
    local boolexpr b = null
    
    loop
    set p = Player(index)
    set e = EVENT_PLAYER_UNIT_SPELL_EFFECT
    call TriggerRegisterPlayerUnitEvent(t,p,e,b)
    set index = index + 1
    exitwhen index == bj_MAX_PLAYER_SLOTS
    set e = null
    set p = null
    endloop
    
    set b = Condition(c)
    call TriggerAddCondition(t,b)
    set c = null
    set c = function Frost_Actions
    call TriggerAddAction(t,c)
    
    set b = null
    set c = null
    set t = null

Ну сами и наплодили непойми чего.

Потом волну силы то не пробовали а?
Тут спелл примитив примитивом, но сделан отвратно, зачем то SteUnitPos - вместо нормального движения по осям, как таймер бредовый 0.01, ну ладно уж 0.02, или 0.03125.
Куда 0.01? Нет никакой обьективной нужды в таких таймерах, как и в прочих вещях вроде SetIUnitPosition.

Vlod, они там улететь немогут, т.к SetUnitPos не выпустит.

Но тут почему то нормально не пострена дальность полета, тупая проверка группой что кто то попалася, а если никто - то оно и дальше тикает....

Полная ахинея, уж блин триггер бы взяли и событие UnitsInRange и вручали его всем даммиками, а триггер был бы 1, если уж дофига оптимизацию охото.

1 пункт от Maniac_91: 1.1 (ненормативная лексика)

Vlod 4 года назад

quq_CCCP, да ладно, он элементарно написал свою систему создания триггера
rsfghd, добавь ограничение по дальности, а то сейчас дамми умирают только если попадают по врагу

rsfghd 4 года назад
Отредактирован rsfghd

Та не в дальности дело, господи. Я на дальность плевать хотел, главное что при попадании все равно есть утечки (быстро кастуем спелл)
Насчёт таймера в 0.01, та бл, там изначально было 0.03, мне пофигу на таймер, если оно в любом случае криво работает

quq_CCCP, чем ужасен SetUnitPosition? Оно просто совместило в себе 2 функции SetUnitX и SetUnitY, разве нет?

они там улететь немогут, т.к SetUnitPos не выпустит.

За карту юниты спокойно улетают (ну или за пределы камеры, хз)

Вообще не понимаю почему вы придрались к отсутствию дальности, если бы мне это нужно было, я бы добавил

Было 230, стало 233

Тут спелл примитив примитивом, но сделан отвратно, зачем то SteUnitPos - вместо нормального движения по осям, как таймер бредовый 0.01, ну ладно уж 0.02, или 0.03125. Куда 0.01? Нет никакой обьективной нужды в таких таймерах, как и в прочих вещях вроде SetIUnitPosition.

Ну окей, поставил таймер 0.03 обратно, движение по осям. А толку? Всё так же, как и было до этого, вообще ничего не изменилось.

Полная ахинея, уж блин триггер бы взяли и событие UnitsInRange и вручали его всем даммиками, а триггер был бы 1, если уж дофига оптимизацию охото.

Мне охота не оптимизация, а избавление от утечек

Загруженные файлы

quq_CCCP 4 года назад

rsfghd,
1)SetUnitPosition - значительно более ресурсоемка чем движение по осям, для проверки границ карты проверяйете кординаты на корректность, это элементарно.

Нет никакой надобности юзать таймеры с таким малым периодом, типа 100 раз в сек, 50 или 23 более чем достаточно.
Ты скорее наделал утечики с переменными чем сделал лучше, подобный код бесполезен, уж лучше обынчый БЖ код юзай.

Далее неверный алгоритм, нет иного завершения кроме как попадания. Если у тебя планируется тонны снарядом - то мб не делать как ты для каждого снаряда 1 таймер, еще и переборы группой ?

ScorpioT1000 4 года назад
Отредактирован ScorpioT1000

Нет никакой обьективной нужды в таких таймерах

240гц передает тебе привет)
хотя в классике действительно нет смысла , хотя интерес к классике остался у полутора землекопов

quq_CCCP 4 года назад

ScorpioT1000, причем тут 240 герц монитор и прочее? Вот причем?

rsfghd 4 года назад
Отредактирован rsfghd

Так, спокойно, дыши ровно.. Когда-нибудь мне да помогут с этими утечками
Вот карта с вашим ограничением полёта, господи

https://xgm.guru/files/temp//Led.w3x

Вот карта без моей "ахинеи" и ограничением полёта, раз уж оно так раздражает

https://xgm.guru/files/temp//Led1.w3x

Почему нельзя было просто сказать как сделать так, чтобы число хэндлов возвращалось на своё изначальное место? Ладно придрались к коду, что-то там плохо, что-то тут не так, но изменение этого не решает проблему
Камон, мне просто нужна помощь, пожалуйста

Загруженные файлы

nazarpunk 4 года назад
Отредактирован rsfghd

rsfghd:

Вот карта с вашим ограничением полёта, господи

Вот карта со снарядом без утечек.

rsfghd:

Камон, мне просто нужна помощь, пожалуйста

Не у всех варкрафт установлен, а без него код не глянуть.

Загруженные файлы

PlagueBarrel.gif

rsfghd 4 года назад
Отредактирован rsfghd

NazarPunk, я не знаю cJass и vJass, я этим даже воспользоваться не смогу

За отсутствие кода извиняюсь

Код

globals
    hashtable H = InitHashtable()
    real x
    real y
    group g = CreateGroup()
endglobals

function move takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local unit u = LoadUnitHandle(H,GetHandleId(t),1)
    local unit u1 = null
    local effect e = null
    local string s = null
    local real a = GetUnitFacing(u)
    local real x1 = LoadReal(H,GetHandleId(t),2)
    local real y1 = LoadReal(H,GetHandleId(t),3)
    local real dx
    local real dy
    
    call SetUnitX(u,GetUnitX(u)+15*Cos(a*bj_DEGTORAD))
    call SetUnitY(u,GetUnitY(u)+15*Sin(a*bj_DEGTORAD))
    set x = GetUnitX(u)
    set y = GetUnitY(u)
    set dx = x1-x
    set dy = y1-y
    
    if SquareRoot(dx*dx+dy*dy) >= 900 then
        call GroupEnumUnitsInRange(g,x,y,300,null)
        
        loop
            set u1 = FirstOfGroup(g)
            exitwhen u1 == null
            if IsUnitType(u1,UNIT_TYPE_DEAD) != true and IsUnitEnemy(u1,GetOwningPlayer(u)) == true then
                call UnitDamageTarget(u,u1,10,true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_NORMAL,null)
            endif
            call GroupRemoveUnit(g,u1)
            set u1 = null
        endloop
        
        set s = "Abilities\\Spells\\Undead\\FrostNova\\FrostNovaTarget.mdl"
        set e = AddSpecialEffect(s,x,y)
        call DestroyEffect(e)
        set e = null
        set s = null
        
        call KillUnit(u)
        call PauseTimer(t)
        call FlushChildHashtable(H,GetHandleId(t))
        call DestroyTimer(t)
    else
        call GroupEnumUnitsInRange(g,x,y,100,null)
        loop
            set u1 = FirstOfGroup(g)
            exitwhen u1 == null
            if IsUnitType(u1,UNIT_TYPE_DEAD) != true and IsUnitEnemy(u1,GetOwningPlayer(u)) == true then
                call GroupClear(g)
                call GroupEnumUnitsInRange(g,x,y,300,null)
                
                loop
                    set u1 = FirstOfGroup(g)
                    exitwhen u1 == null
                    if IsUnitType(u1,UNIT_TYPE_DEAD) != true and IsUnitEnemy(u1,GetOwningPlayer(u)) == true then
                        call UnitDamageTarget(u,u1,10,true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_NORMAL,null)
                    endif
                    call GroupRemoveUnit(g,u1)
                    set u1 = null
                endloop
                
                set s = "Abilities\\Spells\\Undead\\FrostNova\\FrostNovaTarget.mdl"
                set e = AddSpecialEffect(s,x,y)
                call DestroyEffect(e)
                set e = null
                set s = null
                
                call KillUnit(u)
                call PauseTimer(t)
                call FlushChildHashtable(H,GetHandleId(t))
                call DestroyTimer(t)
            endif
            call GroupRemoveUnit(g,u1)
            set u1 = null
        endloop
    endif
    
    call GroupClear(g)
    set t = null
    set u = null
endfunction

function Frost_Actions takes nothing returns nothing
    local timer t = CreateTimer()
    local code c = function move
    local unit u1 = GetSpellAbilityUnit()
    local real x1 = GetUnitX(u1)
    local real y1 = GetUnitY(u1)
    local unit u = CreateUnit(GetOwningPlayer(u1),'u000',x1,y1,bj_RADTODEG*Atan2(GetSpellTargetY()-y1,GetSpellTargetX()-x1))
    
    call SaveUnitHandle(H,GetHandleId(t),1,u)
    call SaveReal(H,GetHandleId(t),2,x1)
    call SaveReal(H,GetHandleId(t),3,y1)
    call TimerStart(t,.03,true,c)
    
    set c = null
    set t = null
    set u1 = null
    set u = null
endfunction

function Frost_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction

function InitTrig_Frost takes nothing returns nothing
    local trigger t = CreateTrigger()
    local integer index = 0
    local playerunitevent e = null
    local code c = function Frost_Conditions
    local player p = null
    local boolexpr b = null
    
    loop
    set p = Player(index)
    set e = EVENT_PLAYER_UNIT_SPELL_EFFECT
    call TriggerRegisterPlayerUnitEvent(t,p,e,b)
    set index = index + 1
    exitwhen index == bj_MAX_PLAYER_SLOTS
    set e = null
    set p = null
    endloop
    
    set b = Condition(c)
    call TriggerAddCondition(t,b)
    set c = null
    set c = function Frost_Actions
    call TriggerAddAction(t,c)
    
    set b = null
    set c = null
    set t = null
endfunction

ScorpioT1000 4 года назад

quq_CCCP, даже при 120 фпс период движения 0.01 уже будет заметен

Zetox 4 года назад

0,0069 для моего монитора оптимально. Но это отступление.

Почему call KillUnit(u) а не RemoveUnit() ?
Запустил твою карту, поставил условие выхода снаряда за пределы карты и remove unit, лагов не было, запускал по 200 снарядов.
Или ты судил по GetHandleId ? Так она не покажет количество хендлов в карте, у тебя хендл с более большим значением может освободиться позже.

Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.

Чтобы оставить комментарий, пожалуйста, войдите на сайт.

Утечки

rsfghd

Принятый ответ

Вход

Регистрация на сайте

Переместить ресурс 移动资源

Создание задания

Выбор проекта для репоста

Управление интересами