Алгоритмы, Наработки и Способности
Способ реализации:
cJass
Тип:
Наработка
Библиотека, которая позволяет добавлять общее событие "юнит получает урон":
cJass
library UnitDamaged initializer InitRect {
    #include "cj_types_priv.j"

    private group   allUnits;
    private region  mapArea;
    private trigger Trigger[];
    private int     TrigsNum = 0;

    private void unitDamagedEvent() {
        TriggerRegisterUnitEvent(Trigger[TrigsNum], GetEnumUnit(), EVENT_UNIT_DAMAGED);
    }

    void AnyUnitDamagedEvent(trigger toTrigger) {
        Trigger[TrigsNum] = toTrigger;
        ForGroup(allUnits, function unitDamagedEvent);
        TrigsNum++;
    }

    private void onUnitSpawn() {
        for (int i = 0; i < TrigsNum; i++) {
            TriggerRegisterUnitEvent(Trigger[i], GetEnteringUnit(), EVENT_UNIT_DAMAGED);
        }
        GroupAddUnit(allUnits, GetEnteringUnit());
    }

    private void onUnitDecay() {
        GroupRemoveUnit(allUnits, GetDecayingUnit());
    }

    private void InitRect() {
        trigger onSpawn = CreateTrigger();
        trigger onDecay = CreateTrigger();
        allUnits = CreateGroup();
        mapArea = CreateRegion();
        GroupEnumUnitsInRect(allUnits, GetWorldBounds(), null);
        RegionAddRect(mapArea, GetWorldBounds());
        TriggerRegisterEnterRegion(onSpawn, mapArea, null);
        for (int i = 0; i < bj_MAX_PLAYER_SLOTS; i++) {
            TriggerRegisterPlayerUnitEvent(onDecay, Player(i), EVENT_PLAYER_UNIT_DECAY, null);
        }
        TriggerAddAction(onSpawn, function onUnitSpawn);
        TriggerAddAction(onDecay, function onUnitDecay);
    }
}
vJass
library UnitDamaged initializer initRect
    globals
        private group   allUnits
        private region  mapArea
        private trigger Trigger[]
        private integer TrigsNum = 0
    endglobals

    private function unitDamagedEvent takes nothing returns nothing
        call TriggerRegisterUnitEvent(Trigger[TrigsNum], GetEnumUnit(), EVENT_UNIT_DAMAGED)
    endfunction

    function AnyUnitDamagedEvent takes trigger toTrigger returns nothing
        set Trigger[TrigsNum] = toTrigger
        call ForGroup(allUnits, function unitDamagedEvent)
        set TrigsNum = TrigsNum + 1
    endfunction

    private function onUnitSpawn takes nothing returns nothing
        local integer i = 0
        loop
            exitwhen (i == TrigsNum)
            call TriggerRegisterUnitEvent(Trigger[i], GetEnteringUnit(), EVENT_UNIT_DAMAGED)
            set i = i + 1
        endloop
        call GroupAddUnit(allUnits, GetEnteringUnit())
    endfunction

    private function onUnitDecay takes nothing returns nothing
        call GroupRemoveUnit(allUnits, GetDecayingUnit())
    endfunction

    private function initRect takes nothing returns nothing
        local integer i = 0
        local trigger onSpawn = CreateTrigger()
        local trigger onDecay = CreateTrigger()
        set allUnits = CreateGroup()
        set mapArea = CreateRegion()
        call GroupEnumUnitsInRect(allUnits, GetWorldBounds(), null)
        call RegionAddRect(mapArea, GetWorldBounds())
        call TriggerRegisterEnterRegion(onSpawn, mapArea, null)
        loop
            exitwhen (i == bj_MAX_PLAYER_SLOTS)
            call TriggerRegisterPlayerUnitEvent(onDecay, Player(i), EVENT_PLAYER_UNIT_DECAY, null)
            set i = i + 1
        endloop
        call TriggerAddAction(onSpawn, function onUnitSpawn)
        call TriggerAddAction(onDecay, function onUnitDecay)
    endfunction
endlibrary

Добавление события:
    call AnyUnitDamagedEvent(subscribingTrigger)

Источник урона (атаковавший юнит):
GetEventDamageSource()
Цель урона (атакованный юнит):
GetTriggerUnit() 
Величина нанесённого урона:
GetEventDamage()

Установка: скопировать в Нестандартный Код Карты, дальнейших действий не требуется.

Ограничения:
  • Нельзя использовать с динамичными триггерами
  • Нельзя использовать более, чем с JASS_MAX_ARRAY_SIZE триггеров

Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.
0
30
6 лет назад
0
Raised,
main
Удачи вручную перепаковывать .j файл после каждого сейва карты.
2
37
6 лет назад
2
Clamp, есть inject
0
21
6 лет назад
0
Если что инжект перезаписывает майн.

По сабжу: имелл ввиду 2 триггера которые регают событие для третьего. Первый при ините добавляет ивент для всех начальных юнитов. Второй - при входе на карту. Это и есть "Как обычно".
Вешать на каждый ивент по бандлу триггеров едва ли целесообразней чем эксекутить функцию в зависимости от кейса, то есть необходимость такой "системы" весьма спорна.
0
30
6 лет назад
0
Первый при ините добавляет ивент для всех начальных юнитов.
Для этого не нужна сущность триггера, что прекрасно видно из кода системы.

Вешать на каждый ивент по бандлу триггеров
Вот только это эвенты вешаются на триггеры, а не наоброт.
1
21
6 лет назад
Отредактирован Raised
1
Вот только это эвенты вешаются на триггеры, а не наоброт.
ok.
0
30
6 лет назад
Отредактирован Clamp
0
Вызов в Jass
trigger Trig = CreateTrigger()
TriggerRegisterUnitEvent(Trig, GetSomeUnit(), SOME_EVENT)
Можно интерпретировать примерно так:
trigger Trig = trigger.create();
Trig.registerUnitEvent(GetSomeUnit(), SOME_EVENT);
0
21
6 лет назад
Отредактирован Raised
0
В игровом цикле триггерится событие, запускающее бандл триггеров. Не важно как ты это интерпретируешь.
Для этого не нужна сущность триггера, что прекрасно видно из кода системы.
На выходе предназначение системы - все то же, то есть регать событие для для триггеров в одну строку. И ты игнорируешь тот факт что вешать на ивент тучу триггеров - заведомо ущербный подход, а если делать нормально, то твоя система нафиг не нужна.
3
30
6 лет назад
Отредактирован Clamp
3
если делать нормально, то твоя система не нужна
Отлично, делай "нормально" и не пользуйся моей системой.
Этот комментарий удален
0
21
5 лет назад
0
Ограничения:
Нельзя использовать с динамичными триггерами
Почему бы не убрать это ограничение? Легко же делается.
0
30
5 лет назад
0
ScopteRectuS, не то, чтобы мне хотелось возвращаться к этой наработке, но ты можешь сделать свой вариант и скинуть в личку, если всё ок, то обновлю ресурс и добавлю в соавторы.
Но имей в виду, что я против привлечения новых сущностей, система должна оставаться компактной и простой.
Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.
Чтобы оставить комментарий, пожалуйста, войдите на сайт.