Алгоритмы, Наработки и Способности
Способ реализации:
cJass
Тип:
Наработка
Библиотека, которая позволяет добавлять общее событие "юнит получает урон":
cJass
library UnitDamaged initializer InitRect {
    #include "cj_types_priv.j"

    private group   allUnits;
    private region  mapArea;
    private trigger Trigger[];
    private int     TrigsNum = 0;

    private void unitDamagedEvent() {
        TriggerRegisterUnitEvent(Trigger[TrigsNum], GetEnumUnit(), EVENT_UNIT_DAMAGED);
    }

    void AnyUnitDamagedEvent(trigger toTrigger) {
        Trigger[TrigsNum] = toTrigger;
        ForGroup(allUnits, function unitDamagedEvent);
        TrigsNum++;
    }

    private void onUnitSpawn() {
        for (int i = 0; i < TrigsNum; i++) {
            TriggerRegisterUnitEvent(Trigger[i], GetEnteringUnit(), EVENT_UNIT_DAMAGED);
        }
        GroupAddUnit(allUnits, GetEnteringUnit());
    }

    private void onUnitDecay() {
        GroupRemoveUnit(allUnits, GetDecayingUnit());
    }

    private void InitRect() {
        trigger onSpawn = CreateTrigger();
        trigger onDecay = CreateTrigger();
        allUnits = CreateGroup();
        mapArea = CreateRegion();
        GroupEnumUnitsInRect(allUnits, GetWorldBounds(), null);
        RegionAddRect(mapArea, GetWorldBounds());
        TriggerRegisterEnterRegion(onSpawn, mapArea, null);
        for (int i = 0; i < bj_MAX_PLAYER_SLOTS; i++) {
            TriggerRegisterPlayerUnitEvent(onDecay, Player(i), EVENT_PLAYER_UNIT_DECAY, null);
        }
        TriggerAddAction(onSpawn, function onUnitSpawn);
        TriggerAddAction(onDecay, function onUnitDecay);
    }
}
vJass
library UnitDamaged initializer initRect
    globals
        private group   allUnits
        private region  mapArea
        private trigger Trigger[]
        private integer TrigsNum = 0
    endglobals

    private function unitDamagedEvent takes nothing returns nothing
        call TriggerRegisterUnitEvent(Trigger[TrigsNum], GetEnumUnit(), EVENT_UNIT_DAMAGED)
    endfunction

    function AnyUnitDamagedEvent takes trigger toTrigger returns nothing
        set Trigger[TrigsNum] = toTrigger
        call ForGroup(allUnits, function unitDamagedEvent)
        set TrigsNum = TrigsNum + 1
    endfunction

    private function onUnitSpawn takes nothing returns nothing
        local integer i = 0
        loop
            exitwhen (i == TrigsNum)
            call TriggerRegisterUnitEvent(Trigger[i], GetEnteringUnit(), EVENT_UNIT_DAMAGED)
            set i = i + 1
        endloop
        call GroupAddUnit(allUnits, GetEnteringUnit())
    endfunction

    private function onUnitDecay takes nothing returns nothing
        call GroupRemoveUnit(allUnits, GetDecayingUnit())
    endfunction

    private function initRect takes nothing returns nothing
        local integer i = 0
        local trigger onSpawn = CreateTrigger()
        local trigger onDecay = CreateTrigger()
        set allUnits = CreateGroup()
        set mapArea = CreateRegion()
        call GroupEnumUnitsInRect(allUnits, GetWorldBounds(), null)
        call RegionAddRect(mapArea, GetWorldBounds())
        call TriggerRegisterEnterRegion(onSpawn, mapArea, null)
        loop
            exitwhen (i == bj_MAX_PLAYER_SLOTS)
            call TriggerRegisterPlayerUnitEvent(onDecay, Player(i), EVENT_PLAYER_UNIT_DECAY, null)
            set i = i + 1
        endloop
        call TriggerAddAction(onSpawn, function onUnitSpawn)
        call TriggerAddAction(onDecay, function onUnitDecay)
    endfunction
endlibrary

Добавление события:
    call AnyUnitDamagedEvent(subscribingTrigger)

Источник урона (атаковавший юнит):
GetEventDamageSource()
Цель урона (атакованный юнит):
GetTriggerUnit() 
Величина нанесённого урона:
GetEventDamage()

Установка: скопировать в Нестандартный Код Карты, дальнейших действий не требуется.

Ограничения:
  • Нельзя использовать с динамичными триггерами
  • Нельзя использовать более, чем с JASS_MAX_ARRAY_SIZE триггеров

Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.
2
30
6 лет назад
2
Пользуясь случаем, чутка улучшил системку.
0
21
6 лет назад
0
А может ли один юнит в каком-то случае дважды войти в bj_mapInitialPlayableArea?
2
30
6 лет назад
2
ScopteRectuS, можешь ли ты зайти в комнату дважды, не выходя из неё? :)
0
21
6 лет назад
Отредактирован scopterectus
0
Clamp, Но я же не внутри варика.
Может я еще неправильно прочитал/понял код, но даже если воин войдёт, выйдет и снова войдёт в bj_mapInitialPlayableArea. То всем триггерам добавится второе событие на одного и того же юнита?
2
32
6 лет назад
2
ScopteRectuS, когда юнит создается на карте - он входит в игровой рект (bj_mapInitialPlayableArea), а когда он умирает он никуда не уходит, где был там и остается, у совсем дохлы координаты х -0.00, y - 0.00 что является центром карты.
Выйти за пределы карты юнит не может, т.к игра завершится с фаталом.
6
16
6 лет назад
6
Юнит МОЖЕТ выйти за пределы bj_mapInitialPlayableArea. Для нормальной работы создай рект -99999,-99999,99999,99999 и в нём регистрируй входящих.
0
21
6 лет назад
0
quq_CCCP, DracoL1ch, я не имел ввиду выход воина из области карты, когда GetUnitX( ) > GetRectMaxX( ) и GetUnitY( ) < GetRectMinY( ).
Я имел ввиду другое, например, если воина спрятать, а затем снова показать, или воскресить мёртвого воина и тому подобные случаи.
0
8
6 лет назад
0
ScopteRectuS, спрятанный стоит там же, а воскресить = создать нового юнита.
0
21
6 лет назад
0
воскресить = создать нового юнита
тут не согласен, потому что GetHandeId( ) возвращает одно и то же число.
0
32
6 лет назад
0
ScopteRectuS, умершие с карты никуда не уходят.
0
8
6 лет назад
Отредактирован uranus
0
ScopteRectuS, а может просто Remove идет на труп? Хм, странно, почему я был так уверен в этом.
Показан только небольшой набор комментариев вокруг указанного. Перейти к актуальным.
Чтобы оставить комментарий, пожалуйста, войдите на сайт.