library EffectsTimedLife initializer InitHash
    //==================================================
    // Автор quq_CCCP Сделано для сайта XGM.ru                                             
    // Одна из функций взята с барахолки (AddSpecialEffectZ, Автор - bee )       
    // Копируем в и юзаем AddSpecialEffectTargetToTimed, и 2 другие функции  
    //==================================================
    globals
        // обьявление вспомогательных переменных, нужных для работы системы (лучше не трогать)
        private timer bj_effectTimer
        private integer bj_effectTimerId
        private destructable bj_auxDestructable
        private location bj_AdditionalPoint = Location( 0.00, 0.00 )
        private real bj_HeightFactor = 45.00 //базовая высота юнита над рельефом, можно задать на своё усмотрение.
        private hashtable bj_Hash
    endglobals
    
    private function InitHash takes nothing returns nothing
        set bj_Hash = InitHashtable( )
    endfunction
    
    private function DestroyEffectToTimed takes nothing returns nothing // удаление спецэффекта.
        set bj_effectTimer = GetExpiredTimer( )
        set bj_effectTimerId = GetHandleId( bj_effectTimer )
        call DestroyTimer( bj_effectTimer )
        call DestroyEffect( LoadEffectHandle( bj_Hash, bj_effectTimerId, 0 ) )
        call FlushChildHashtable( bj_Hash, bj_effectTimerId )
    endfunction
  
    function GetUnitZ takes unit whithUnit returns real // функция возвращающая высоту юнита
        call MoveLocation( bj_AdditionalPoint, GetUnitX(whithUnit), GetUnitY( whithUnit ) )
        return GetLocationZ( bj_AdditionalPoint ) + bj_HeightFactor + GetUnitFlyHeight( whithUnit )
    endfunction
    
    function AddSpecialEffectTargetToTimed takes string path, widget targetWidget, string attachPointName, real timeout returns nothing // создаёт спецэффект на указанном юните.
        set bj_effectTimer = CreateTimer( )
        call SaveEffectHandle( bj_Hash, GetHandleId( bj_effectTimer ), 0, AddSpecialEffectTarget( path, targetWidget, attachPointName ) )
        call TimerStart( bj_effectTimer, timeout, false, function DestroyEffectToTimed )
    endfunction
    
    function AddSpecialEffectToTimed takes string path, real x, real y, real timeout returns nothing // создаёт спецэффект в указанных координатах
        set bj_effectTimer = CreateTimer( )
        call SaveEffectHandle( bj_Hash, GetHandleId( bj_effectTimer ), 0, AddSpecialEffect( path, x, y ) )
        call TimerStart( bj_effectTimer, timeout, false, function DestroyEffectToTimed )
    endfunction
    
    function AddSpecialEffectZtoTimed takes string path, real x, real y, real z, real timeout returns nothing // создаёт спецэффект в казаннх координатах и на некоторой высоте Z.
        set bj_auxDestructable = CreateDestructableZ( 'OTip', x, y, z, 0.00, 1, 0 )
        call AddSpecialEffectToTimed( path, x, y, timeout )
        call RemoveDestructable( bj_auxDestructable )
    endfunction
    
endlibrary