Увеличение запаса здоровья героя

library StateMax initializer init requires CoreState, optional AbilityPreload, optional xepreload
    globals
        private integer array powersOf2
        private integer powersOf2Count = 1
    endglobals

    struct StateMax extends TypeState
        private unitstate us = null
        private integer id = 0
        private integer count = 0
        
        public static method create takes integer id, unitstate us, integer count returns thistype
            local thistype this = thistype.allocate(0, 0)
            local integer i
            
            set this.id = id
            set this.us = us
            set this.count = count
        
            // Grow powers of 2
            if powersOf2Count < count then
                set i = powersOf2Count
                loop
                    exitwhen i == count * 2 * 2 * 3 + 1
                    
                    set powersOf2[i] = 2 * powersOf2[i - 1]

                    set i = i + 1
                endloop
                set powersOf2Count = count
            endif
            
            static if xe_PRELOAD_ABILITIES then
                call AbilityRangePreload(id, id + count * 2 - 1)
            endif
            
            return this
        endmethod
        
        method operator[]= takes unit u, real amount returns nothing
            local integer rawcode = this.id
            local integer abilityId
            local integer abilityLevel
            local integer currentAbility
            
            set amount = R2I(amount) - R2I(this[u])
            
            if amount < 0 then
                set amount = -amount
                set rawcode = rawcode + this.count
            endif
            
            set abilityId = this.count - 1
            set abilityLevel = 4
            set currentAbility = rawcode + abilityId
            loop
                exitwhen amount == 0
                
                if amount >= powersOf2[abilityId * 3 + (abilityLevel - 2)] then
                    call UnitAddAbility(u, currentAbility)
                    call SetUnitAbilityLevel(u, currentAbility, abilityLevel)
                    call UnitRemoveAbility(u, currentAbility)
                    
                    set amount = amount - powersOf2[abilityId * 3 + (abilityLevel - 2)]
                else
                    set abilityLevel = abilityLevel - 1
                    if abilityLevel <= 1 then
                        set abilityId = abilityId - 1
                        set abilityLevel = 4
                        set currentAbility = rawcode + abilityId
                    endif
                endif
            endloop
        endmethod
        
        method operator[] takes unit u returns real
            return GetUnitState(u, this.us)
        endmethod
    endstruct
    
    //! textmacro StateMaxStart takes CREATE_ABILITIES
        function StateMaxSetup takes nothing returns nothing
        /*
        //! externalblock extension=lua ObjectMerger $FILENAME$
        //! i if $CREATE_ABILITIES$ == "true" then
        //! i function CreateAbility(baseAbility, rawcodePrefix, field, abilityCount, name, icon)
        //! i     k = 0
        //! i     for sign = -1, 1, 2 do
        //! i         signStr = "+"
        //! i         if sign < 0 then
        //! i             signStr = "-"
        //! i         end
        //! i         j = 0
        //! i         for i = 0, (abilityCount - 1) * 3, 3 do
        //! i             j = j + 1
        //! i             createobject(baseAbility, rawcodePrefix .. string.sub(chars, k + 1, k + 1))
        //! i             makechange(current, "anam", "StateMax - " .. name)
        //! i             makechange(current, "ansf", "(" .. signStr .. tostring(j) .. ")")
        //! i             makechange(current, "aart", "ReplaceableTextures\\CommandButtons\\" .. icon)
        //! i             makechange(current, "aite", 0)
        //! i             makechange(current, "alev", 4)
        //! i             makechange(current, field, 1, 0)
        //! i             makechange(current, field, 2, 2^(i + 0) * sign)
        //! i             makechange(current, field, 3, 2^(i + 1) * sign)
        //! i             makechange(current, field, 4, 2^(i + 2) * sign)
        //! i             k = k + 1
        //! i         end
        //! i     end
        //! i end
        //! i setobjecttype("abilities")
        //! i chars = "abcdefghijklmnopqrstuvwxyz"
        */
    //! endtextmacro
    
    //! textmacro StateMaxCreate takes NAME, COUNT, PREFIX, SOURCE_ABILITY, FIELD, ICON
        //! i CreateAbility("$ABILITY$", "$PREFIX$", "$FIELD$", $COUNT$, "$NAME$", "$ICON$")
        globals
            TypeState STATE_$NAME$
        endglobals
        set STATE_$NAME$ = StateMax.create('$PREFIX$a', UNIT_STATE_$NAME$, $COUNT$)
    //! endtextmacro
    
    //! textmacro StateMaxEnd
        /*
        //! i end
        //! endexternalblock
        */
        endfunction
    //! endtextmacro
    
    //! runtextmacro StateMaxStart("false")
    //! runtextmacro StateMaxCreate("MAX_LIFE", "3", "ZxL", "AIlf", "Ilif", "BTNHealthStone.blp")
    //! runtextmacro StateMaxCreate("MAX_MANA", "3", "ZxM", "AImz", "Iman", "BTNManaStone.blp")
    //! runtextmacro StateMaxEnd()
        
    private function init takes nothing returns nothing
        set powersOf2[0] = 1
        
        call StateMaxSetup()
    endfunction
endlibrary