function Trig_PoisonBomb_Conditions takes nothing returns boolean
        return GetSpellAbilityId() == 'A016'
endfunction

function Trig_PoisonBomb_FILTER takes nothing returns boolean
        return (GetOwningPlayer(GetFilterUnit()) == Player(PLAYER_NEUTRAL_AGGRESSIVE))
endfunction

function Trig_PoisonBomb_Func010A takes nothing returns nothing
    call UnitDamageTarget( GetTriggerUnit(), GetEnumUnit(), ( 99.00 + 1.00 ), true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS )
endfunction

function Trig_PoisonBomb_Actions takes nothing returns nothing
    //цель заклинания - точка
    local real xCast = GetUnitX(GetTriggerUnit()) //положение кастера по Х
    local real yCast = GetUnitY(GetTriggerUnit())//положение кастера по Y
    local real xTarget = GetSpellTargetX() //положение точки цели по Х
    local real yTarget = GetSpellTargetY() //положение точки цели по Y
    local real dx = xTarget - xCast //разница положений кастера и цели по Х
    local real dy = yTarget - yCast //разница положений кастера и цели по Y
    local real dist = SquareRoot(dx * dx + dy * dy) //дистанция между кастером и целью
    local real x
    local real y
    local real angle
    local group g = CreateGroup()
    local boolexpr f = Condition(function Trig_PoisonBomb_FILTER) //ссылка на функцию, которая возвращает "да" или "нет"
    local string s = "Abilities\\Spells\\Human\\Heal\\HealTarget.mdl" //эффект
    local effect array e //некоторые эффекты нельзя удалять сразу(т.к. у них нет анимации смерти и они просто удаляются)
    local integer i = 1
    local integer max = 3 //кол-во создаваемых эффектов
    call TriggerSleepAction( dist/700.00 )
    loop
     exitwhen i > max
        set angle = GetRandomReal (1,360) //случайное направление
        set x = xTarget + 100.0 * Cos(angle * bj_DEGTORAD) //случайное положение по Х от Х-цели
        set y = yTarget + 100.0 * Sin(angle * bj_DEGTORAD) //случайное положение по Y от Y-цели
        set e[i] = AddSpecialEffect ( s, x, y ) //эффект
     set i = i + 1
    endloop
    set s = null //обнуляем
    call GroupEnumUnitsInRange ( g, xTarget, yTarget, 150.0, f ) //выделяем всех в области (удовлетворяющие условиям f)
    call ForGroup( g, function Trig_PoisonBomb_Func010A ) //произодим действия
    call DestroyBoolExpr (f) //обнуление
    set f = null //обнуление
    call GroupClear (g) //обнуление
    call DestroyGroup (g) //обнуление
    set g = null //обнуление
    call TriggerSleepAction ( 2.0 ) //ждем, чтобы удалить эффекты
    set i = 1
    loop
     exitwhen i > max
        call DestroyEffect ( e[i] ) //удаляем все созданные эффекты
        set e[i] = null // и обнуляем переменные
     set i = i + 1
    endloop
endfunction

//===========================================================================
function InitTrig_PoisonBomb takes nothing returns nothing
    set gg_trg_PoisonBomb = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_PoisonBomb, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_PoisonBomb, Condition( function Trig_PoisonBomb_Conditions ) )
    call TriggerAddAction( gg_trg_PoisonBomb, function Trig_PoisonBomb_Actions )
endfunction