proc    DrawFrame,.hWin                 ;расчёт и вывод кадра
enter                                   ;с номером [dwFrame]
  ;очистка заднего буфера кадра (частичная)
 invoke PatBlt,[hCompDC],[rVirtWin.left],0,[rVirtWin.left],\
               [rVirtWin.bottom],PATCOPY
  ;вывод линии координат
 mov    ecx,[rVirtWin.bottom]
 shr    ecx,1                           ;/2
 push   ecx
 invoke MoveToEx,[hCompDC],[rVirtWin.left],ecx,NULL
 pop    ecx
 invoke LineTo,[hCompDC],[rVirtWin.right],ecx
 invoke MoveToEx,[hCompDC],[rVirtWin.left],[rVirtWin.top],NULL ;начало
  ;инициализация цикла
 xor    ecx,ecx                         ;счётчик цикла
  ;вычислим каждую точку вывода (цикл)
m_df_loop:                              ;начало цикла
 push   ecx
 fninit                                 ;инициализация сопроцессора
 fld    dword [siPos]                   ;считать позицию
 fld    dword [siStep]                  ;шаг
 fadd   st,st1                          ;сложить
 fstp   dword [siPos]                   ;записать в переменную

 fldpi                                  ;Pi->st0
 mov    [dwTmp],10                      ;10
 fimul  dword [dwTmp]                   ;st0=10*Pi
 fld    dword [siPos]                   ;наш x
 fmul   st,st1                          ;st0=10*Pi*x
 fsin                                   ;st0=sin(10Pi*x)
 fld    dword [siPos]                   ;st0=x,st1=sin(10Pi*x)
 fsin                                   ;st0=sin(x)
 fmul   st,st1                          ;st0=sin(x)*sin(10Pi*x)
 fld    dword [siPos]                   ;st0=x,st1=pi
 fimul  dword [dwFrame]                 ;st0=Pi*x*frame
 mov    [dwTmp],32
 fidiv  dword [dwTmp]                   ;st0=Pi*x*frame/100
 fsin                                   ;st0=sin(Pi*x*frame/100)
 fmul   st,st1                          ;st0=f(x,frame) - ура!

 fldz                                   ;st0=0,st1=yCounted
 fsub   st,st1                          ;st0=-yCounted
 fimul  dword [dwStretchY]              ;масштабируем
 fistp  dword [dwTmp]                   ;извлекаем с округлением
 mov    eax,[dwTmp]                     ;загружаем в eax
 add    eax,[rVirtWin.top]              ;получаем реальную координату Y

 fld    dword [siPos]                   ;грузим x
 fld    dword [siStretchX]              ;st1=x,st0=StretchX
 fmul   st,st1                          ;st0=x*StretchX
 fistp  dword [dwTmp]                   ;извлекаем округлённое
 mov    edx,[dwTmp]
 add    edx,[rVirtWin.left]             ;получается реальная координата X
 invoke LineTo,[hCompDC],edx,eax        ;вывод куска линии
 pop    ecx
 inc    ecx                             ;следующая итерация
jif     ecx,b,300,m_df_loop             ;конец рассчётного цикла
 fldz
 fstp   dword [siPos]                   ;X на начало
  ;вывод на передний буфер кадра
 mov    ecx,[rVirtWin.right]
 shr    ecx,1                           ;половина окна по x
 mov    edx,[rWinRect.right]
 shr    edx,1
 invoke StretchBlt,[hDC],edx,0,edx,[rWinRect.bottom],\
                   [hCompDC],ecx,0,ecx,[rVirtWin.bottom],SRCCOPY
return