Алгоритмы, Наработки и Способности
Способ реализации:
cJass
Тип:
Наработка
Библиотека, которая позволяет добавлять общее событие "юнит получает урон":
cJass
library UnitDamaged initializer InitRect {
    #include "cj_types_priv.j"

    private group   allUnits;
    private region  mapArea;
    private trigger Trigger[];
    private int     TrigsNum = 0;

    private void unitDamagedEvent() {
        TriggerRegisterUnitEvent(Trigger[TrigsNum], GetEnumUnit(), EVENT_UNIT_DAMAGED);
    }

    void AnyUnitDamagedEvent(trigger toTrigger) {
        Trigger[TrigsNum] = toTrigger;
        ForGroup(allUnits, function unitDamagedEvent);
        TrigsNum++;
    }

    private void onUnitSpawn() {
        for (int i = 0; i < TrigsNum; i++) {
            TriggerRegisterUnitEvent(Trigger[i], GetEnteringUnit(), EVENT_UNIT_DAMAGED);
        }
        GroupAddUnit(allUnits, GetEnteringUnit());
    }

    private void onUnitDecay() {
        GroupRemoveUnit(allUnits, GetDecayingUnit());
    }

    private void InitRect() {
        trigger onSpawn = CreateTrigger();
        trigger onDecay = CreateTrigger();
        allUnits = CreateGroup();
        mapArea = CreateRegion();
        GroupEnumUnitsInRect(allUnits, GetWorldBounds(), null);
        RegionAddRect(mapArea, GetWorldBounds());
        TriggerRegisterEnterRegion(onSpawn, mapArea, null);
        for (int i = 0; i < bj_MAX_PLAYER_SLOTS; i++) {
            TriggerRegisterPlayerUnitEvent(onDecay, Player(i), EVENT_PLAYER_UNIT_DECAY, null);
        }
        TriggerAddAction(onSpawn, function onUnitSpawn);
        TriggerAddAction(onDecay, function onUnitDecay);
    }
}
vJass
library UnitDamaged initializer initRect
    globals
        private group   allUnits
        private region  mapArea
        private trigger Trigger[]
        private integer TrigsNum = 0
    endglobals

    private function unitDamagedEvent takes nothing returns nothing
        call TriggerRegisterUnitEvent(Trigger[TrigsNum], GetEnumUnit(), EVENT_UNIT_DAMAGED)
    endfunction

    function AnyUnitDamagedEvent takes trigger toTrigger returns nothing
        set Trigger[TrigsNum] = toTrigger
        call ForGroup(allUnits, function unitDamagedEvent)
        set TrigsNum = TrigsNum + 1
    endfunction

    private function onUnitSpawn takes nothing returns nothing
        local integer i = 0
        loop
            exitwhen (i == TrigsNum)
            call TriggerRegisterUnitEvent(Trigger[i], GetEnteringUnit(), EVENT_UNIT_DAMAGED)
            set i = i + 1
        endloop
        call GroupAddUnit(allUnits, GetEnteringUnit())
    endfunction

    private function onUnitDecay takes nothing returns nothing
        call GroupRemoveUnit(allUnits, GetDecayingUnit())
    endfunction

    private function initRect takes nothing returns nothing
        local integer i = 0
        local trigger onSpawn = CreateTrigger()
        local trigger onDecay = CreateTrigger()
        set allUnits = CreateGroup()
        set mapArea = CreateRegion()
        call GroupEnumUnitsInRect(allUnits, GetWorldBounds(), null)
        call RegionAddRect(mapArea, GetWorldBounds())
        call TriggerRegisterEnterRegion(onSpawn, mapArea, null)
        loop
            exitwhen (i == bj_MAX_PLAYER_SLOTS)
            call TriggerRegisterPlayerUnitEvent(onDecay, Player(i), EVENT_PLAYER_UNIT_DECAY, null)
            set i = i + 1
        endloop
        call TriggerAddAction(onSpawn, function onUnitSpawn)
        call TriggerAddAction(onDecay, function onUnitDecay)
    endfunction
endlibrary

Добавление события:
    call AnyUnitDamagedEvent(subscribingTrigger)

Источник урона (атаковавший юнит):
GetEventDamageSource()
Цель урона (атакованный юнит):
GetTriggerUnit() 
Величина нанесённого урона:
GetEventDamage()

Установка: скопировать в Нестандартный Код Карты, дальнейших действий не требуется.

Ограничения:
  • Нельзя использовать с динамичными триггерами
  • Нельзя использовать более, чем с JASS_MAX_ARRAY_SIZE триггеров

Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.
0
21
6 лет назад
0
Хотя в итоге не сильно удобней чем в классическом виде.
0
30
6 лет назад
0
ScopteRectuS, спасибо, поправил.

Raised, "классического" вида знавать не приходилось.
0
21
6 лет назад
0
2 Триггера жеж. Тем более нет смысла так запариваться когда можно создать простой обработчик урона. Регать овердохрена событий для тучи триггеров - так себе подход.
0
30
6 лет назад
0
создать простой обработчик урона
Вот тут поподробнее, пожалуйста.
0
21
6 лет назад
Отредактирован Raised
0
Функция, которая срабатывает когда проходит урон. В ней проверяются условия и эксекутится соответствующая функция в зависимости от кейса. А ты о чем подумал?
0
30
6 лет назад
0
срабатывает когда проходит урон
Как?
0
21
6 лет назад
0
Так как обычно.
0
21
6 лет назад
0
Clamp, я думаю он имел ввиду сделать так, как было ранее.
0
21
6 лет назад
Отредактирован Clamp
0
раскрыть
    function OnDamage takes nothing returns nothing
        //Тут проверки и эксекут функции, в зависимости от кейса. Только не перегрейся.
    endfunction

    function OnMapEntrance takes nothing returns nothing
        call TriggerRegisterUnitEvent(ON_UNIT_DAMAGE,GetEnteringUnit(),EVENT_UNIT_DAMAGED)
    endfunction

    function main takes nothing returns nothing
        call InitBlizzard()
        
        set WHOLE_MAP = CreateRegion()
        call RegionAddRect(WHOLE_MAP,bj_mapInitialPlayableArea)
        
        set ON_MAP_ENTRANCE = CreateTrigger()
        call TriggerRegisterEnterRegion(ON_MAP_ENTRANCE,WHOLE_MAP,null)
        call TriggerAddAction(ON_MAP_ENTRANCE,function OnMapEntrance)
      
        set ON_UNIT_DAMAGE = CreateTrigger()
        call TriggerAddAction(ON_UNIT_DAMAGE,function OnDamage)
                         
    
        set MY_UNIT = CreateUnit(Player(0),'U005',-3440.0,3542.7,309.950)
        call SetHeroStr(MY_UNIT,14,true)
        call SetHeroAgi(MY_UNIT,14,true)
        call SetHeroInt(MY_UNIT,24,true)
        call SetUnitColor(MY_UNIT,ConvertPlayerColor(12))
        
        set NEUTRAL_UNIT = CreateUnit(NEUTRAL_UNIT,'u003',3269.8,2784.1,262.763)
        call SetUnitColor(NEUTRAL_UNIT,ConvertPlayerColor(12))
            
    endfunction 
2 пункта от Кет: 2.1 (оскорбление)
0
30
6 лет назад
0
Raised,
main
Удачи вручную перепаковывать .j файл после каждого сейва карты.
2
37
6 лет назад
2
Clamp, есть inject
Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.
Чтобы оставить комментарий, пожалуйста, войдите на сайт.