//@ Debug Log library by DoctorGester, 2011, v 1.0

#define{
    private SavePath = Dir\\Debug
    private SaveOnHardDrive = true
    private HardDriveLetter = C
    private AutoSaveLog = true
    private LogSavePeriod = 1.0
}

library DebugLog initializer DebugLogInit{

    #include "cj_types_priv.j"

    private string DebugLog[8192]
    private int CurrentString = 0
    private int Seconds = 0
    private int Minutes = 0
    private constant int StringLimit = 200
    
    void LogAdd(string s){
        string sec = I2S(Seconds)
        if (Seconds < 10){
            sec = "0" + sec
        }
        DebugLog[CurrentString] = DebugLog[CurrentString] + ("[" + I2S(Minutes) + ":" + sec + "] " + s + "\n") /* DebugLog[CurrentString] += (s + "\n") cJass bug ! */
        if (StringLength(DebugLog[CurrentString]) >= StringLimit){
            CurrentString++
        }
    }
    
    void LogClear(){
        int i = 0
        while (i <= CurrentString){
            DebugLog[i] = ""
            i++
        }
        CurrentString = 0
    }
    
    void LogUpdate(){
      PreloadGenClear()
      PreloadGenStart()
      int i = 0
        while (i <= CurrentString){
            Preload("\")\n" + DebugLog[i] + "\n(\"")
            i++
        }
      #if SaveOnHardDrive
            PreloadGenEnd(`HardDriveLetter` + ":\\" + `SavePath` + ".txt")
      #else
            PreloadGenEnd("\\" + `SavePath` + ".txt")
      #endif
    }
    
    private void DebugLogOnTimer(){
        Seconds++
        if (Seconds > 59){
            Seconds = 0
            Minutes++
        }
    }

    private void DebugLogInit(){
        #if AutoSaveLog
            TimerStart(CreateTimer(), LogSavePeriod, true, function LogUpdate)
        #endif
        TimerStart(CreateTimer(), 1., true, function DebugLogOnTimer)
        LogAdd("By DoctorGester. Last compilation: " + `DATE` + " " + `TIME`)
    }
    
}